Ynhâldsopjefte
Witte jo hoe't jo getallen yn in bepaalde kolom optelle moatte as in wearde yn in oare kolom oan ien fan 'e opjûne betingsten foldocht? Yn dit artikel sille jo 3 ferskillende manieren leare om SUMIF te dwaan mei meardere kritearia en OR-logika.
Microsoft Excel hat in spesjale funksje om sellen mei meardere betingsten op te tellen - de SUMIFS-funksje. Dizze funksje is ûntworpen om te wurkjen mei EN-logika - in sel wurdt allinich tafoege as alle opjûne kritearia TRUE binne foar dy sel. Yn guon situaasjes, ma jo miskien moatte som mei meardere OR kritearia, dat wol sizze in foegjen in sel as ien fan de betingsten is TRUE. En dit is wannear't de SUMIF-funksje fan pas komt.
SUMIF + SUMIF om sellen gelyk oan dit of dat op te tellen
As jo sykje om nûmers yn ien kolom op te tellen as in oare kolom gelyk is oan of A of B, is de meast foar de hân lizzende oplossing om elke betingst yndividueel te behanneljen, en dan de resultaten byinoar op te foegjen:
SUMIF(berik, kritearia1, som_berik) + SUMIF(berik) , criteria2, sum_range)Stel yn 'e tabel hjirûnder dat jo ferkeap optelle wolle foar twa ferskillende produkten, sis Apples en Sitroenen . Hjirfoar kinne jo de items fan belang direkt yn 'e kritearia arguminten fan 2 ferskillende SUMIF-funksjes leverje:
=SUMIF(A2:A10, "apples", B2:B10) + SUMIF(A2:A10, "lemons", B2:B10)
Of jo kinne de kritearia yn aparte sellen ynfiere, en ferwize nei dy sellen:
=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)
Wêr't A2:A10 de list fan items is ( berik ), B2:B10binne de nûmers om op te tellen ( sum_rage ), E1 en E2 binne de doelitems ( kritearia ):
Hoe dizze formule wurket:
De earste SUMIF-funksje telt de Apples -ferkeap by, de twadde SUMIF somt de Lemons -ferkeap op. De tafoegingsoperaasje foeget de subtotalen byinoar ta en jout it totaal út.
SUMIF mei arraykonstante - kompakte formule mei meardere kritearia
De SUMIF + SUMIF-oanpak wurket goed foar 2 betingsten. As jo moatte sommen mei 3 of mear kritearia, de formule wurdt te grut en lestich te lêzen. Om itselde resultaat te berikken mei in kompakter formule, leverje jo kritearia yn in arraykonstante:
SUM(SUMIF(berik, { crireria1, crireria2, crireria3, …}, sum_range))Tink derom dat dizze formule wurket op basis fan OR-logika - in sel wurdt gearfette as oan ien inkelde betingst is foldien.
Yn ús gefal, om ferkeap foar 3 ferskillende optellen items, de formule is:
=SUM(SUMIF(A2:A10, {"Apples","Lemons","Oranges"}, B2:B10))
Yn it boppesteande skermôfbylding binne de betingsten hardkodearre yn in array, wat betsjut dat jo de formule moatte bywurkje mei elke feroaring yn 'e kritearia. Om dit te foarkommen, kinne jo de kritearia ynfiere yn foarôf definieare sellen en oan in formule leverje as berikferwizing (E1:E3 yn dit foarbyld).
=SUM(SUMIF(A2:A10, E1:E3, B2:B10))
Yn Excel 365 dat dynamyske arrays stipet , it wurket as in gewoane formule foltôge mei de Enter-kaai. Yn pre-dynamyske ferzjes fan Excel 2019, Excel 2016, Excel2013 en earder, moat it ynfierd wurde as in arrayformule mei de fluchtoets Ctrl + Shift + Enter:
Hoe wurket dizze formule:
In arraykonstante ynplugd yn 'e kritearia fan SUMIF twingt it om meardere resultaten werom te jaan yn 'e foarm fan in array. Yn ús gefal binne it 3 ferskillende bedraggen: foar appels , citroenen en sinaasappels :
{425;425;565}
Om de totaal, wy brûke de SUM-funksje en wikkelje it om de SUMIF-formule.
SUMPRODUCT en SUMIF om sellen op te tellen mei meardere OR-betingsten
Hâld net fan arrays en sykje in normale formule dy't soe tastean jo te sum mei meardere kritearia yn ferskillende sellen? Gjin probleem. Yn stee fan SUM, brûk de SUMPRODUCT-funksje dy't arrays native behannelet:
SUMPRODUCT(SUMIF(berik, crireria_berik , som_berik))
As der fan útgien wurdt dat de betingsten yn sellen E1 binne, E2 en E3, de formule nimt dizze foarm oan:
=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
Hoe wurket dizze formule:
Like yn it foarige foarbyld jout de SUMIF-funksje in array fan nûmers werom, dy't de sommen foar elke yndividuele betingst fertsjintwurdigje. SUMPRODUCT foeget dizze nûmers byinoar ta en jout in definitive totaal út. Oars as de SUM-funksje is SUMPRODUCT ûntworpen om arrays te ferwurkjen, dus it wurket as in gewoane formule sûnder dat jo op Ctrl + Shift + Enter hoege te drukken.
SUMIF mei meardere kritearia mei jokertekens
Sûnt de Excel SUMIF funksje stipet jokertekens, do kinstopnimme se yn meardere kritearia as it nedich is.
Om bygelyks ferkeap foar alle soarten Apples en bananen op te tellen, is de formule:
=SUM(SUMIF(A2:A10, {"*Apples","*Bananas"}, B2:B10))
As jo betingsten moatte wurde ynfierd yn yndividuele sellen, kinne jo jokertekens direkt yn dy sellen ynfiere en in berikferwizing leverje as kritearia foar de SUMPRODUCT SUMIF-formule:
Yn dit foarbyld sette wy in jokerteken (*) foar de itemnammen om oerien te kommen mei elke foarôfgeande folchoarder fan tekens lykas Griene appels en Goldfinger bananen . Om in totaal te krijen foar items dy't spesifike tekst oeral yn in sel befetsje, pleats in asterisk oan beide kanten, bgl. "*appel*".
Dat is hoe SUMIF te brûken yn Excel mei meardere betingsten. Ik tankje jo foar it lêzen en hoopje jo nije wike op ús blog te sjen!
Oefeningswurkboek foar download
SUMIF meardere kritearia (.xlsx-bestân)
