Tutorialul explică specificul funcțiilor Excel Rank și arată cum să faceți clasamente în Excel pe baza mai multor criterii, să clasificați datele în funcție de grup, să calculați clasamentul percentila și multe altele.

Atunci când trebuie să determinați poziția relativă a unui număr într-o listă de numere, cel mai simplu este să sortați numerele în ordine crescătoare sau descrescătoare. Dacă, din anumite motive, sortarea nu este posibilă, o formulă Rank din Excel este instrumentul perfect pentru a face treaba.

Funcția Excel RANK

Funcția RANK din Excel returnează ordinea (sau rangul) unei valori numerice în comparație cu alte valori din aceeași listă. Cu alte cuvinte, vă spune care valoare este cea mai mare, a doua cea mai mare etc.

Într-o listă sortată, rangul unui anumit număr ar fi poziția acestuia. Funcția RANK din Excel poate determina rangul începând cu cea mai mare valoare (ca și cum ar fi sortată în ordine descrescătoare) sau cea mai mică valoare (ca și cum ar fi sortată în ordine crescătoare).

Sintaxa funcției RANK din Excel este următoarea:

Unde:

Număr (obligatoriu) - valoarea al cărei rang doriți să îl găsiți.

Ref (obligatoriu) - o listă de valori numerice pentru clasificare. Poate fi furnizată sub forma unei matrice de numere sau a unei referințe la lista de numere.

Comandă (opțional) - un număr care specifică modul de clasificare a valorilor:

• Dacă este 0 sau este omis, valorile sunt clasificate în ordine descrescătoare, adică de la cea mai mare la cea mai mică.
• Dacă este 1 sau orice altă valoare diferită de zero, valorile sunt clasificate în ordine crescătoare, adică de la cea mai mică la cea mai mare.

Funcția Excel RANK.EQ

RANK.EQ este o versiune îmbunătățită a funcției RANK, introdusă în Excel 2010. Are aceeași sintaxă ca și RANK și funcționează cu aceeași logică: dacă mai multe valori sunt clasificate în mod egal, cel mai mare rang este atribuit tuturor acestor valori. (EQ înseamnă "egal").

În Excel 2007 și versiunile mai mici, trebuie să utilizați întotdeauna funcția RANK. În Excel 2010, Excel 2013 și Excel 2016, puteți utiliza fie RANK, fie RANK.EQ. Cu toate acestea, ar fi înțelept să utilizați RANK.EQ deoarece RANK poate fi întreruptă în orice moment.

Funcția Excel RANK.AVG

RANK.AVG este o altă funcție pentru a găsi rangul în Excel, care este disponibilă numai în Excel 2010, Excel 2013, Excel 2016 și ulterior.

Aceasta are aceeași sintaxă ca și celelalte două funcții:

Diferența constă în faptul că, dacă mai multe numere au același rang, atunci rangul mediu este returnat (AVG înseamnă "medie").

4 lucruri pe care ar trebui să le știți despre RANK în Excel

1. Orice formulă Rank din Excel funcționează numai pentru valori numerice: numere pozitive și negative, zerouri, valori de dată și de oră. Valorile nenumerice din ref sunt ignorate.
2. Toate funcțiile RANK returnează același rang pentru valorile duplicate și sar peste clasamentul ulterior, după cum se arată în exemplul de mai jos.
3. În Excel 2010 și în versiunile ulterioare, funcția RANK a fost înlocuită cu RANK.EQ și RANK.AVG. Pentru compatibilitate retroactivă, RANK funcționează în continuare în toate versiunile Excel, dar este posibil să nu mai fie disponibilă în viitor.
4. Dacă număr nu se găsește în cadrul ref , orice funcție Excel Rank ar returna eroarea #N/A.

Formula de bază Excel Rank (de la cel mai mare la cel mai mic)

Pentru a înțelege mai bine cum se clasifică datele în Excel, vă rugăm să vă uitați la această captură de ecran:

Toate cele trei formule clasifică numerele din coloana B în ordine descrescătoare (a comandă argument omis):

În toate versiunile de Excel 2003 - 2016:

=RANK($B2,$B$2:$B$7)

În Excel 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Diferența constă în modul în care aceste formule procesează valorile duplicate. După cum vedeți, același scor apare de două ori, în celulele B5 și B6, ceea ce afectează clasamentul ulterior:

• Formulele RANK și RANK.EQ atribuie un rang 2 ambelor scoruri duplicate. Următorul punctaj (Daniela) se află pe locul 4. Un rang 3 nu este atribuit nimănui.
• Formula RANK.AVG atribuie un rang diferit fiecărui duplicat din spatele scenei (2 și 3 în acest exemplu) și returnează media acestor ranguri (2,5). Din nou, al treilea rang nu este atribuit nimănui.

Cum se utilizează RANK în Excel - exemple de formule

Se spune că drumul spre excelență este pavat cu practică. Așadar, pentru a învăța mai bine cum să folosim funcția RANK în Excel, singură sau în combinație cu alte funcții, haideți să elaborăm soluții la câteva sarcini din viața reală.

Cum se clasifică în Excel de la cel mai mic la cel mai mare

După cum se arată în exemplul de mai sus, pentru a clasifica numerele de la cel mai mare la cel mai mic, utilizați una dintre formulele Excel Rank cu comandă setat la 0 sau omis (implicit).

Pentru a avea număr clasate față de alte numere sortate în ordine crescătoare , puneți 1 sau orice altă valoare diferită de zero în cel de-al treilea argument opțional.

De exemplu, pentru a clasifica timpii de sprint pe 100 de metri ai elevilor, puteți utiliza oricare dintre formulele de mai jos:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Vă rugăm să fiți atenți la faptul că blocăm intervalul în ref utilizând referințe absolute de celule, astfel încât să nu se schimbe atunci când copiem formula în josul coloanei.

Ca rezultat, cea mai mică valoare (cel mai rapid timp) se clasează pe locul 1, iar cea mai mare valoare (cel mai lent timp) primește cel mai mic rang, 6. Timpii egali (B2 și B7) primesc același rang.

Cum să clasificați datele în Excel în mod unic

După cum s-a subliniat mai devreme, toate funcțiile Excel Rank returnează același rang pentru elemente de valoare egală. Dacă nu doriți acest lucru, utilizați una dintre următoarele formule pentru a rezolva situațiile de egalitate și a da un rang rang unic la fiecare număr.

Clasament unic de la cel mai mare la cel mai mic

Pentru a clasifica notele la matematică ale elevilor noștri în ordine descrescătoare, utilizați această formulă:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Clasament unic de la cel mai mic la cel mai mare

Pentru a clasifica rezultatele cursei de 100 de metri în ordine crescătoare, fără dubluri, folosiți această formulă:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Cum funcționează aceste formule

După cum probabil ați observat, singura diferență între cele două formule este comandă argument al funcției RANK.EQ: omis pentru a clasifica valorile în ordine descrescătoare, 1 pentru a le clasifica în ordine crescătoare.

În ambele formule, funcția COUNTIF, cu utilizarea inteligentă a referințelor relative și absolute la celule, este cea care face trucul. Pe scurt, utilizați COUNTIF pentru a afla câte apariții ale numărului care se clasifică există în celulele de mai sus, inclusiv în celula numărului. În rândul cel mai de sus, unde introduceți formula, intervalul constă într-o singură celulă ($B$2:B2). Dar, deoarece blocați numaiprima referință ($B$2), ultima referință relativă (B2) se modifică în funcție de rândul în care este copiată formula. Astfel, pentru rândul 7, intervalul se extinde la $B$2:B7, iar valoarea din B7 este comparată cu fiecare dintre celulele de mai sus.

În consecință, pentru toate primele apariții, COUNTIF returnează 1; și se scade 1 la sfârșitul formulei pentru a restabili rangul inițial.

Pentru a doua apariție, COUNTIF returnează 2. Prin scăderea lui 1 se mărește rangul cu 1 punct, prevenind astfel dublurile. Dacă se întâmplă să existe 3 apariții ale aceleiași valori, COUNTIF()-1 va adăuga 2 la rangul lor, și așa mai departe.

Soluție alternativă pentru a rupe legăturile din Excel RANK

Un alt mod de a clasifica numerele în Excel în mod unic este prin adăugarea a două funcții COUNTIF:

• Prima funcție determină câte valori sunt mai mari sau mai mici decât numărul care urmează să fie clasificat, în funcție de clasificarea descrescătoare sau, respectiv, crescătoare.
• A doua funcție (cu "intervalul de extindere" $B$2:B2 ca în exemplul de mai sus) obține numărul de valori egal cu numărul.

De exemplu, pentru a clasifica numerele în mod unic, de la cel mai mare la cel mai mic, se utilizează următoarea formulă:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

După cum se arată în captura de ecran de mai jos, problema de departajare este rezolvată cu succes, iar fiecărui elev i se atribuie un rang unic:

Clasificare în Excel pe baza mai multor criterii

Exemplul anterior a demonstrat două soluții funcționale pentru o situație de departajare în Excel RANK. Cu toate acestea, poate părea nedrept ca numere egale să fie clasificate diferit doar pe baza poziției lor în listă. Pentru a îmbunătăți clasamentul, este posibil să doriți să adăugați încă un criteriu care să fie luat în considerare în caz de egalitate.

În eșantionul nostru de date, să adunăm scorurile totale din coloana C și să calculăm clasamentul după cum urmează:

• În primul rând, clasificați cu Punctaj matematică (criterii principale)
• În caz de egalitate, rupeți-o cu Scor total (criterii secundare)

Pentru a face acest lucru, vom folosi o formulă obișnuită RANK/RANK.EQ pentru a afla rangul și funcția COUNTIFS pentru a rupe o egalitate:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

În comparație cu exemplul de mai sus, această formulă de clasificare este mai obiectivă: Timothy este clasat pe locul 2 deoarece scorul său total este mai mare decât cel al Juliei:

Cum funcționează această formulă

Partea RANK a formulei este evidentă, iar funcția COUNTIFS face următoarele:

• Primul interval_criteriu / criterii pereche ($B$2:$B$7,$B2) numără aparițiile valorii pe care o clasificați. Vă rugăm să observați că fixăm gama cu referințe absolute, dar nu blocați criterii ($B2), astfel încât formula să verifice valoarea din fiecare rând în parte.
• Al doilea interval_criteriu / criterii pereche ($C$2:$C$7,">"&$C2) află câte scoruri totale sunt mai mari decât scorul total al valorii care se clasifică.

Deoarece COUNTIFS lucrează cu logica AND, adică numără numai celulele care îndeplinesc toate condițiile specificate, funcția COUNTIFS returnează 0 pentru Timothy, deoarece niciun alt elev cu același punctaj la matematică nu are un punctaj total mai mare. Prin urmare, rangul lui Timothy returnat de RANK.EQ rămâne neschimbat. Pentru Julia, funcția COUNTIFS returnează 1 deoarece un elev cu același punctaj la matematică are un punctaj total mai mare, deci numărul ei de rang esteDacă încă un elev ar avea același punctaj la matematică și un punctaj total mai mic decât cel al lui Timothy și Julia, rangul său ar fi mărit cu 2, și așa mai departe.

Soluții alternative pentru clasificarea numerelor cu criterii multiple

În locul funcției RANK sau RANK.EQ, ați putea utiliza COUNTIF pentru a verifica criteriile principale și COUNTIFS sau SUMPRODUCT pentru a rezolva un caz de egalitate:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Rezultatul acestor formule este exact același cu cel prezentat mai sus.

Cum se calculează rangul percentila în Excel

În statistică, un percentila (sau centile ) este valoarea sub care se situează un anumit procent de valori dintr-un anumit set de date. De exemplu, dacă 70 % dintre studenți au un scor la test egal sau mai mic decât cel obținut de dumneavoastră, percentila este 70.

Pentru a obține rangul percentila în Excel, utilizați funcția RANK sau RANK.EQ cu o valoare diferită de zero. comandă pentru a clasifica numerele de la cel mai mic la cel mai mare, apoi se împarte numărul de numere la numărul de numere. Astfel, se utilizează argumentul generic Formula Excel Percentile Rank se prezintă astfel:

Pentru a calcula rangul percentila al elevilor noștri, formula are următoarea formă:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Pentru ca rezultatele să fie afișate corect, asigurați-vă că ați setat parametrul Procentul formatul celulelor de formulă:

Cum se clasifică numerele în celule neadiacente

În situațiile în care este necesar să clasificați celule necontinue, furnizați acele celule direct în ref argument al formulei Excel Rank sub forma unei uniuni de referințe, blocând referințele cu semnul $. De exemplu:

=RANK(B2,($B$2,$B$4,$B$6))

Pentru a preveni erorile în celulele care nu sunt ordonate, includeți RANK în funcția IFERROR, astfel:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Vă rugăm să observați că un număr duplicat primește, de asemenea, un rang, deși celula B5 nu este inclusă în formulă:

Dacă aveți nevoie să clasificați mai multe celule necontinue, formula de mai sus poate deveni prea lungă. În acest caz, o soluție mai elegantă ar fi definirea unui interval denumit și referirea la acest nume în formulă:

=IFERROR(RANK(B2,range), "")

Cum să clasificați în Excel în funcție de grup

Atunci când lucrați cu intrări organizate într-un anumit tip de structură de date, datele pot aparține unor grupuri diferite și este posibil să doriți să clasificați numerele din fiecare grup în parte. Funcția RANK din Excel nu poate rezolva această provocare, așa că vom utiliza o formulă SUMPRODUCT mai complexă:

Clasament pe grupe în descrescător comandă:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Clasament pe grupe în ascendent comandă:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Unde:

• A2:A7 sunt grupuri atribuite numerelor.
• C2:C7 sunt numere care urmează să fie clasificate.

În acest exemplu, folosim prima formulă pentru a clasifica numerele din fiecare grup de la cel mai mare la cel mai mic:

Cum funcționează această formulă

În esență, formula evaluează 2 condiții:

• În primul rând, se verifică grupul (A2=$A$2:$A$7). Această parte returnează o matrice de TRUE și FALSE, în funcție de apartenența unui element din interval la același grup cu A2.
• În al doilea rând, se verifică scorul. Pentru a clasifica valorile de la cea mai mare la cea mai mică ( ordine descrescătoare ), utilizați condiția (C2<$C$2:$C$11), care returnează TRUE pentru celulele mai mari sau egale cu C2, iar în caz contrar FALSE.

Deoarece, în termenii Microsoft Excel, TRUE = 1 și FALSE = 0, înmulțirea celor două tablouri dă un tablou de 1 și 0, în care 1 este returnat numai pentru rândurile în care sunt îndeplinite ambele condiții.

Apoi, SUMPRODUCT însumează elementele din matricea 1 și 0, returnând astfel 0 pentru cel mai mare număr din fiecare grup. Și adăugați 1 la rezultat pentru a începe clasamentul cu 1.

Formula care clasifică numerele în cadrul grupurilor de la cel mai mic la cel mai mare ( ascendent comandă ) funcționează cu aceeași logică. Diferența constă în faptul că SUMPRODUCT returnează 0 pentru cel mai mic număr dintr-un anumit grup, deoarece niciun număr din acel grup nu îndeplinește a 2-a condiție (C2>$C$2:$C$7). Din nou, înlocuiți rangul zero cu rangul 1 prin adăugarea lui 1 la rezultatul formulei.

În loc de SUMPRODUCT, puteți utiliza funcția SUM pentru a aduna elementele tabloului. Dar acest lucru ar necesita utilizarea unei formule de tablou, completată prin Ctrl + Shift + Enter . De exemplu:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Cum se clasifică separat numerele pozitive și negative

Dacă lista dvs. de numere conține atât valori pozitive, cât și negative, funcția RANK din Excel le va clasifica pe toate în cel mai scurt timp. Dar dacă doriți ca numerele pozitive și negative să fie clasificate separat?

Cu numerele din celulele A2 - A10, utilizați una dintre următoarele formule pentru a obține un clasament individual pentru valorile pozitive și negative:

Ordonează numerele pozitive în ordine descrescătoare:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Clasificați numerele pozitive în ordine crescătoare:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),""),")

Clasificați numerele negative în ordine descrescătoare:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),""),")

Clasificați numerele negative în ordine crescătoare:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Rezultatele vor arăta cam așa:

Cum funcționează aceste formule

Pentru început, să descifrăm formula care clasifică numerele pozitive în descrescător comandă:

• În testul logic al funcției IF, verificați dacă numărul este mai mare decât zero.
• Dacă numărul este mai mare decât 0, funcția COUNTIF returnează numărul de valori mai mari decât numărul clasificat.

  În acest exemplu, A2 conține al doilea cel mai mare număr pozitiv, pentru care COUNTIF returnează 1, ceea ce înseamnă că există un singur număr mai mare decât acesta. Pentru a începe clasamentul cu 1, nu cu 0, adăugăm 1 la rezultatul formulei, astfel încât aceasta returnează un rang de 2 pentru A2.

• Dacă numărul este mai mare decât 0, formula returnează un șir gol ("").

Formula care ierarhizează numerele pozitive în ascendent comanda funcționează puțin diferit:

Dacă numărul este mai mare decât 0, primul COUNTIF obține numărul total de numere pozitive din setul de date, iar al doilea COUNTIF află câte valori sunt mai mari decât acel număr. Apoi, îl scadeți pe cel din urmă din primul și obțineți rangul dorit. În acest exemplu, există 5 valori pozitive, dintre care 1 este mai mare decât A2. Deci, scădeți 1 din 5, obținând astfel un rang de 4 pentru A2.

Formulele de clasificare a numerelor negative se bazează pe o logică similară.

Notă. Toate formulele de mai sus ignoră valorile zero deoarece 0 nu aparține nici setului numerelor pozitive, nici setului numerelor negative. Pentru a include zerourile în clasament, înlocuiți>0 și =0 și, respectiv, <=0, acolo unde logica formulei o cere.

De exemplu, pentru a clasifica numerele pozitive și zerourile de la cel mai mare la cel mai mic, utilizați această formulă: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Cum să clasificați datele în Excel ignorând valorile zero

După cum știți deja, o formulă RANK este Excel gestionează toate numerele: pozitive, negative și zerouri. Dar, în unele cazuri, dorim doar să clasificăm celulele cu date care ignoră valorile 0. Pe web, puteți găsi câteva soluții posibile pentru această sarcină, dar formula Excel RANK IF, cred că este cea mai universală:

Ordonează numerele descrescător, ignorând zero:

=IF($B2=0,""",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))))

Ordonează numerele în ordine crescătoare, ignorând zero:

=IF($B2=0,""",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1)))

Unde B2:B10 este intervalul de numere care urmează să fie clasificate.

Cel mai bun lucru la această formulă este că funcționează foarte bine atât pentru numere pozitive, cât și pentru numere negative, lăsând valorile zero în afara clasamentului:

Cum funcționează această formulă

La prima vedere, formula poate părea puțin complicată. La o privire mai atentă, logica este foarte simplă.

Iată cum formula Excel RANK IF clasifică numerele de la cel mai mare la cel mai mic, ignorând zerourile:

• Primul IF verifică dacă numărul este 0, iar dacă este, returnează un șir gol:

  IF($B2=0,""", ...)

• Dacă numărul nu este zero, al doilea IF verifică dacă este mai mare decât 0, iar dacă este, o funcție obișnuită RANK / RANK.EQ îi calculează rangul:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Dacă numărul este mai mic decât 0, se ajustează clasamentul în funcție de numărul de zerouri. În acest exemplu, există 4 numere pozitive și 2 zerouri. Deci, pentru cel mai mare număr negativ din B10, o formulă Excel RANK ar returna 7. Dar noi sărim zerouri și, prin urmare, trebuie să ajustăm clasamentul cu 2 puncte. Pentru aceasta, scădem numărul de zerouri din clasament:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Da, este atât de simplu! Formula de clasificare a numerelor de la cel mai mic la cel mai mare, ignorând zerourile, funcționează într-un mod similar și ar putea fi un exercițiu bun pentru a deduce logica sa :)

Cum se calculează rangul în Excel prin valoarea absolută

Atunci când aveți de-a face cu o listă de valori pozitive și negative, poate fi necesar să clasificați numerele în funcție de valorile lor absolute, ignorând semnul.

Sarcina poate fi îndeplinită cu ajutorul uneia dintre formulele de mai jos, în centrul căreia se află funcția ABS, care returnează valoarea absolută a unui număr:

Clasamentul ABS descrescător:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Clasamentul ABS în ordine crescătoare:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Ca urmare, numerele negative sunt clasificate ca și cum ar fi numere pozitive:

Cum se obțin N cele mai mari sau cele mai mici valori

Dacă doriți să obțineți un număr N real al celor mai mari sau mai mici valori, mai degrabă decât clasamentul acestora, utilizați funcția LARGE, respectiv SMALL.

De exemplu, putem obține primele 3 note ale elevilor noștri cu această formulă:

=LARGE($B$2:$B$7, $D3)

Unde B2:B7 este lista de scoruri, iar D3 este rangul dorit.

În plus, puteți prelua numele elevilor utilizând formula INDEX MATCH (cu condiția să nu existe punctaje duble în primele 3):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

În mod similar, puteți utiliza funcția SMALL pentru a extrage cele 3 valori inferioare:

=SMALL($B$2:$B$7, $D3)

Pentru a înțelege mai bine și, probabil, pentru a face inginerie inversă a formulelor discutate în acest tutorial, vă invităm să descărcați exemplul nostru de clasament în Excel.

Vă mulțumesc pentru lectură și sper să ne revedem pe blog săptămâna viitoare!