Le tutoriel explique les spécificités des fonctions de classement d'Excel et montre comment effectuer un classement dans Excel sur la base de critères multiples, classer des données par groupe, calculer le rang centile, et plus encore.

Lorsque vous devez déterminer la position relative d'un nombre dans une liste de nombres, le plus simple est de trier les nombres dans l'ordre croissant ou décroissant. Si, pour une raison quelconque, le tri n'est pas possible, une formule de classement dans Excel est l'outil parfait pour faire le travail.

Fonction RANK d'Excel

La fonction RANK d'Excel renvoie l'ordre (ou le rang) d'une valeur numérique par rapport aux autres valeurs de la même liste. En d'autres termes, elle vous indique quelle valeur est la plus élevée, la deuxième plus élevée, etc.

La fonction RANK d'Excel peut déterminer le rang en commençant par la plus grande valeur (comme si elle était triée par ordre décroissant) ou la plus petite valeur (comme si elle était triée par ordre croissant).

La syntaxe de la fonction RANK d'Excel est la suivante :

Où :

Numéro (obligatoire) - la valeur dont vous souhaitez trouver le rang.

Réf. (obligatoire) - une liste de valeurs numériques à classer. Elle peut être fournie sous la forme d'un tableau de nombres ou d'une référence à la liste de nombres.

Commandez (facultatif) - un nombre qui spécifie comment classer les valeurs :

• Si 0 ou omis, les valeurs sont classées par ordre décroissant, c'est-à-dire du plus grand au plus petit.
• S'il s'agit de 1 ou de toute autre valeur non nulle, les valeurs sont classées par ordre croissant, c'est-à-dire de la plus petite à la plus grande.

Fonction Excel RANK.EQ

RANK.EQ est une version améliorée de la fonction RANK, introduite dans Excel 2010. Elle a la même syntaxe que RANK et fonctionne selon la même logique : si plusieurs valeurs sont classées de manière égale, le rang le plus élevé est attribué à toutes ces valeurs (EQ signifie "égal").

Dans Excel 2007 et les versions inférieures, vous devez toujours utiliser la fonction RANK. Dans Excel 2010, Excel 2013 et Excel 2016, vous pouvez utiliser soit la fonction RANK, soit la fonction RANK.EQ. Cependant, il serait sage d'utiliser la fonction RANK.EQ car la fonction RANK peut être abandonnée à tout moment.

Fonction Excel RANK.AVG

RANK.AVG est une autre fonction pour trouver le rang dans Excel qui est disponible uniquement dans Excel 2010, Excel 2013, Excel 2016 et plus.

Elle a la même syntaxe que les deux autres fonctions :

La différence est que si plus d'un numéro a le même rang, l'ordre de priorité est le suivant rang moyen est retourné (AVG signifie "moyenne").

4 choses que vous devez savoir sur le RANK dans Excel

1. Toute formule de rang dans Excel ne fonctionne que pour les valeurs numériques : les nombres positifs et négatifs, les zéros, les valeurs de date et d'heure. Les valeurs non numériques dans la formule de rang sont les suivantes réf. sont ignorés.
2. Toutes les fonctions RANK renvoient le même rang pour les valeurs dupliquées, et sautent le classement suivant, comme le montre l'exemple ci-dessous.
3. Dans Excel 2010 et les versions ultérieures, la fonction RANK a été remplacée par RANK.EQ et RANK.AVG. Pour des raisons de compatibilité ascendante, RANK fonctionne toujours dans toutes les versions d'Excel, mais il se peut qu'elle ne soit plus disponible à l'avenir.
4. Si numéro ne se trouve pas dans réf. toute fonction de classement Excel renverrait l'erreur #N/A.

Formule de classement Excel de base (du plus élevé au plus bas)

Pour mieux comprendre le classement des données dans Excel, veuillez consulter cette capture d'écran :

Les trois formules classent les nombres de la colonne B en ordre décroissant (le commander argument omis) :

Dans toutes les versions d'Excel 2003 - 2016 :

=RANK($B2,$B$2:$B$7)

Dans Excel 2010 - 2016 :

=RANK.EQ($B2,$B$2:$B$7)

=RANK.AVG($B2,$B$2:$B$7)

La différence réside dans la manière dont ces formules traitent les valeurs en double. Comme vous le voyez, le même score apparaît deux fois, dans les cellules B5 et B6, ce qui affecte le classement ultérieur :

• Les formules RANK et RANK.EQ donnent un rang de 2 aux deux scores en double. Le score suivant (Daniela) est classé 4ème. Un rang de 3 n'est donné à personne.
• La formule RANK.AVG attribue un rang différent à chaque doublon en coulisses (2 et 3 dans cet exemple) et renvoie la moyenne de ces rangs (2,5). Là encore, le 3e rang n'est attribué à personne.

Comment utiliser RANK dans Excel - exemples de formules

Le chemin de l'excellence, dit-on, est pavé de pratique. Donc, pour mieux apprendre à utiliser la fonction RANK dans Excel, seule ou en combinaison avec d'autres fonctions, trouvons des solutions à quelques tâches réelles.

Comment classer dans Excel du plus bas au plus haut

Comme le montre l'exemple ci-dessus, pour classer les nombres du plus élevé au plus bas, vous utilisez l'une des formules de classement d'Excel avec l'attribut commander argument défini à 0 ou omis (par défaut).

Pour avoir numéro classé par rapport à d'autres nombres triés en ordre ascendant , mettez 1 ou toute autre valeur non nulle dans le troisième argument facultatif.

Par exemple, pour classer les temps de sprint sur 100 mètres des élèves, vous pouvez utiliser l'une des formules suivantes :

=RANK(B2,$B$2:$B$7,1)

=RANK.EQ(B2,$B$2:$B$7,1)

Veuillez noter que nous bloquons la gamme dans l'interface de l'utilisateur. réf. en utilisant des références de cellule absolues, afin qu'il ne change pas lorsque nous copions la formule vers le bas de la colonne.

En conséquence, la valeur la plus faible (temps le plus rapide) est classée au 1er rang et la valeur la plus élevée (temps le plus lent) est classée au 6e rang. Les temps égaux (B2 et B7) sont classés au même rang.

Comment classer des données dans Excel de manière unique

Comme nous l'avons souligné précédemment, toutes les fonctions de classement d'Excel renvoient le même rang pour des éléments de valeur égale. Si ce n'est pas ce que vous voulez, utilisez l'une des formules suivantes pour résoudre les situations d'égalité et donner un rang à chaque élément. rang unique à chaque numéro.

Classement unique du plus élevé au plus bas

Pour classer les résultats en mathématiques de nos élèves uniquement par ordre décroissant, utilisez cette formule :

=RANK.EQ(B2,$B$2:$B$7)+COUNTIF($B$2:B2,B2)-1

Classement unique du plus bas au plus haut

Pour classer les résultats des courses de 100 mètres dans l'ordre croissant, sans doublons, utilisez cette formule :

=RANK.EQ(B2,$B$2:$B$7,1) + COUNTIF($B$2:B2,B2)-1

Comment fonctionnent ces formules

Comme vous l'avez peut-être remarqué, la seule différence entre les deux formules est l'élément commander argument de la fonction RANK.EQ : omis pour classer les valeurs par ordre décroissant, 1 pour les classer par ordre croissant.

Dans les deux formules, c'est la fonction COUNTIF avec l'utilisation intelligente des références de cellules relatives et absolues qui fait l'affaire. En bref, vous utilisez COUNTIF pour trouver combien d'occurrences du nombre à classer il y a dans les cellules ci-dessus, y compris la cellule du nombre. Dans la ligne supérieure où vous entrez la formule, la plage consiste en une seule cellule ($B$2:B2). Mais parce que vous ne verrouillez que la celluleAinsi, pour la ligne 7, la plage s'étend à $B$2:B7, et la valeur de B7 est comparée à chacune des cellules ci-dessus.

Par conséquent, pour toutes les 1ères occurrences, COUNTIF renvoie 1 ; et vous soustrayez 1 à la fin de la formule pour rétablir le rang initial.

Pour les secondes occurrences, COUNTIF renvoie 2. En soustrayant 1, vous incrémentez le rang d'un point, évitant ainsi les doublons. S'il y a 3 occurrences de la même valeur, COUNTIF()-1 ajoutera 2 à leur rang, et ainsi de suite.

Solution alternative pour briser les liens RANK d'Excel

Une autre façon de classer des nombres dans Excel de manière unique consiste à additionner deux fonctions COUNTIF :

• La première fonction détermine combien de valeurs sont supérieures ou inférieures au nombre à classer, selon que vous effectuez un classement descendant ou ascendant, respectivement.
• La deuxième fonction (avec la "plage d'expansion" $B$2:B2 comme dans l'exemple ci-dessus) obtient le nombre de valeurs égal au nombre.

Par exemple, pour classer les nombres de manière unique, du plus élevé au plus bas, vous utiliserez la formule suivante :

=COUNTIF($B$2:$B$7,"> ;"&$B2)+COUNTIF($B$2:B2,B2)

Comme le montre la capture d'écran ci-dessous, le bris d'égalité est résolu avec succès, et un rang unique est attribué à chaque étudiant :

Classement dans Excel sur la base de critères multiples

L'exemple précédent a montré deux solutions efficaces pour résoudre une situation de rupture d'égalité dans Excel RANK. Cependant, il peut sembler injuste que des nombres égaux soient classés différemment uniquement en fonction de leur position dans la liste. Pour améliorer votre classement, vous pouvez ajouter un critère supplémentaire à prendre en compte en cas d'égalité.

Dans notre échantillon de données, additionnons les scores totaux de la colonne C et calculons le rang comme suit :

• Tout d'abord, le classement avec Score en mathématiques (critères principaux)
• En cas d'égalité, il faut trancher avec Score total (critères secondaires)

Pour ce faire, nous utiliserons une formule classique RANK/RANK.EQ pour trouver le rang, et la fonction COUNTIFS pour départager les ex-aequo :

=RANK.EQ($B2,$B$2:$B$7)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,"> ;"&$C2)

Par rapport à l'exemple ci-dessus, cette formule de classement est plus objective : Timothy est classé 2e parce que son score total est plus élevé que celui de Julia :

Comment fonctionne cette formule

La partie RANK de la formule est évidente, et la fonction COUNTIFS fait ce qui suit :

• Le premier critères_plage / critères ($B$2:$B$7,$B2) compte les occurrences de la valeur que vous classez. Veuillez noter que nous corrigeons le paramètre gamme avec des références absolues, mais ne verrouillez pas les critères La formule vérifie donc la valeur de chaque ligne individuellement.
• Le deuxième critères_plage / critères pair ($C$2:$C$7,"> ;"&$C2) permet de savoir combien de notes totales sont supérieures à la note totale de la valeur classée.

Comme la fonction COUNTIFS fonctionne avec la logique AND, c'est-à-dire qu'elle ne compte que les cellules qui remplissent toutes les conditions spécifiées, elle renvoie 0 pour Timothy puisqu'aucun autre élève ayant la même note en mathématiques n'a une note totale plus élevée. Par conséquent, le rang de Timothy renvoyé par RANK.EQ reste inchangé. Pour Julia, la fonction COUNTIFS renvoie 1 parce qu'un élève ayant la même note en mathématiques a une note totale plus élevée, son rang est donc le suivantSi un autre élève avait le même score en mathématiques et un score total inférieur à celui de Timothy et Julia, son rang serait augmenté de 2, et ainsi de suite.

Solutions alternatives pour classer les nombres avec des critères multiples

Au lieu de la fonction RANK ou RANK.EQ, vous pourriez utiliser COUNTIF pour vérifier les critères principaux, et COUNTIFS ou SUMPRODUCT pour résoudre une rupture d'égalité :

=COUNTIF($B$2:$B$7,"> ;"&$B2)+COUNTIFS($B$2:$B$7,$B2,$C$2:$C$7,"> ;"&$C2)+1

=COUNTIF($B$2:$B$7,"> ;"&B2)+SUMPRODUCT(--($C$2:$C$7=C2),--($B$2:$B$7>B2))+1

Le résultat de ces formules est exactement le même que celui indiqué ci-dessus.

Comment calculer le rang centile dans Excel ?

En statistiques, un percentile (ou centile ) est la valeur en dessous de laquelle se situe un certain pourcentage de valeurs dans un ensemble de données donné. Par exemple, si 70 % des étudiants ont une note égale ou inférieure à la vôtre, votre rang centile est de 70.

Pour obtenir le rang centile dans Excel, utilisez la fonction RANK ou RANK.EQ avec une valeur non nulle. commander pour classer les nombres du plus petit au plus grand, puis diviser le rang par le nombre de nombres. Ainsi, l'argument générique Formule Excel du rang centile va comme suit :

Pour calculer le rang percentile de nos étudiants, la formule prend la forme suivante :

=RANK.EQ(B2,$B$2:$B$7,1)/COUNT($B$2:$B$7)

Pour que les résultats s'affichent correctement, assurez-vous de définir le paramètre Pourcentage dans les cellules de formule :

Comment classer des nombres dans des cellules non adjacentes ?

Dans les situations où vous devez classer des cellules non contiguës, fournissez ces cellules directement dans le fichier réf. de votre formule Excel Rank sous la forme d'une union de références, en verrouillant les références avec le signe $. Par exemple :

=RANK(B2,($B$2,$B$4,$B$6))

Pour éviter les erreurs dans les cellules non classées, intégrez RANK dans la fonction IFERROR, comme suit :

=IFERROR(RANK(B2,($B$2,$B$4,$B$6)), "")

Veuillez noter qu'un numéro en double se voit également attribuer un rang, bien que la cellule B5 ne soit pas incluse dans la formule :

Si vous devez classer plusieurs cellules non contiguës, la formule ci-dessus peut devenir trop longue. Dans ce cas, une solution plus élégante consiste à définir une plage nommée et à faire référence à ce nom dans la formule :

=IFERROR(RANK(B2,range), "")

Comment classer dans Excel par groupe

Lorsque vous travaillez avec des entrées organisées dans une sorte de structure de données, les données peuvent appartenir à différents groupes et vous pouvez vouloir classer les nombres dans chaque groupe individuellement. La fonction RANK d'Excel ne peut pas résoudre ce problème, nous allons donc utiliser une formule SUMPRODUCT plus complexe :

Classement par groupe en descendant l'ordre :

=SUMPRODUCT((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Classement par groupe en ascendant l'ordre :

=SUMPRODUCT((A2=$A$2:$A$7)*(C2>$C$2:$C$7))+1

Où :

• A2:A7 sont des groupes affectés à des numéros.
• C2:C7 sont des numéros à classer.

Dans cet exemple, nous utilisons la première formule pour classer les nombres dans chaque groupe du plus grand au plus petit :

Comment fonctionne cette formule

Essentiellement, la formule évalue 2 conditions :

• Tout d'abord, vous vérifiez le groupe (A2=$A$2:$A$7). Cette partie renvoie un tableau de VRAI et de FAUX selon qu'un élément de la plage appartient au même groupe que A2.
• Ensuite, vous vérifiez le score. Pour classer les valeurs du plus grand au plus petit ( ordre décroissant ), utilisez la condition (C2<$C$2:$C$11), qui renvoie VRAI pour les cellules supérieures ou égales à C2, FAUX sinon.

Étant donné qu'en termes de Microsoft Excel, VRAI = 1 et FAUX = 0, la multiplication des deux tableaux donne un tableau de 1 et de 0, où 1 est renvoyé uniquement pour les lignes dans lesquelles les deux conditions sont remplies.

Ensuite, SUMPRODUCT additionne les éléments du tableau des 1 et des 0, retournant ainsi 0 pour le plus grand nombre dans chaque groupe. Et vous ajoutez 1 au résultat pour commencer le classement avec 1.

La formule qui classe les nombres dans les groupes du plus petit au plus grand ( ascendant commander ) fonctionne selon la même logique. La différence est que SUMPRODUCT renvoie 0 pour le plus petit nombre d'un groupe particulier, puisqu'aucun nombre de ce groupe ne remplit la deuxième condition (C2>$C$2:$C$7). Là encore, vous remplacez le rang zéro par le 1er rang en ajoutant 1 au résultat de la formule.

Au lieu de la fonction SUMPRODUCT, vous pouvez utiliser la fonction SUM pour additionner les éléments du tableau, mais cela nécessite l'utilisation d'une formule de tableau, complétée par Ctrl + Shift + Enter . Par exemple :

=SUM((A2=$A$2:$A$7)*(C2<$C$2:$C$7))+1

Comment classer séparément les nombres positifs et négatifs

Si votre liste de nombres contient des valeurs positives et négatives, la fonction RANK d'Excel les classera toutes en un rien de temps. Mais que faire si vous souhaitez que les nombres positifs et négatifs soient classés séparément ?

Avec les nombres figurant dans les cellules A2 à A10, utilisez l'une des formules suivantes pour obtenir un classement individuel pour les valeurs positives et négatives :

Classer les nombres positifs par ordre décroissant :

=IF($A2>0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Classez les nombres positifs par ordre croissant :

=IF($A2>0,COUNTIF($A$2:$A$10,">0")-COUNTIF($A$2:$A$10,"> ;"&$A2),"")

Classez les nombres négatifs par ordre décroissant :

=IF($A2<0,COUNTIF($A$2:$A$10,"<0")-COUNTIF($A$2:$A$10,"<;"&$A2),"")

Classez les nombres négatifs par ordre croissant :

=IF($A2<0,COUNTIF($A$2:$A$10,"<"&$A2)+1,"")

Les résultats ressembleront à ceci :

Comment fonctionnent ces formules

Pour commencer, décomposons la formule qui classe les nombres positifs en descendant l'ordre :

• Dans le test logique de la fonction IF, vous vérifiez si le nombre est supérieur à zéro.
• Si le nombre est supérieur à 0, la fonction COUNTIF renvoie le nombre de valeurs supérieures au nombre à classer.

  Dans cet exemple, A2 contient le deuxième nombre positif le plus élevé, pour lequel le COUNTIF renvoie 1, ce qui signifie qu'il n'y a qu'un seul nombre plus grand que lui. Afin de commencer notre classement avec 1, et non 0, nous ajoutons 1 au résultat de la formule, de sorte qu'elle renvoie un rang de 2 pour A2.

• Si le nombre est supérieur à 0, la formule renvoie une chaîne vide ("").

La formule qui classe les nombres positifs dans ascendant La commande fonctionne un peu différemment :

Si le nombre est supérieur à 0, le premier COUNTIF obtient le nombre total de nombres positifs dans l'ensemble de données, et le second COUNTIF détermine combien de valeurs sont supérieures à ce nombre. Ensuite, vous soustrayez le dernier du premier, et obtenez le rang souhaité. Dans cet exemple, il y a 5 valeurs positives, dont 1 est supérieure à A2. Donc, vous soustrayez 1 de 5, ce qui donne un rang de 4 pour A2.

Les formules de classement des nombres négatifs reposent sur une logique similaire.

Remarque : toutes les formules ci-dessus ignorer les valeurs nulles car 0 n'appartient ni à l'ensemble des nombres positifs ni à l'ensemble des nombres négatifs. Pour inclure les zéros dans votre classement, remplacez respectivement>0 et =0 et <=0, là où la logique de la formule l'exige.

Par exemple, pour classer les nombres positifs et les zéros du plus grand au plus petit, utilisez cette formule : =IF($A2>=0,COUNTIF($A$2:$A$10,">"&A2)+1,"")

Comment classer des données dans Excel en ignorant les valeurs nulles ?

Comme vous le savez déjà, la formule RANK d'Excel traite tous les nombres : positifs, négatifs et zéros. Mais dans certains cas, nous voulons seulement classer les cellules dont les données ignorent les valeurs 0. Sur le web, vous pouvez trouver quelques solutions possibles pour cette tâche, mais la formule Excel RANK IF, à mon avis, est la plus universelle :

Classer les nombres en ordre décroissant en ignorant le zéro :

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10), RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0)))

Classer les nombres en ordre croissant en ignorant le zéro :

=IF($B2=0,"",IF($B2>0,RANK($B2,$B$2:$B$10,1) - COUNTIF($B$2:$B$10,0), RANK($B2,$B$2:$B$10,1))))

Où B2:B10 est la plage de nombres à classer.

L'avantage de cette formule est qu'elle fonctionne parfaitement pour les nombres positifs et négatifs, sans tenir compte des valeurs nulles :

Comment fonctionne cette formule

À première vue, la formule peut sembler un peu compliquée, mais en y regardant de plus près, la logique est très simple.

Voici comment la formule Excel RANK IF classe les nombres du plus grand au plus petit en ignorant les zéros :

• Le premier IF vérifie si le nombre est égal à 0, et si c'est le cas, il renvoie une chaîne vide :

  IF($B2=0,"", ...)

• Si le nombre n'est pas nul, le deuxième IF vérifie s'il est supérieur à 0, et s'il l'est, une fonction RANK / RANK.EQ régulière calcule son rang :

  IF($B2>0,RANK($B2,$B$2:$B$10),...)

• Si le nombre est inférieur à 0, vous ajustez le classement en fonction du nombre de zéros. Dans cet exemple, il y a 4 nombres positifs et 2 zéros. Donc, pour le plus grand nombre négatif de B10, une formule Excel RANK donnerait 7. Mais nous sautons les zéros, et nous devons donc ajuster le classement de 2 points. Pour cela, nous soustrayons le nombre de zéros du classement :

  RANK($B2,$B$2:$B$10)-COUNTIF($B$2:$B$10,0))

La formule pour classer les nombres du plus petit au plus grand en ignorant les zéros fonctionne de la même manière, et ce pourrait être un bon exercice cérébral que de déduire sa logique :)

Comment calculer le rang dans Excel par valeur absolue

Lorsqu'il s'agit d'une liste de valeurs positives et négatives, il peut être nécessaire de classer les nombres en fonction de leur valeur absolue, sans tenir compte du signe.

Cette tâche peut être accomplie à l'aide de l'une des formules ci-dessous, au cœur desquelles se trouve la fonction ABS qui renvoie la valeur absolue d'un nombre :

Classement ABS décroissant :

=SUMPRODUCT((ABS(A2)<=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

Classer l'ABS par ordre croissant :

=SUMPRODUCT((ABS(A2)>=ABS(A$2:A$7)) * (A$2:A$7"")) - SUMPRODUCT((ABS(A2)=ABS($A$2:$A$7)) * (A$2:A$7""))+1

En conséquence, les nombres négatifs sont classés comme s'ils étaient des nombres positifs :

Comment obtenir les N valeurs les plus grandes ou les plus petites

Si vous souhaitez obtenir un nombre N réel des valeurs les plus grandes ou les plus petites plutôt que leur classement, utilisez la fonction LARGE ou SMALL, respectivement.

Par exemple, nous pouvons obtenir les 3 meilleurs scores de nos étudiants avec cette formule :

=LARGE($B$2:$B$7, $D3)

Où B2:B7 est la liste des notes et D3 est le rang souhaité.

En outre, vous pouvez récupérer les noms des élèves en utilisant la formule INDEX MATCH (à condition qu'il n'y ait pas de doublons dans les trois premiers résultats) :

=INDEX($A$2:$A$7,MATCH(E3,$B$2:$B$7,0))

De même, vous pouvez utiliser la fonction SMALL pour extraire les 3 valeurs les plus basses :

=SMALL($B$2:$B$7, $D3)

Afin de mieux comprendre et probablement d'effectuer une rétro-ingénierie des formules présentées dans ce tutoriel, nous vous invitons à télécharger notre classeur Excel Exemple de classement.

Je vous remercie de votre lecture et j'espère vous voir sur notre blog la semaine prochaine !