Kiam vi bezonas trovi datumojn en via folio, kiuj respondas al certa ŝlosila registro, kutime vi turnas vin al Google Sheets VLOOKUP. Sed jen: VLOOKUP preskaŭ tuj vangofrapas vin per limigoj. Tial vi prefere pligrandigus la rimedojn por la tasko per lernado de INDEX MATCH.

INDEX MATCH en Google Sheets estas kombinaĵo de du funkcioj: INDEX kaj MATCH. Se uzataj en tandemo, ili funkcias kiel pli bona alternativo por Google Sheets VLOOKUP. Ni eltrovu iliajn kapablojn kune en ĉi tiu blogaĵo. Sed unue, mi ŝatus doni al vi rapidan viziton pri siaj propraj roloj en kalkultabeloj.

Google Sheets MATCH-funkcio

Mi ŝatus komenci kun Guglo. Sheets MATCH ĉar ĝi estas vere simpla. Ĝi skanas viajn datumojn por specifa valoro kaj redonas ĝian pozicion:

• serĉo_ŝlosilo estas tiu rekordo, kiun vi serĉas. Bezonata.
• intervalo estas aŭ vico aŭ kolumno por rigardi. Bezonata.

  Notu. MATCH nur akceptas unudimensiajn tabelojn: ĉu vicon aŭ kolumnon.

• serĉo_tipo estas laŭvola kaj difinas ĉu la kongruo estu ĝusta aŭ proksimuma. Se ellasita, ĝi estas 1 defaŭlte:
  • 1 signifas, ke la intervalo estas ordigita en suprena ordo. La funkcio ricevas la plej grandan valoron malpli ol aŭ egala al via serĉa_ŝlosilo .
  • 0 igos la funkcion serĉi la ĝustan kongruon se via intervalo ne estasordigita.
  • -1 sugestas ke registroj estas rangigitaj per malkreska ordigo. En ĉi tiu kazo, la funkcio ricevas la plej malgrandan valoron pli granda ol aŭ egala al via serĉo_ŝlosilo .

Jen ekzemplo: por akiri pozicion de certa. beron en la listo de ĉiuj beroj, mi bezonas la jenan MATCH-formulon en miaj Google Sheets:

=MATCH("Blueberry", A1:A10, 0)

Google Sheets INDEX-funkcio

Dum MATCH montras kie serĉi vian valoron (ĝia loko en la intervalo), Google Sheets INDEX-funkcio alportas la valoron mem surbaze de ĝiaj vicoj kaj kolumnaj ofsetoj:

• referenco estas la intervalo por rigardi. Bezonata.
• vico estas la nombro da vicoj por kompensi de la unua ĉelo de via intervalo . Laŭvola, 0 se ellasita.
• kolumno , same kiel vico , estas la nombro da ofsetaj kolumnoj. Ankaŭ nedeviga, ankaŭ 0 se ellasita.

Se vi specifas ambaŭ laŭvolajn argumentojn (vico kaj kolumno), Google Sheets INDEX resendos rekordon el celĉelo:

=INDEX(A1:C10, 7, 1)

Saltu unu el tiuj argumentoj kaj la funkcio ricevos al vi la tutan vicon aŭ kolumnon laŭe:

=INDEX(A1:C10, 7)

Kiel uzi INDEX MATCH en Google Sheets — formulekzemploj

Kiam INDEX kaj MATCH estas uzataj kune en kalkultabeloj, ili estas plej potencaj. Ili povas absolute anstataŭigi Google Sheets VLOOKUP kaj alporti la postulatan rekordon de tabelo bazita survia ŝlosila valoro.

Konstruu vian unuan INDEXMATCH-formulon por Google Sheets

Supozu, ke vi ŝatus akiri la akciajn informojn pri kranbero el la sama tabelo, kiun mi uzis supre. Mi nur interŝanĝis kolumnojn B kaj C (vi ekscios kial iom poste).

1. Nun ĉiuj beroj estas listigitaj en kolumno C. Guglo Sheets MATCH funkcio helpos vin lokalizi la ĝustan vicon de la cranberry: 8

   =MATCH("Cranberry", C1:C10, 0)

2. Metu tiun tutan MATCH-formulon al vica argumento en la INDEX-funkcio:

   =INDEX(A1:C10, MATCH("Cranberry", C1:C10, 0))

   Ĉi tiu redonos la tutan vicon kun oksiko en ĝi.

3. Sed ĉar vi bezonas nur la akciajn informojn, specifu ankaŭ la nombron de la serĉkolumno: 3

   =INDEX(A1:C10, MATCH("Cranberry", C1:C10,0), 2)

4. Venu. !

   

5. Vi povas iri plu kaj rezigni tiun lastan kolumnan indikilon ( 2 ). Vi tute ne bezonos ĝin se vi uzas nur la serĉkolumnon ( B1:B10 ) anstataŭ la tutan tabelon ( A1:C10 ) kiel la unua argumento:

   =INDEX(B1:B10, MATCH("Cranberry", C1:C10, 0))

   

   Konsileto. Pli oportuna maniero kontroli la haveblecon de diversaj beroj estus meti ilin en falliston ( E2 ) kaj referenci vian MATCH-funkcion al la ĉelo kun tiu listo:

   =INDEX(B1:B10, MATCH(E2, C1:C10, 0))

   Post kiam vi elektas la beron, la rilata valoro ŝanĝiĝos laŭe:

   

Kial INDEX MATCH en Google Sheets estas pli bona ol VLOOKUP

Vi jam scias, ke Google Sheets INDEX MATCH rigardas vian valoron en tabelo kaj liveras alian rilatan rekordon de la samavico. Kaj vi scias, ke Google Sheets VLOOKUP faras ĝuste la samon. Do kial ĝeni?

La afero estas, INDEKSA MATCH havas kelkajn ĉefajn avantaĝojn super VLOOKUP:

1. Maldekstra flanko serĉo eblas . Mi ŝanĝis la kolumnojn lokojn pli frue por ilustri ĉi tiun: INDEX MATCH-funkcio en Google Sheets povas kaj aspektas maldekstre de la serĉkolumno. VLOOKUP ĉiam serĉas la plej unuan kolumnon de la intervalo kaj serĉas kongruojn dekstre — alie, ĝi ricevas nur #N/A eraroj:

   

2. Ne fuŝas. referencoj kiam vi aldonas novajn kolumnojn kaj movas ekzistantajn. Se vi aldonas aŭ movas kolumnojn, INDEX MATCH aŭtomate reflektos la ŝanĝojn sen enmiksiĝi en la rezulton. Ĉar vi uzas kolumnreferencojn, ili estas tuj ĝustigitaj de Google Sheets:

   

   Antaŭeniru kaj provu fari tion per VLOOKUP: ĝi postulas la mendan numeron anstataŭ ĉelreferencojn por serĉkolumno. Tiel, vi simple ricevos la malĝustan valoron ĉar alia kolumno prenas la saman lokon — kolumno 2 en mia ekzemplo:

   

3. Konsideru tekston kiam necese (pli ĉi-malsupre).
4. Uzeblas por vertikala serĉo surbaze de pluraj kriterioj.

Mi invitas vin rigardi. ĉe la lastaj du punktoj detale malsupre.

Uskle-distinga v-serĉo kun INDEX MATCH en Google Sheets

INDEX MATCH estas konvena kiam temas pri majuskloj.sentemo.

Supozi, ke ĉiuj beroj estas vendataj en du manieroj — lozaj (pezitaj ĉe la vendotablo) kaj pakitaj en skatoloj. Tial, estas du aperoj de ĉiu bero skribita en malsamaj kazoj en la listo, ĉiu kun sia propra identigilo kiu ankaŭ varias en kazoj:

Do kiel vi povas serĉi la akciajn informojn pri bero vendita en certa maniero? VLOOKUP redonos la antaŭnomon, kiun ĝi trovas, negrave ĝia kazo.

Bonŝance, INDEX MATCH por Google Sheets povas fari ĝin ĝuste. Vi nur bezonos uzi unu plian funkcion — TROVU aŭ EKZAKZAN.

Ekzemplo 1. TROVU por uskle-distinga Vlookup

TROVU estas uskle-distinga funkcio en Guglo-Folioj, kiu faras ĝin bonega. por uskle-distinta vertikala serĉo:

=ArrayFormula(INDEX(B2:B19, MATCH(1, FIND(E2, C2:C19)), 0))

Ni vidu kio okazas en ĉi tiu formulo:

1. TROVU skanas kolumnon C ( C2:C19 ) por la rekordo de E2 ( ĉerizo ) konsiderante ĝian literon. Fojo lokalizita, la formulo "markas" tiun ĉelon per numero — 1 .
2. MATCH serĉas ĉi tiun markon — 1 — en la sama kolumno ( C ) kaj donas la numeron de ĝia vico al INDEX.
3. INDEX venas malsupren al tiu vico en kolumno B ( B2:B19 ) kaj alportas la bezonatan registron al vi.
4. Kiam vi finos konstrui la formulon, premu Ctrl+Shift+Enter por aldoni ArrayFormula komence. Ĝi estas postulata ĉar sen ĝi FIND ne povos serĉi en tabeloj (en pli ol unu ĉelo). Aŭ vi povas tajpi' ArrayFormula ' de via klavaro.

Ekzemplo 2. EKZAKTA por uskle-distinga Vserĉo

Se vi anstataŭigas FIND per EXACT, ĉi-lasta serĉos registrojn. kun la ekzakte samaj signoj, inkluzive de ilia teksta majusklo.

La nura diferenco estas ke EKZAKTA "markas" kongruon per VERA prefere ol numero 1 . Tial, la unua argumento por MATCH devus esti VERA :

=ArrayFormula(INDEX(B2:B19, MATCH(TRUE, EXACT(E2, C2:C19), 0)))

Google Sheets INDEX MATCH kun pluraj kriterioj

Kaj se ekzistas pluraj kondiĉoj surbaze de kiuj vi ŝatus preni la rekordon?

Ni kontrolu la prezon de la ĉerizo kiu estas vendita en PP siteloj kaj jam elĉerpiĝas :

Mi aranĝis ĉiujn kriteriojn en la fallistoj en kolumno F. Kaj ĝi estas Google Sheets INDEX MATCH kiu subtenas plurajn kriteriojn, ne VLOOKUP. Jen la formulo, kiun vi bezonos uzi:

=ArrayFormula(INDEX(B2:B24, MATCH(CONCATENATE(F2:F4), A2:A24&C2:C24&D2:D24, 0),))

Ne paniku! :) Ĝia logiko estas efektive sufiĉe simpla:

1. CONCATENATE(F2:F4) kombinas ĉiujn tri registrojn el ĉeloj kun kriterioj en unu ĉenon kiel ĉi tiu:

   CherryPP bucketRunning out

   Ĉi tio estas serĉa_ŝlosilo por MATCH, aŭ, alivorte, tio, kion vi serĉas en la tabelo.

2. A2:A24&C2:C24&D2:D24 konsistigas gamon por ke la MATCH-funkcio enrigardu. Ĉar ĉiuj tri kriterioj okazas en tri apartaj kolumnoj, tiamaniere vi kombinas ilin:

   ĈerizoKardona pletoEn stoko

   ĈerizoFilmpakaĵoElĉerpita

   ĈerizoPP-siteloElĉerpiĝanta

   ktp .

3. La lasta argumento en MATCH — 0 — ebligas trovi la ĝustan kongruon por CherryPP bucketRunning out inter ĉiuj tiuj vicoj de kombinitaj kolumnoj. Kiel vi povas vidi, ĝi estas en la 3-a vico.
4. Kaj tiam INDEX faras sian aferon: ĝi prenas la rekordon el la 3-a vico de la kolumno B.
5. ArrayFormula estas uzata por permesi aliajn funkciojn. labori kun tabeloj.

Konsileto. Se via formulo ne trovas kongruon, ĝi resendos eraron. Por eviti tion, vi povas envolvi ĉi tiun tutan formulon en IFERARO (faru ĝin la unua argumento) kaj enigi kion ajn vi volas vidi en ĉelo anstataŭ eraroj kiel dua argumento:

=IFERROR(ArrayFormula(INDEX(B2:B27, MATCH(CONCATENATE(F2:F4), A2:A27&C2:C27&D2:D27, 0),)), "Not found")

Pli bona alternativo al INDEX MATCH en Google Sheets — Multoblaj VLOOKUP-Kongruoj

Kiu ajn serĉfunkcio vi preferas, VLOOKUP aŭ INDEX MATCH, estas pli bona alternativo al ili ambaŭ.

Multoblaj VLOOKUP Matches estas speciala aldonaĵo por Google Sheets dizajnita por:

• serĉi sen formuloj
• serĉi en ĉiuj direktoj
• serĉi laŭ pluraj kondiĉoj por malsamaj datumtipoj : teksto, nombroj, datoj, horo, ktp.
• portu plurajn kongruojn, kiom vi bezonas (kondiĉe ke estas tiom da ili en via tabelo, kompreneble)

La interfaco estas simpla, do vi ne devos dubi ĉu vi farasĉio ĝuste:

1. Elektu fontan gamon.
2. Agordu la nombron da kongruoj kaj kolumnoj revenindaj.
3. Fajnigu la kondiĉojn per la antaŭdifinitaj operatoroj ( enhavas, =, ne malplenan , inter , ktp.).

Vi ankaŭ povos:

• antaŭrigardu la rezulton
• decidu kie meti ĝin
• kaj kiel: kiel formulo aŭ nur valoroj

Ne maltrafu ĉi tiun ŝancon kontroli la aldonaĵon. Antaŭeniru kaj instalu ĝin de Google Workspace Marketplace. Ĝia lernila paĝo klarigos ĉiun opcion detale.

Ni ankaŭ preparis specialan instruan filmeton:

Ĝis revido en la subaj komentoj aŭ en la sekva artikolo ;)