목차
이 자습서에서는 Excel에서 If 일치 수식을 구성하여 논리 값, 사용자 지정 텍스트 또는 다른 셀의 값을 반환하는 방법을 알려줍니다.
볼 수 있는 Excel 수식 두 개의 셀이 일치하는 경우 A1=B1처럼 간단할 수 있습니다. 그러나 이 명백한 솔루션이 작동하지 않거나 예상과 다른 결과를 생성하는 다른 상황이 있을 수 있습니다. 이 튜토리얼에서는 Excel에서 셀을 비교하는 다양한 방법에 대해 논의하므로 작업에 대한 최적의 솔루션을 찾을 수 있습니다.
Excel에서 두 셀이 일치하는지 확인하는 방법
Excel If 일치 수식에는 다양한 변형이 있습니다. 아래 예를 검토하고 시나리오에 가장 적합한 것을 선택하세요.
두 셀이 같으면 TRUE를 반환합니다.
가장 간단한 " 한 셀이 다른 셀과 같으면 참" Excel 수식은 다음과 같습니다.
셀 A= 셀 B예를 들어, 각 행에서 열 A와 B의 셀을 비교하려면 다음 수식을 입력합니다. C2, 그런 다음 열 아래로 복사:
=A2=B2
결과적으로 두 셀이 동일하면 TRUE, 그렇지 않으면 FALSE가 표시됩니다. 
참고:
- 이 수식은 두 개의 부울 값을 반환합니다. 두 셀이 같으면 - TRUE; 같지 않은 경우 - FALSE. TRUE 값만 반환하려면 다음 예제와 같이 IF 문에서 사용하십시오.
- 이 수식은 대소문자를 구분하지 않으므로 대문자와 소문자를 같은 문자로 취급합니다. 만약 텍스트대소문자를 구분하는 공식을 사용하세요.
두 셀이 일치하면 값 반환
두 셀이 일치하면 고유한 값을 반환하려면 이 패턴을 사용하여 IF 문을 구성하세요. :
IF( 셀 A = 셀 B , value_if_true, value_if_false)예를 들어, A2와 B2를 비교하여 동일한 값을 포함하는 경우 "예"를 반환합니다. , 그렇지 않으면 "no", 공식은 다음과 같습니다.
=IF(A2=B2, "yes", "no") 
셀이 동일한 경우에만 값을 반환하려면 value_if_false에 빈 문자열("")을 제공합니다. .
일치하면 예 :
=IF(A2=B2, "yes", "")
일치하면 참:
=IF(A2=B2, TRUE, "") 
참고. 논리값 TRUE를 반환하려면 큰따옴표로 묶지 마십시오. 큰따옴표를 사용하면 논리 값이 일반 텍스트 문자열로 변환됩니다.
한 셀이 다른 셀과 같으면 다른 셀을 반환합니다.
다음은 이 특정 작업을 해결하는 일치하는 경우 Excel 수식의 변형입니다. 두 셀의 값을 비교하고 데이터 일치 후 다른 셀에서 값을 복사합니다.
Excel 언어에서는 다음과 같이 공식화됩니다.
IF( 셀 A = 셀 B , cell C , "")예를 들어 A열과 B열의 항목을 확인하고 텍스트가 일치하면 C열의 값을 반환하려면 D2의 수식을 복사하면 다음과 같습니다.
=IF(A2=B2, C2, "") 
두 셀이 일치하는지 확인하는 대소문자 구분 수식
대소문자 구분 텍스트 값을 처리하는 경우 EXACT대소문자를 포함하여 셀을 정확하게 비교하는 함수:
IF(EXACT( cell A , cell B ), value_if_true, value_if_false)예: 비교 A2 및 B2의 항목을 입력하고 텍스트가 정확히 일치하면 "예"를 반환하고, 차이가 있으면 "아니오"를 반환합니다. 다음 수식을 사용할 수 있습니다.
=IF(EXACT(A2, B2), "Yes", "No") 
여러 셀이 있는지 확인하는 방법 같음
두 개의 셀을 비교하는 것과 마찬가지로 여러 셀이 일치하는지 확인하는 방법도 몇 가지 있습니다.
AND 여러 셀이 일치하는지 확인하는 수식
To 여러 값이 일치하는지 확인하려면 두 개 이상의 논리 테스트에 AND 기능을 사용할 수 있습니다.
AND( cell A = cell B , cell A = 셀 C , …)예를 들어, 셀 A2, B2 및 C2가 같은지 확인하려면 공식은 다음과 같습니다.
=AND(A2=B2, A2=C2)
동적 배열에서 Excel(365 및 2021) 아래 구문을 사용할 수도 있습니다. Excel 2019 이하에서는 Ctrl + Shift + Enter 키를 함께 눌러 완료되는 기존 CSE 배열 수식으로만 작동합니다.
=AND(A2=B2:C2)
두 AND 수식의 결과는 논리 값 TRUE 및 FALSE.
고유한 값을 반환하려면 다음과 같이 IF 함수에 AND를 래핑합니다.
=IF(AND(A2=B2:C2), "yes", "")
이 수식은 세 개의 셀이 모두 "yes"인 경우 "yes"를 반환합니다. 같지 않으면 빈 셀입니다. 
여러 열이 일치하는지 확인하는 COUNTIF 수식
여러 열이 일치하는지 확인하는 또 다른 방법은 다음 형식의 COUNTIF 함수를 사용하는 것입니다.
COUNTIF( range , cell )= n여기서 range 은 서로 비교할 셀의 범위, cell 은 범위의 단일 셀이고 n 은 범위의 셀 수입니다.
샘플 데이터세트의 경우 수식을 다음 형식으로 작성할 수 있습니다. :
=COUNTIF(A2:C2, A2)=3
많은 열을 비교하는 경우 COLUMNS 함수는 자동으로 셀 개수(n)를 가져올 수 있습니다.
=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)
그리고 IF 함수는 원하는 모든 것을 결과로 반환하는 데 도움이 됩니다.
=IF(COUNTIF(A2:C2, A2)=3, "All match", "") 
여러 일치에 대한 대소문자 구분 공식
두 개의 셀을 확인하는 것과 마찬가지로 대소문자를 포함하여 정확한 비교를 수행하려면 EXACT 함수를 사용하십시오. 여러 셀을 처리하기 위해 EXACT는 다음과 같이 AND 함수에 중첩됩니다.
AND(EXACT( range , cell ))In Excel 365 및 Excel 2021 , 동적 배열 지원으로 인해 일반 공식으로 작동합니다. Excel 2019 이하에서는 Ctrl + Shift + Enter를 눌러 배열 수식 으로 만들어야 합니다.
예를 들어 셀 A2:C2에 동일한 값이 포함되어 있는지 확인하려면 대소문자 -민감한 수식은 다음과 같습니다.
=AND(EXACT(A2:C2, A2))
IF와 조합하여 다음과 같은 형태를 취합니다.
=IF(AND(EXACT(A2:C2, A2)), "Yes", "No") 
셀이 범위 내의 셀과 일치하는지 확인
셀이 주어진 범위의 셀과 일치하는지 확인하려면 다음 수식 중 하나를 사용하십시오.
OR 함수
사용하는 것이 가장 좋습니다. 2~3셀 확인용.
OR( 셀 A = 셀 B , 셀 A = 셀 C , 셀 A = cell D , …)Excel 365 및 Excel 2021도 이 구문을 이해합니다.
OR( cell = range )Excel 2019 및 Ctrl + Shift + Enter 단축키를 눌러 배열 수식으로 입력해야 합니다.
COUNTIF 함수
COUNTIF( range , cell )>0예를 들어, A2가 B2:D2의 셀과 같은지 확인하려면 다음 공식 중 하나를 수행합니다.
=OR(A2=B2, A2=C2, A2=D2)
=OR(A2=B2:D2)
=COUNTIF(B2:D2, A2)>0
Excel 2019 이하 버전을 사용하는 경우 Ctrl + Shift + Enter를 눌러 두 번째 OR 수식을 가져와야 정확한 결과를 얻을 수 있습니다. 
예/아니요 또는 원하는 다른 값을 반환하려면 IF 함수의 논리적 테스트에 위 수식 중 하나를 중첩해야 합니다. 예:
=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No") 
자세한 내용은 범위에 값이 있는지 확인을 참조하세요.
두 범위가 같은지 확인
비교하려면 셀별로 두 개의 범위를 지정하고 해당 위치의 모든 셀이 일치하면 논리적 값 TRUE를 반환하고 동일한 크기의 범위를 AND 함수의 논리적 테스트에 제공합니다.
AND( range A = 범위 B )예를 들어, B3:F6의 매트릭스 A와 B11:F14의 매트릭스 B를 비교하려면 공식은 다음과 같습니다.
=AND(B3:F6= B11:F14)
To 결과로 Yes / No 를 얻으려면 다음 IF AND 조합을 사용하십시오.
=IF(AND(B3:F6=B11:F14), "Yes", "No") 
If 일치 수식을 사용하는 방법입니다.엑셀에서. 읽어 주셔서 감사합니다. 다음 주 블로그에서 뵙겠습니다!
연습 워크북
Excel에서 셀이 일치하는 경우 - 수식 예제(.xlsx 파일)
