Vodič daje kratak uvod u sintaksu funkcije ADDRESS i pokazuje kako je koristiti za vraćanje Excel adrese ćelije i više.

Da biste kreirali referencu ćelije u Excelu, morate može ručno upisati koordinate stupca i reda. Alternativno, možete dobiti adresu ćelije u Excelu iz brojeva redaka i stupaca koji su dostavljeni funkciji ADDRESS. Gotovo besmisleno sama po sebi, u kombinaciji s drugim funkcijama ova tehnika može biti jedino rješenje u situacijama kada nije moguće uputiti se direktno na ćeliju.

Excel ADDRESS funkcija - sintaksa i osnovne upotrebe

Funkcija ADDRESS je dizajnirana da dobije adresu ćelije u Excelu na osnovu navedenih brojeva redaka i stupaca. Adresa ćelije se vraća kao tekstualni niz, a ne stvarna referenca.

Funkcija je dostupna u svim verzijama programa Excel za Microsoft 365 - Excel 2007.

Sintaksa funkcije ADDRESS je kako slijedi:

Prva dva argumenta su obavezna:

broj_reda - red broj koji će se koristiti u referenci ćelije.

broj_stupca - broj stupca za izradu reference ćelije.

Posljednja tri argumenta, koja specificiraju format reference ćelije, su opciono:

abs_num - tip reference, apsolutni ili relativni. Može uzeti bilo koji od dolje navedenih brojeva; zadana vrijednost je apsolutna.

• 1 ili izostavljena -apsolutna referenca ćelije kao $A$1
• 2 - mješovita referenca: relativni stupac i apsolutni red kao A$1
• 3 - mješovita referenca: apsolutni stupac i relativni red kao $A1
• 4 - relativna referenca ćelije kao što je A1

a1 - stil reference, A1 ili R1C1. Ako se izostavi, koristi se zadani stil A1.

• 1 ili TRUE ili izostavljen - vraća adresu ćelije u referentnom stilu A1 gdje su stupci slova, a redovi brojevi.
• 0 ili FALSE - vraća adresu ćelije u referentnom stilu R1C1 gdje su redovi i stupci predstavljeni brojevima.

sheet_text - naziv radnog lista koji treba uključiti u vanjsku referencu. Naziv lista treba navesti kao tekstualni niz i staviti ga u navodnike, npr. "Sheet2". Ako se izostavi, naziv radnog lista se ne koristi, a adresa je podrazumevana na trenutnom listu.

Na primer:

=ADDRESS(1,1) - vraća adresu prve ćelije (tj. ćelije na preseku prvi red i prvi stupac) kao apsolutnu referencu ćelije $A$1.

=ADDRESS(1,1,4) - vraća adresu prve ćelije kao relativnu referencu ćelije A1.

U sljedećoj tabeli naći ćete još nekoliko tipova referenci koje se mogu vratiti formulama ADDRESS.

Kako koristiti funkciju ADDRESS u Excelu - primjeri formule

Primjeri u nastavku pokazuju kako koristiti funkciju ADDRESS unutar većih formula da postignete više teški zadaci.

Vrati vrijednost ćelije u datom redu i stupcu

Ako je vaš cilj da dobijete vrijednost iz određene ćelije na osnovu broja njenih redova i stupaca, koristite zabavu ADDRESS akcija zajedno sa INDIRECT:

Funkcija ADDRESS ispisuje adresu ćelije kao tekst. INDIRECT funkcija pretvara taj tekst u normalnu referencu i vraća vrijednost iz odgovarajuće ćelije.

Na primjer, da biste dobili vrijednost ćelije na osnovu broja reda u E1 i broja kolone u E2, koristite ovu formulu :

=INDIRECT(ADDRESS(E1,E2))

Nabavite adresućelije s najvećom ili najnižom vrijednošću

U ovom primjeru, prvo ćemo pronaći najviše i najniže vrijednosti u rasponu B2:B7 korištenjem funkcija MAX i MIN i iznijeti te vrijednosti u posebne ćelije:

Ćelija E2: =MAX(B2:B7)

Ćelija F2: =MIN(B2:B7)

I tada ćemo koristiti ADRESU u kombinaciji sa funkcijom MATCH da dobijte adrese ćelija.

Ćelija s maksimalnom vrijednošću:

=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))

Ćelija s minimalnom vrijednošću:

=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))

U slučaju da ne želite najviše i najniže vrijednosti u odvojenim ćelijama, možete ugnijezditi funkciju MAX/MIN u prvi argument MATCH. Na primjer:

Ćelija s najvećom vrijednošću:

=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))

Ćelija s najnižom vrijednošću:

=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))

Kako ove formule work

Da biste pronašli broj reda, koristite funkciju MATCH(lookup_value, lookup_array, [match_type]) koja vraća relativnu poziciju lookup_value u lookup_array. U našoj formuli, tražena vrijednost je broj koji vraća funkcija MAX ili MIN, a niz pretraživanja je cijeli stupac. Prema tome, relativna pozicija tražene vrijednosti u nizu tačno odgovara broju reda na listu.

Da biste pronašli broj kolone, koristite funkciju COLUM. Naravno, ništa vas ne sprečava da unesete broj direktno u formulu, ali COLUMN štedi nevolje ručnog brojanja u slučaju da je ciljni stupac u sredini lista.

Nabavite slovo stupcaiz broja kolone

Da pretvorite bilo koji dati broj u slovo stupca, koristite funkciju ADDRESS unutar SUBSTITUTE:

Kao primjer, pronađimo slovo stupca koje odgovara broju u A2:

=SUBSTITUTE(ADDRESS(1,A2,4),"1","")

Gledajući rezultate ispod, možemo reći da je prva kolona na listu je A, što je očigledno; 10. stupac je J, 50. stupac je AX, a 100. stupac je CV:

Kako ova formula funkcionira

Za početak, postavite ADDRESS funkcija za vraćanje relativne reference na prvu ćeliju u ciljnoj koloni:

• Za broj reda koristite 1.
• Za broj stupca navedite referencu na ćeliju koji sadrži broj, A2 u našem primjeru.
• Za argument abs_num unesite 4.

Kao rezultat, ADDRESS(1,A2,4) će vratiti A1.

Da biste se riješili koordinata reda, umotajte gornju formulu u funkciju SUBSTITUTE i zamijenite "1" praznim nizom (""). Gotovo!

Nabavite adresu imenovanog raspona

Da biste pronašli adresu imenovanog raspona u Excelu, prvo ćete morati dobiti prvu i posljednju referencu ćelije, a zatim ih spojiti . Ovo radi malo drugačije u preddinamičkom Excelu (2019 i stariji) i Dynamic Array Excel (Office 365 i Excel 2021). Primjeri u nastavku su za Excel 2019 - Excel 2007. Upute za Excel 365 i Excel 2021 suovdje.

Kako dobiti adresu prve ćelije u rasponu

Da biste vratili referencu na prvu ćeliju u imenovanom rasponu, koristite ovu generičku formulu:

Pod pretpostavkom da je raspon nazvan "Prodaja", prava formula glasi kako slijedi:

=ADDRESS(ROW(Sales), COLUMN(Sales))

I vraća adresu gornje lijeve ćelije u rasponu:

U ovoj formuli, funkcije ROW i COLUMN vraćaju niz svih brojeva redaka i stupaca u domet, respektivno. Na osnovu tih brojeva, funkcija ADDRESS gradi niz adresa ćelija. Ali pošto se formula unosi u jednu ćeliju, prikazuje se samo prva stavka niza, koja odgovara prvoj ćeliji u rasponu.

Kako dobiti adresu posljednje ćelije u rasponu

Da biste pronašli adresu posljednje ćelije u imenovanom rasponu, koristite ovu generičku formulu:

Primijenjena na naš raspon pod nazivom "Prodaja", formula poprima sljedeći oblik:

=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

I vraća referencu na donju desnu ćeliju raspona:

Ovaj put, trebamo malo složenije kalkulacije da razradimo red broj. Kao u prethodnom primjeru, funkcija ROW nam daje niz svih brojeva redova u rasponu, {4;5;6;7} u našem slučaju. Moramo da "pomerimo" ove brojeve za ukupan broj redova minus 1, tako daprva stavka u nizu postaje broj posljednjeg reda. Da bismo pronašli ukupan broj redova, koristimo funkciju ROWS i oduzimamo 1 od njenog rezultata: (4-1=3). Zatim dodajemo 3 svakom elementu početnog niza da izvršimo traženi pomak: {4;5;6;7} + 3 = {7;8;9;10}.

Broj kolone je izračunato na sličan način: {2,3,4}+3-1 = {4,5,6}

Od gornjih nizova brojeva redova i kolona, ​​funkcija ADDRESS sastavlja niz adresa ćelija , ali vraća samo prvu koja odgovara posljednjoj ćeliji u rasponu.

Isti rezultat se također može postići odabirom maksimalnih vrijednosti iz nizova brojeva redaka i stupca. Međutim, ovo funkcionira samo u formuli niza, koja zahtijeva da pritisnete Ctrl + Shift + Enter da bi se ispravno završilo:

=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))

Kako dobiti punu adresu imenovanog raspona

Da biste vratili kompletnu adresu imenovanog raspona, trebate samo spojiti dvije formule iz prethodnih primjera i umetnuti operator raspona (:) između.

Da bi to funkcioniralo za naš skup podataka uzorka, zamjenjujemo generički "raspon" pravim imenom raspona "Prodaja":

=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)

I dobijamo kompletnu adresu raspona kao apsolutna referenca $B$4:$D$7:

Za povratak rasponaadresu kao relativnu referencu (bez znaka $, kao B4:D7), postavite argument abs_num u obje funkcije ADDRESS na 4:

=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)

Naravno, iste promjene se mogu napraviti u pojedinačnim formulama za prvu i zadnju ćeliju, a rezultat će izgledati slično ovome:

Kako dobiti adresu imenovanog raspona u Excelu 365 i Excel 2021

Za razliku od tradicionalnog ponašanja "jedna formula - jedna ćelija" u starijim verzijama, u novom Excelu, svaka formula koja potencijalno može vratiti više vrijednosti, to radi automatski. Takvo ponašanje se naziva prolijevanje.

Na primjer, umjesto vraćanja adrese prve ćelije, formula ispod daje adrese svake ćelije u imenovanom rasponu:

=ADDRESS(ROW(Sales), COLUMN(Sales))

Da biste dobili adresu samo prve ćelije , morate omogućiti implicitno sjecište, koje se po defaultu pokreće u programu Excel 2019 i starijim. Za ovo stavite simbol @ (implicitni operator preseka) ispred imena opsega:

=ADDRESS(@ROW(Sales), @COLUMN(Sales))

Na sličan način možete popraviti druge formule.

Da biste dobili posljednja ćelija u rasponu:

=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Da biste dobili adresu imenovanog raspona :

=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)

Snimka ekrana ispod prikazuje rezultate:

Savjet. Prilikom otvaranja radnog lista sa formulama kreiranim u starijoj verziji u dinamičkom nizu Excel, Excel automatski ubacuje implicitni operator presjeka.

Tako možetevratite adresu ćelije u Excelu. Da biste bliže pogledali sve formule o kojima se govori u ovom vodiču, možete preuzeti naš primjer radne sveske ispod. Zahvaljujem vam na čitanju i nadam se da se vidimo na našem blogu sljedeće sedmice!

Vježbajte radnu svesku za preuzimanje

Excel funkcija ADRESA - primjeri formule (.xlsx datoteka)