V učbeniku so pojasnjene posebnosti funkcij Excel Rank in prikazano, kako v Excelu razvrstiti podatke na podlagi več meril, razvrstiti podatke po skupinah, izračunati percentilni rang in še več.

Kadar morate določiti relativni položaj števila na seznamu številk, jih najlažje razvrstite po naraščajočem ali padajočem vrstnem redu. Če razvrščanje iz kakšnega razloga ni mogoče, je formula Rank v Excelu odlično orodje za to nalogo.

Funkcija Excel RANK

Funkcija RANK v Excelu vrne vrstni red (ali rang) številčne vrednosti v primerjavi z drugimi vrednostmi na istem seznamu. Z drugimi besedami, pove vam, katera vrednost je najvišja, druga najvišja itd.

V razvrščenem seznamu je rang določenega števila njegov položaj. Funkcija RANK v Excelu lahko določi rang, ki se začne z največjo vrednostjo (kot da je razvrščena v padajočem vrstnem redu) ali najmanjšo vrednostjo (kot da je razvrščena v naraščajočem vrstnem redu).

Sintaksa Excelove funkcije RANK je naslednja:

Kje:

Številka (obvezno) - vrednost, katere rang želite poiskati.

Ref (obvezno) - seznam številčnih vrednosti, ki se razvrstijo glede na rangiranje. Lahko se navede kot polje številk ali sklic na seznam številk.

Naročilo (neobvezno) - število, ki določa, kako razvrstiti vrednosti:

• Če je vrednost 0 ali je izpuščena, so vrednosti razvrščene v padajočem vrstnem redu, tj. od največje do najmanjše.
• Če je vrednost 1 ali katera koli druga neničelna vrednost, so vrednosti razvrščene po naraščajočem vrstnem redu, tj. od najmanjše do največje.

Excelova funkcija RANK.EQ

RANK.EQ je izboljšana različica funkcije RANK, ki je bila uvedena v Excelu 2010. Ima enako sintakso kot RANK in deluje po isti logiki: če je več vrednosti enako razvrščenih, se vsem tem vrednostim dodeli najvišji rang (EQ pomeni "enak").

V Excelu 2007 in nižjih različicah morate vedno uporabljati funkcijo RANK. V Excelu 2010, Excelu 2013 in Excelu 2016 lahko uporabite funkcijo RANK ali RANK.EQ. Vendar bi bilo pametno uporabiti funkcijo RANK.EQ, saj se lahko funkcija RANK kadar koli ukine.

Funkcija Excel RANK.AVG

RANK.AVG je še ena funkcija za iskanje ranga v Excelu, ki je na voljo samo v Excelu 2010, Excelu 2013, Excelu 2016 in pozneje.

Ima enako sintakso kot drugi dve funkciji:

Razlika je v tem, da če ima več števil enak rang, se povprečni rang (AVG pomeni "povprečje").

4 stvari, ki jih morate vedeti o razvrstitvi v Excelu

1. Vsaka formula za rangiranje v Excelu deluje samo za numerične vrednosti: pozitivna in negativna števila, ničle, datumske in časovne vrednosti. ref se ne upošteva.
2. Vse funkcije RANK vrnejo enak rang za podvojene vrednosti in preskočijo nadaljnje razvrščanje, kot je prikazano v spodnjem primeru.
3. V Excelu 2010 in novejših različicah je bila funkcija RANK nadomeščena s funkcijama RANK.EQ in RANK.AVG. Zaradi združljivosti za nazaj funkcija RANK še vedno deluje v vseh različicah programa Excel, vendar v prihodnosti morda ne bo več na voljo.
4. Če številka se ne nahaja v ref , bi vsaka funkcija Excel Rank vrnila napako #N/A.

Osnovna Excelova formula za rangiranje (od najvišjega do najnižjega)

Če želite bolje razumeti razvrščanje podatkov v Excelu, si oglejte to zaslonsko sliko:

Vse tri formule razvrščajo številke v stolpcu B v padajoči vrstni red (v Naročite na . argument je izpuščen):

V vseh različicah programa Excel 2003-2016:

=RANK($B2,$B$2:$B$7)

V Excelu 2010 - 2016:

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

Razlika je v tem, kako ti formuli obdelujeta podvojene vrednosti. Kot vidite, se ista ocena pojavi dvakrat, v celicah B5 in B6, kar vpliva na nadaljnje razvrščanje:

• Formuli RANK in RANK.EQ dajeta obema podvojenima rezultatoma rang 2. Naslednji najvišji rezultat (Daniela) je uvrščen na 4. mesto. Rang 3 ni dodeljen nikomur.
• Formula RANK.AVG v ozadju vsakemu podvojencu dodeli različen rang (2 in 3 v tem primeru) in vrne povprečje teh rangov (2,5). 3. rang ponovno ni dodeljen nikomur.

Kako uporabiti RANK v Excelu - primeri formul

Pravijo, da je pot do odličnosti tlakovana z vajo. Da bi se bolje naučili uporabljati funkcijo RANK v Excelu, samostojno ali v kombinaciji z drugimi funkcijami, pripravimo rešitve za nekaj resničnih nalog.

Kako v Excelu razvrstiti od najnižje do najvišje vrednosti

Kot je prikazano v zgornjem primeru, za razvrščanje številk od najvišje do najnižje uporabite eno od Excelovih formul Rank z Naročite na . argument nastavljen na 0 ali izpuščen (privzeto).

imeti številka razvrščene glede na druge številke, razvrščene v naraščajoči vrstni red , v neobvezni tretji argument vpišite 1 ali katero koli drugo neničelno vrednost.

Če želite na primer razvrstiti šprinterske čase učencev na 100 metrov, lahko uporabite eno od spodnjih formul:

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Bodite pozorni, da območje zaklenemo v ref argumenta z uporabo absolutnih referenc na celice, tako da se ne bo spremenil, ko bomo formulo kopirali navzdol po stolpcu.

Tako je najmanjša vrednost (najhitrejši čas) uvrščena na 1. mesto, največja vrednost (najpočasnejši čas) pa dobi najnižji rang 6. Enaki časi (B2 in B7) imajo enak rang.

Kako edinstveno razvrstiti podatke v Excelu

Kot smo že poudarili, vse funkcije Excel Rank vrnejo enak rang za elemente enake vrednosti. Če tega ne želite, uporabite eno od naslednjih formul, da rešite situacije z neodločenim izidom in podate edinstveni rang za vsako številko.

Edinstvena razvrstitev od najvišje do najnižje

Če želite razvrstiti matematične rezultate naših učencev v padajočem vrstnem redu, uporabite to formulo:

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Edinstvena razvrstitev od najnižje do najvišje

Če želite rezultate teka na 100 metrov razvrstiti po naraščajočem vrstnem redu brez podvojitev, uporabite to formulo:

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Kako te formule delujejo

Kot ste morda opazili, je edina razlika med obema formulama Naročite na . argumenta funkcije RANK.EQ: izpustite, če želite vrednosti razvrstiti padajoče, in 1, če želite razvrstiti naraščajoče.

V obeh formulah je to funkcija COUNTIF s pametno uporabo relativnih in absolutnih sklicev na celice. Na kratko, z uporabo COUNTIF ugotovite, koliko pojavitev uvrščenega števila je v zgornjih celicah, vključno s celico števila. V najvišji vrstici, v katero vnesete formulo, je obseg sestavljen iz ene celice ($B$2:B2). Ker pa ste zaklenili samo celicoprva referenca ($B$2), zadnja relativna referenca (B2) pa se spremeni glede na vrstico, v katero se kopira formula. Tako se za vrstico 7 območje razširi na $B$2:B7, vrednost v B7 pa se primerja z vsako od zgornjih celic.

Zato se za vse 1. pojavitve COUNTIF vrne 1, na koncu formule pa odštejete 1, da povrnete prvotni vrstni red.

Za 2. pojavitev COUNTIF vrne 2. Z odštevanjem 1 povečate rang za 1 točko, s čimer preprečite podvajanje. Če se zgodi, da so 3 pojavitve iste vrednosti, COUNTIF()-1 doda 2 k njihovemu rangu in tako naprej.

Alternativna rešitev za prekinitev vezi Excel RANK

Drug način za enolično razvrščanje številk v Excelu je s seštevanjem dveh funkcij COUNTIF:

• Prva funkcija določi, koliko vrednosti je večjih ali manjših od števila, ki ga želite razvrstiti, odvisno od tega, ali razvrščate padajoče ali naraščajoče.
• Druga funkcija (z "razširitvenim območjem" $B$2:B2 kot v zgornjem primeru) dobi število vrednosti, ki je enako številu.

Če želite na primer števila razvrstiti od najvišjega do najnižjega, uporabite to formulo:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIF($B$2:B2,B2)

Kot je prikazano na spodnji sliki zaslona, je izenačitev uspešno rešena in vsakemu učencu je dodeljena edinstvena uvrstitev:

Razvrščanje v Excelu na podlagi več meril

Prejšnji primer je pokazal dve delujoči rešitvi za primer enakega vrstnega reda v programu Excel. Vendar se morda zdi nepravično, da so enake številke različno razvrščene samo na podlagi njihovega položaja na seznamu. Če želite izboljšati razvrščanje, boste morda želeli dodati še eno merilo, ki se bo upoštevalo v primeru enakega števila točk.

V našem vzorčnem naboru podatkov seštejemo skupne ocene v stolpcu C in izračunamo rang na naslednji način:

• Najprej se uvrstite z Matematični rezultat (glavna merila)
• Če je rezultat neodločen, ga prekinite z Skupni rezultat (sekundarna merila)

Za iskanje ranga bomo uporabili običajno formulo RANK/RANK.EQ, za prekinitev neodločenega rezultata pa funkcijo COUNTIFS:

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)

V primerjavi z zgornjim primerom je ta formula za razvrščanje bolj objektivna: Timotej je uvrščen na 2. mesto, ker je njegov skupni rezultat višji od Julijinega:

Kako deluje ta formula

Del formule RANK je očiten, funkcija COUNTIFS pa naredi naslednje:

• Prvi kriterij_območje / merila ($B$2:$B$7,$B2) šteje pojavitve vrednosti, ki jo razvrščate. obseg z absolutnimi referencami, vendar ne zaklenite merila ($B2), tako da formula preveri vrednost v vsaki vrstici posebej.
• Drugi kriterij_območje / merila par ($C$2:$C$7,">"&$C2) ugotovi, koliko skupnih ocen je več kot skupna ocena vrednosti, ki se razvršča.

Ker funkcija COUNTIFS deluje z logiko AND, tj. šteje samo celice, ki izpolnjujejo vse navedene pogoje, za Timoteja vrne 0, ker noben drug učenec z enakim rezultatom iz matematike nima višjega skupnega rezultata. Zato je Timotejev rang, ki ga vrne funkcija RANK.EQ, nespremenjen. Za Julijo funkcija COUNTIFS vrne 1, ker ima en učenec z enakim rezultatom iz matematike višji skupni rezultat, zato je njeno število rangaČe bi imel še en učenec enak rezultat iz matematike in nižji skupni rezultat od Timoteja in Julije, bi se njegova uvrstitev povečala za 2 in tako naprej.

Alternativne rešitve za razvrščanje številk z več merili

Namesto funkcije RANK ali RANK.EQ lahko uporabite COUNTIF za preverjanje glavnih meril in COUNTIFS ali SUMPRODUCT za reševanje enakega števila točk:

=COUNTIF($B$2:$B$7,">"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,">"&$C2)+1

=COUNTIF($B$2:$B$7,">"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Rezultati teh formul so popolnoma enaki, kot je prikazano zgoraj.

Kako izračunati percentilni rang v Excelu

V statistiki je percentil (ali centil ) je vrednost, pod katero je določen odstotek vrednosti v danem naboru podatkov. Če je na primer 70 % učencev enakih ali nižjih od vašega rezultata testa, je vaš percentilni rang 70.

Če želite v Excelu pridobiti percentilni rang, uporabite funkcijo RANK ali RANK.EQ z neničelno vrednostjo Naročite na . za razvrstitev številk od najmanjšega do največjega, nato pa rang deli s številom številk. Excelova formula Percentile Rank se glasi:

Za izračun percentilnega ranga naših učencev se uporablja naslednja formula:

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Če želite, da se rezultati pravilno prikažejo, se prepričajte, da ste nastavili Odstotek obliko v celice formule:

Kako razvrstiti številke v nesorodnih celicah

Kadar morate razvrstiti nesorodne celice, te celice navedite neposredno v ref argument vaše formule Excel Rank v obliki referenčne zveze, pri čemer reference zaklenite z znakom $. Na primer:

=RANK(B2,($B$2,$B$4,$B$6))

Če želite preprečiti napake v celicah, ki niso razvrščene, zavijte funkcijo RANK v funkcijo IFERROR, kot sledi:

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Opazite, da je podvojeni številki prav tako dodeljen rang, čeprav celica B5 ni vključena v formulo:

Če morate razvrstiti več celic, ki se ne stikajo, bo zgornja formula morda predolga. V tem primeru bi bila elegantnejša rešitev opredelitev poimenovanega območja in sklicevanje na to ime v formuli:

=IFERROR(RANK(B2,razpon), "")

Kako v Excelu razvrstiti po skupinah

Pri delu z vnosi, organiziranimi v neki podatkovni strukturi, lahko podatki pripadajo različnim skupinam in morda boste želeli razvrstiti številke znotraj vsake skupine posebej. Excelova funkcija RANK ne more rešiti tega izziva, zato bomo uporabili kompleksnejšo formulo SUMPRODUCT:

Razvrstitev po skupinah v padajoče naročite:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Razvrstitev po skupinah v naraščajoče naročite:

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Kje:

• A2:A7 so skupine, dodeljene številkam.
• C2:C7 so številke, ki jih je treba razvrstiti.

V tem primeru uporabimo prvo formulo za razvrstitev števil v vsaki skupini od največjega do najmanjšega:

Kako deluje ta formula

V formuli sta ocenjena dva pogoja:

• Najprej preverite skupino (A2=$A$2:$A$7). Ta del vrne polje TRUE in FALSE glede na to, ali element območja pripada isti skupini kot A2.
• Drugič, preverite oceno. Vrednosti razvrstite od največje do najmanjše ( padajoči vrstni red ), uporabite pogoj (C2<$C$2:$C$11), ki vrne TRUE za celice, večje ali enake C2, in FALSE v nasprotnem primeru.

Ker je v programu Microsoft Excel TRUE = 1 in FALSE = 0, z množenjem obeh polj dobimo polje 1 in 0, pri čemer se 1 vrne samo za vrstice, v katerih sta izpolnjena oba pogoja.

Nato SUMPRODUCT sešteje elemente polj 1 in 0, tako da vrne 0 za največje število v vsaki skupini. Rezultatu dodate 1, da se razvrščanje začne z 1.

Formula, ki razvršča števila v skupine od najmanjšega do največjega ( naraščajoče Naročite na . ) deluje po isti logiki. Razlika je v tem, da SUMPRODUCT vrne 0 za najmanjše število v določeni skupini, saj nobeno število v tej skupini ne izpolnjuje 2. pogoja (C2>$C$2:$C$7). Ponovno nadomestite ničelni rang s 1. rangom tako, da rezultatu formule dodate 1.

Namesto funkcije SUMPRODUCT lahko za seštevanje elementov polja uporabite funkcijo SUM. Pri tem pa je treba uporabiti formulo polja, ki jo dokončate s kombinacijo tipk Ctrl + Shift + Enter . Na primer:

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Kako ločeno razvrstiti pozitivna in negativna števila

Če vaš seznam števil vsebuje pozitivne in negativne vrednosti, jih bo funkcija RANK v Excelu v trenutku razvrstila vse. Kaj pa, če želite pozitivna in negativna števila razvrstiti ločeno?

S številkami v celicah A2 do A10 uporabite eno od naslednjih formul, da dobite posamezne razvrstitve za pozitivne in negativne vrednosti:

Pozitivna števila razvrstite padajoče:

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Pozitivna števila razvrstite naraščajoče:

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,">"&$A2),"")

Negativna števila razvrstite padajoče:

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<"&$A2),"")

Negativna števila razvrstite naraščajoče:

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Rezultati bodo videti približno tako:

Kako te formule delujejo

Za začetek razčlenimo formulo, ki pozitivna števila razvršča v padajoče naročite:

• Pri logičnem preizkusu funkcije IF preverite, ali je število večje od nič.
• Če je število večje od 0, funkcija COUNTIF vrne število vrednosti, ki so višje od števila, ki ga razvrščamo.

  V tem primeru A2 vsebuje drugo največje pozitivno število, za katerega COUNTIF vrne 1, kar pomeni, da je samo eno število večje od njega. Da bi razvrščanje začeli z 1 in ne z 0, rezultatu formule dodamo 1, tako da vrne rang 2 za A2.

• Če je število večje od 0, formula vrne prazen niz ("").

Formula, ki pozitivna števila razvršča v naraščajoče naročanje deluje nekoliko drugače:

Če je število večje od 0, se s prvim COUNTIF ugotovi skupno število pozitivnih števil v podatkovnem nizu, z drugim COUNTIF pa se ugotovi, koliko vrednosti je večjih od tega števila. Nato se od prvega odšteje drugo in dobi želeni rang. V tem primeru je 5 pozitivnih vrednosti, od katerih je 1 večja od A2. Zato se od 5 odšteje 1 in tako dobi rang 4 za A2.

Formule za razvrščanje negativnih števil temeljijo na podobni logiki.

Opomba: Vse zgornje formule ignoriranje ničelnih vrednosti ker 0 ne spada niti v množico pozitivnih niti v množico negativnih števil. Če želite v razvrstitev vključiti ničle, zamenjajte>0 in =0 oziroma <=0, kjer to zahteva logika formule.

Če želite na primer pozitivna števila in ničle razvrstiti od največjega do najmanjšega, uporabite to formulo: =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Kako razvrstiti podatke v Excelu brez upoštevanja ničelnih vrednosti

Kot že veste, formula RANK v Excelu obravnava vsa števila: pozitivna, negativna in ničle. V nekaterih primerih pa želimo le razvrstiti celice s podatki brez vrednosti 0. Na spletu lahko najdete nekaj možnih rešitev za to nalogo, vendar je formula Excel RANK IF najbolj univerzalna:

Številke razvrstite padajoče, pri čemer zanemarite ničlo:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Številke razvrstite naraščajoče, ne da bi upoštevali ničlo:

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1))

Pri čemer je B2:B10 območje številk, ki jih je treba razvrstiti.

Najboljša lastnost te formule je, da odlično deluje tako za pozitivna kot negativna števila, pri čemer ničelnih vrednosti ne upošteva:

Kako deluje ta formula

Na prvi pogled se zdi formula nekoliko zapletena, vendar je po natančnejšem pregledu logika zelo preprosta.

Tukaj je prikazano, kako Excelova formula RANK IF razvršča števila od največjega do najmanjšega, pri čemer ne upošteva ničel:

• Prvi IF preveri, ali je število 0, in če je, vrne prazen niz:

  IF($B2=0,"", ...)

• Če število ni enako nič, se v drugem ukazu IF preveri, ali je večje od 0, in če je, se z običajno funkcijo RANK / RANK.EQ izračuna njegov rang:

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Če je število manjše od 0, prilagodite rang za število ničel. V tem primeru so 4 pozitivna števila in 2 ničli. Tako bi za največje negativno število v B10 Excelova formula RANK vrnila 7. Toda ničle smo preskočili, zato moramo rang prilagoditi za 2 točki. Za to od ranga odštejemo število ničel:

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

Formula za razvrščanje števil od najmanjšega do največjega brez upoštevanja ničel deluje na podoben način in lahko bi bila dobra možganska vaja, če bi sklepali o njeni logiki :)

Kako izračunati rang v Excelu z absolutno vrednostjo

Pri obravnavi seznama pozitivnih in negativnih vrednosti je morda treba števila razvrstiti po absolutnih vrednostih, pri čemer se ne upošteva znak.

To nalogo lahko opravite z eno od spodnjih formul, v središču katere je funkcija ABS, ki vrne absolutno vrednost števila:

Razvrstitev ABS po padajočem vrstnem redu:

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7")))+1

Razvrstite ABS naraščajoče:

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7")))+1

Zato so negativna števila razvrščena tako, kot da bi bila pozitivna:

Kako dobiti N največjih ali najmanjših vrednosti

Če želite dobiti dejansko število N največjih ali najmanjših vrednosti in ne njihovega vrstnega reda, uporabite funkcijo LARGE oziroma SMALL.

S to formulo lahko na primer dobimo tri najboljše rezultate naših učencev:

=LARGE($B$2:$B$7, $D3)

Pri čemer je B2:B7 seznam rezultatov, D3 pa je želeni rang.

Poleg tega lahko imena učencev pridobite z uporabo formule INDEX MATCH (če med prvimi tremi rezultati ni podvojenih rezultatov):

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

Podobno lahko uporabite funkcijo SMALL, če želite izvleči spodnje tri vrednosti:

=SMALL($B$2:$B$7, $D3)

Da bi bolje razumeli formule, obravnavane v tem učbeniku, in jih verjetno tudi izvedli, lahko prenesete naš delovni zvezek Excel z vzorcem rangiranja.

Zahvaljujem se vam za branje in upam, da se naslednji teden vidimo na našem blogu!