Знаете ли как да съберете числата в определена колона, когато стойност в друга колона отговаря на някое от зададените условия? В тази статия ще научите 3 различни начина за извършване на SUMIF с помощта на множество критерии и логиката OR.

Microsoft Excel разполага със специална функция за сумиране на клетки с няколко условия - функцията SUMIFS. Тази функция е предназначена за работа с логиката AND - клетка се добавя само когато всички посочени критерии са верни за тази клетка. В някои ситуации обаче може да се наложи да сумирате с няколко критерия OR, т.е. да добавите клетка, когато някое от условията е вярно.е удобен.

SUMIF + SUMIF за сумиране на клетки, равни на това или онова

Когато искате да съберете числата в една колона, когато друга колона е равна на A или B, най-очевидното решение е да обработите всяко условие поотделно и след това да съберете резултатите:

Предположете, че в таблицата по-долу искате да съберете продажбите на два различни продукта, например Ябълки и Лимони За тази цел можете да въведете интересуващите ви елементи директно в критерии аргументи на 2 различни функции SUMIF:

=SUMIF(A2:A10, "ябълки", B2:B10) + SUMIF(A2:A10, "лимони", B2:B10)

Или можете да въведете критериите в отделни клетки и да се позовавате на тези клетки:

=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)

Където A2:A10 е списъкът с елементи ( обхват ), B2:B10 са числата за сумиране ( sum_rage ), E1 и E2 са целевите елементи ( критерии ):

Как работи тази формула:

Първата функция SUMIF сумира Ябълки продажби, а вторият SUMIF сумира Лимони Операцията за събиране събира междинните суми и извежда общата сума.

SUMIF с константа на масива - компактна формула с множество критерии

Подходът SUMIF + SUMIF работи добре за 2 условия. Ако трябва да сумирате с 3 или повече критерия, формулата ще стане твърде голяма и трудна за четене. За да постигнете същия резултат с по-компактна формула, въведете критериите си в константа на масив:

Не забравяйте, че тази формула работи на базата на логиката ИЛИ - дадена клетка се сумира, когато е изпълнено някое от условията.

В нашия случай, за да съберем продажбите на 3 различни артикула, формулата е:

=SUM(SUMIF(A2:A10, {"Ябълки", "Лимони", "Портокали"}, B2:B10))

В горната снимка условията са твърдо кодирани в масив, което означава, че ще трябва да актуализирате формулата при всяка промяна в критериите. За да избегнете това, можете да въведете критериите в предварително определени клетки и да ги предоставите на формулата като препратка към диапазон (E1:E3 в този пример).

=SUM(SUMIF(A2:A10, E1:E3, B2:B10))

В Excel 365, който поддържа динамични масиви, тя работи като обикновена формула, завършена с клавиша Enter. В преддинамичните версии на Excel 2019, Excel 2016, Excel 2013 и по-ранни версии тя трябва да бъде въведена като формула за масив с клавишната комбинация Ctrl + Shift + Enter:

Как работи тази формула:

Константата за масив, включена в критериите на SUMIF, го принуждава да връща множество резултати под формата на масив. В нашия случай това са 3 различни суми: за Ябълки , Лимони и Портокали :

{425;425;565}

За да получим общата сума, използваме функцията SUM и я обгръщаме с формулата SUMIF.

SUMPRODUCT и SUMIF за сумиране на клетки с множество условия OR

Не обичате масиви и търсите нормална формула, която да ви позволи да сумирате с няколко критерия в различни клетки? Няма проблем. Вместо SUM използвайте функцията SUMPRODUCT, която обработва масиви по естествен начин:

SUMPRODUCT(SUMIF(обхват, crireria_range , sum_range))

Ако приемем, че условията са в клетките E1, E2 и E3, формулата придобива следния вид:

=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))

Как работи тази формула:

Както в предишния пример, функцията SUMIF връща масив от числа, представляващи сумите за всяко отделно условие. SUMPRODUCT събира тези числа и извежда крайната сума. За разлика от функцията SUM, SUMPRODUCT е предназначена за обработка на масиви, така че работи като обикновена формула, без да се налага да натискате Ctrl + Shift + Enter .

SUMIF с използване на множество критерии със заместващи символи

Тъй като функцията SUMIF на Excel поддържа заместващи символи, можете да ги включите в няколко критерия, ако е необходимо.

Например, за да обобщите продажбите за всички видове Ябълки и Банани , формулата е:

=SUM(SUMIF(A2:A10, {"*Ябълки", "*Банани"}, B2:B10))

Ако условията трябва да се въвеждат в отделни клетки, можете да въведете заместващи знаци директно в тези клетки и да предоставите препратка към диапазона като критерий за формулата SUMPRODUCT SUMIF:

В този пример поставяме заместващ символ (*) пред имената на елементите, за да съвпада с всяка предходна последователност от символи, като например Зелени ябълки и Банани Goldfinger За да получите обща сума за елементите, които съдържат определен текст където и да е в клетката, поставете звездичка от двете страни, например "*apple*".

Това е начинът за използване на SUMIF в Excel с множество условия. Благодаря ви, че прочетохте, и се надявам да се видим в нашия блог следващата седмица!

Практическа работна тетрадка за изтегляне

SUMIF множество критерии (.xlsx файл)