Le tutoriel examine comment utiliser les fonctions ISTEXT et ISNONTEXT dans Excel pour vérifier si une cellule contient une valeur textuelle ou non.

Lorsque vous avez besoin d'obtenir des informations sur le contenu d'une cellule dans Excel, vous utilisez généralement les fonctions dites d'information. ISTEXT et ISNONTEXT appartiennent à cette catégorie. La fonction ISTEXT vérifie si une valeur est du texte et ISNONTEXT vérifie si une valeur n'est pas du texte. Aussi simple que soit le concept, ces fonctions sont étonnamment utiles pour résoudre une variété de tâches différentes dans Excel.

Fonction ISTEXT d'Excel

La fonction ISTEXT d'Excel vérifie si une valeur spécifiée est du texte ou non. Si la valeur est du texte, la fonction renvoie VRAI. Pour tous les autres types de données (comme les nombres, les dates, les cellules vides, les erreurs, etc.), elle renvoie FAUX.

La syntaxe est la suivante :

ISTEXT(valeur)

Où valeur est une valeur, une référence de cellule, une expression ou une autre fonction dont vous voulez tester le résultat.

Par exemple, pour savoir si une valeur dans A2 est du texte ou non, utilisez cette formule simple :

=ISTEXT(A2)

Fonction ISNONTEXT d'Excel

La fonction ISNONTEXT renvoie VRAI pour toute valeur non textuelle, y compris les nombres, les dates et heures, les blancs et autres formules qui renvoient des résultats non textuels ou des erreurs. Pour les valeurs textuelles, elle renvoie FAUX.

La syntaxe est la même que celle de la fonction ISTEXT :

ISTEXT(valeur)

Par exemple, pour vérifier si une valeur dans A2 n'est pas du texte, utilisez cette formule :

=ISNONTEXT(A2)

Comme le montre la capture d'écran ci-dessous, les formules ISTEXT et ISNONTEXT renvoient des résultats opposés :

Fonctions ISTEXT et ISNONTEXT dans Excel - notes d'utilisation

ISTEXT et ISNONTEXT sont des fonctions très simples et faciles à utiliser, et il est peu probable que vous rencontriez des difficultés avec elles. Cela dit, il y a quelques points clés à prendre en compte :

• Ces deux fonctions font partie du groupe de fonctions IS et renvoient les valeurs logiques (booléennes) VRAI ou FAUX.
• Dans un cas particulier, lorsque les chiffres sont stockés sous forme de texte ISTEXT renvoie VRAI et ISNONTEXT renvoie FAUX.
• Ces deux fonctions sont disponibles dans toutes les versions d'Excel pour Office 365, Excel 2019, Excel 2016, Excel 2013, Excel 2010, Excel 2007, Excel 2003, Excel XP et Excel 2000.

Utilisation de ISTEXT et ISNONTEXT dans Excel - exemples de formules

Vous trouverez ci-dessous des exemples d'utilisations pratiques des fonctions ISTEXT et ISNONTEXT dans Excel qui, nous l'espérons, vous aideront à rendre vos feuilles de calcul plus efficaces.

Vérifier si une valeur est du texte

Parfois, lorsque vous travaillez avec un ensemble de valeurs, vous pouvez être surpris de constater que pour certains nombres, vos formules renvoient des résultats erronés, voire des erreurs. La raison la plus évidente est que les nombres problématiques sont stockés sous forme de texte. Les formules ci-dessous vous permettront de savoir avec certitude quelles valeurs sont du texte du point de vue d'Excel.

Formule ISTEXT :

Renvoie VRAI pour toute valeur qu'Excel considère comme étant texte .

=ISTEXT(B2)

Formule ISNONTEXT :

Renvoie VRAI pour toute valeur qu'Excel considère comme étant hors texte .

=ISNONTEXT(B2)

ISTEXT pour la validation des données : autoriser uniquement le texte

Dans certaines situations, vous pouvez autoriser les utilisateurs à saisir uniquement des valeurs de texte dans certaines cellules. Pour ce faire, créez une règle de validation des données basée sur une formule ISTEXT. Voici comment procéder :

1. Sélectionnez une ou plusieurs cellules que vous souhaitez valider.
2. Sur le Données dans l'onglet Outils de données cliquez sur le bouton Validation des données bouton.
3. Sur le Paramètres de l'onglet Validation des données sélectionnez Personnalisé pour les critères de validation et saisissez votre formule ISTEXT dans la case correspondante.
4. Cliquez sur OK pour enregistrer la règle.

Dans cet exemple, nous validons les réponses au questionnaire dans les cellules B2 à B4 à l'aide de cette formule :

=ISTEXT(B2:B4)

En outre, vous pouvez configurer vos propres Alerte d'erreur pour expliquer à vos utilisateurs quel type de données est accepté :

Par conséquent, lorsque l'utilisateur tente de saisir un nombre ou une date dans l'une des cellules validées, il voit apparaître l'alerte suivante :

Pour plus d'informations, veuillez consulter la section Utilisation de la validation des données dans Excel.

Formule Excel IF ISTEXT

Dans la pratique, ISTEXT et ISNONTEXT sont souvent utilisés avec la fonction IF pour obtenir un résultat plus convivial que les valeurs standard TRUE et FALSE.

Formule 1 : Si est texte, alors

Pour aller un peu plus loin dans notre premier exemple, supposons que vous souhaitiez renvoyer "Oui" pour les valeurs de texte et "Non" pour toute autre valeur. Pour ce faire, il suffit d'imbriquer la fonction ISTEXT dans le test logique IF et d'utiliser "Oui" et "Non" pour le test logique IF. valeur_si_vrai et valeur_si_false respectivement :

=IF(ISTEXT(A2), "Oui", "Non")

Formule 2 : vérifier l'entrée de la cellule

Dans l'un des exemples précédents, nous avons vu comment garantir la validité des données saisies par l'utilisateur à l'aide de la validation des données, ce qui peut également être réalisé sous une forme plus "douce" à l'aide d'une formule Excel IF ISTEXT.

Dans le questionnaire, supposons que vous souhaitiez déterminer quelles sont les réponses valides (texte) et celles qui ne le sont pas (non-texte). Pour cela, utilisez les instructions IF imbriquées avec la logique suivante :

• Si la cellule testée est vide, elle ne renvoie rien, c'est-à-dire une chaîne vide ("").
• Si la cellule est du texte, elle renvoie "Réponse valide".
• Si ce n'est ni l'un ni l'autre, renvoyer "Réponse invalide - veuillez entrer le texte".

En mettant tout cela ensemble, nous obtenons la formule suivante, où B2 est la cellule à vérifier :

=IF(B2="", "", IF(ISTEXT(B2), "Réponse valide", "Réponse invalide - veuillez saisir le texte."))

Vérifier si une plage contient du texte

Jusqu'à présent, nous avons testé chaque cellule individuellement, mais que faire si vous avez besoin de savoir si une cellule d'une plage contient du texte ?

Pour tester l'ensemble de la gamme, combinez la fonction ISTEXT avec SUMPRODUCT de cette manière :

À titre d'exemple, vérifions la présence de valeurs textuelles dans chaque ligne de l'ensemble de données ci-dessous, ce qui peut être fait à l'aide des formules suivantes :

=SUMPRODUCT(ISTEXT(A2:C2)*1)>0

=SUMPRODUCT(--ISTEXT(A2:C2))>0

L'une des formules ci-dessus va dans la cellule D2, puis vous la faites glisser jusqu'à la cellule D5.

Ainsi, vous savez maintenant clairement quelles lignes contiennent une ou plusieurs chaînes de texte (VRAI) et lesquelles ne contiennent que des chiffres (FAUX).

Si vous souhaitez renvoyer des résultats différents, dire "Oui" ou "Non" plutôt que VRAI et FAUX, intégrez la formule ci-dessus dans l'instruction IF :

=IF(SUMPRODUCT(--ISTEXT(A2:C2))>0, "Oui", "Non")

Comment fonctionne cette formule

La formule est basée sur la capacité de SUMPRODUCT à gérer les tableaux de façon native. Voici ce qu'elle fait, en partant de l'intérieur :

• La fonction ISTEXT renvoie un tableau de valeurs VRAIES et FAUX. Pour A2:C2, nous obtenons ce tableau :

  {VRAI, VRAI, FAUX}

• Ensuite, nous multiplions chaque élément du tableau ci-dessus par 1 pour convertir les valeurs logiques de VRAI et FAUX en 1 et 0, respectivement. Un opérateur unaire double (--) peut être utilisé dans le même but. Après la transformation, la formule prend cette forme :

  SUMPRODUCT({1,1,0})>0

• La fonction SUMPRODUCT additionne les 1 et les 0, et vous vérifiez si le résultat est supérieur à zéro. Si c'est le cas, la plage contient au moins une valeur de texte et la formule renvoie VRAI, sinon FAUX.

Vérifier si une cellule contient un texte spécifique

La fonction ISTEXT d'Excel ne peut déterminer que si une cellule contient du texte, c'est-à-dire absolument n'importe quel texte. Pour savoir si une cellule contient une chaîne de texte spécifique, utilisez la formule ISNUMBER SEARCH ou COUNTIF avec des caractères génériques.

Par exemple, pour vérifier si l'ID de l'élément en A2 contient la chaîne de texte saisie dans la cellule D2, utilisez la formule ci-dessous (tenez compte de la référence absolue $D$2 qui empêche l'adresse de la cellule de changer lorsque la formule est copiée dans d'autres cellules) :

=ISNUMBER(SEARCH($D$2, A2))

Pour des raisons de commodité, nous allons l'intégrer dans la fonction IF :

=IF(ISNUMBER(SEARCH($D$2, A2)), "Oui", "Non")

Et obtenir les résultats suivants :

Le même résultat peut être obtenu avec le COUNTIF :

=IF(COUNTIF(A2, "*"&$D$2& ; "*")>0, "Oui", "Non")

Pour plus d'exemples, veuillez consulter Excel Si une cellule contient des formules.

Mettez en surbrillance les cellules qui contiennent du texte

La fonction ISTEXT peut également être utilisée avec la mise en forme conditionnelle d'Excel pour mettre en évidence les cellules contenant des valeurs de texte :

1. Sélectionnez toutes les cellules que vous voulez vérifier et mettez-les en surbrillance (A2:C5 dans cet exemple).
2. Sur le Accueil dans l'onglet Styles cliquez sur Nouvelle règle > ; Utilisez une formule pour déterminer les cellules à mettre en forme .
3. Dans le Formatez les valeurs pour lesquelles cette formule est vraie entrez la formule ci-dessous :

   =ISTEXT(A2)

   Où A2 est la cellule la plus à gauche de la plage sélectionnée.

4. Cliquez sur le bouton Format et choisissez le formatage souhaité.
5. Cliquez deux fois sur OK pour fermer les deux boîtes de dialogue et enregistrer la règle.

Pour une explication plus détaillée de chaque étape, veuillez consulter : Utilisation de formules pour la mise en forme conditionnelle d'Excel.

En conséquence, Excel met en évidence toutes les cellules contenant des chaînes de texte :

Voilà comment utiliser les fonctions ISTEXT et ISNONTEXT dans Excel. Je vous remercie de votre lecture et j'espère vous voir sur notre blog la semaine prochaine !

Téléchargements disponibles

Exemples de formules Excel ISTEXT et ISNONTEXT