جدول المحتويات
هل تعرف كيفية جمع الأرقام في عمود معين عندما تفي قيمة في عمود آخر بأي من الشروط المحددة؟ في هذه المقالة ، ستتعلم 3 طرق مختلفة لإجراء SUMIF باستخدام معايير متعددة ومنطق OR.
يحتوي Microsoft Excel على وظيفة خاصة لتجميع الخلايا بشروط متعددة - وظيفة SUMIFS. تم تصميم هذه الوظيفة للعمل مع منطق AND - تتم إضافة خلية فقط عندما تكون جميع المعايير المحددة صحيحة لتلك الخلية. ومع ذلك ، في بعض الحالات ، قد تحتاج إلى الجمع باستخدام معايير OR متعددة ، أي لإضافة خلية عندما يكون أي من الشروط صحيحًا. وهذا عندما تكون وظيفة SUMIF سهلة الاستخدام.
SUMIF + SUMIF لجمع الخلايا التي تساوي هذا أو ذاك
عندما تبحث عن جمع الأرقام في عمود واحد عندما يساوي عمود آخر إما A أو B ، فإن الحل الأكثر وضوحًا هو معالجة كل شرط على حدة ، ثم جمع النتائج معًا:
SUMIF (range ، criteria1، sum_range) + SUMIF (range ، criteria2، sum_range)في الجدول أدناه ، افترض أنك تريد إضافة مبيعات لمنتجين مختلفين ، قل تفاح و ليمون . لهذا ، يمكنك توفير العناصر ذات الأهمية مباشرة في معايير وسيطات لدالتين مختلفتين SUMIF:
=SUMIF(A2:A10, "apples", B2:B10) + SUMIF(A2:A10, "lemons", B2:B10)
أو يمكنك إدخال المعايير في خلايا منفصلة ، وارجع إلى تلك الخلايا:
=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)
حيث A2: A10 هي قائمة العناصر ( النطاق ) ، B2: B10هي الأرقام المراد جمعها ( sum_rage ) ، E1 و E2 هي العناصر المستهدفة ( المعايير ):
كيف تعمل هذه الصيغة:
تضيف الدالة SUMIF الأولى مبيعات التفاح ، بينما تجمع الدالة SUMIF الثانية مبيعات الليمون . تقوم عملية الإضافة بإضافة المجاميع الفرعية معًا وإخراج الإجمالي.
SUMIF مع ثابت الصفيف - صيغة مضغوطة بمعايير متعددة
يعمل نهج SUMIF + SUMIF جيدًا لشرطين. إذا كنت بحاجة إلى الجمع مع 3 معايير أو أكثر ، فستصبح الصيغة كبيرة جدًا ويصعب قراءتها. لتحقيق نفس النتيجة باستخدام صيغة أكثر إحكاما ، قدم معاييرك في ثابت صفيف:
الرجاء تذكر أن هذه الصيغة تعمل على أساس منطق OR - يتم جمع الخلية عند استيفاء أي شرط واحد.
في حالتنا ، لجمع المبيعات لـ 3 مختلفة العناصر ، الصيغة هي:
=SUM(SUMIF(A2:A10, {"Apples","Lemons","Oranges"}, B2:B10))
في لقطة الشاشة أعلاه ، يتم ترميز الشروط في مصفوفة ، مما يعني أنه سيتعين عليك تحديث الصيغة باستخدام كل تغيير في المعايير. لتجنب ذلك ، يمكنك إدخال المعايير في خلايا محددة مسبقًا وتوفير صيغة كمرجع نطاق (E1: E3 في هذا المثال).
=SUM(SUMIF(A2:A10, E1:E3, B2:B10))
في Excel 365 الذي يدعم المصفوفات الديناميكية ، تعمل كصيغة عادية مكتملة بمفتاح Enter. في الإصدارات السابقة للديناميكية من Excel 2019 و Excel 2016 و Excel2013 وما قبله ، يجب إدخاله كصيغة صفيف باستخدام الاختصار Ctrl + Shift + Enter:
كيف تعمل هذه الصيغة:
ثابت صفيف متصل بمعايير SUMIF يجبره على إرجاع نتائج متعددة في شكل مصفوفة. في حالتنا ، هناك 3 كميات مختلفة: التفاح ، الليمون و البرتقال :
{425;425;565}
للحصول على إجماليًا ، نستخدم الدالة SUM ونلفها حول صيغة SUMIF.
SUMPRODUCT و SUMIF لتجميع الخلايا بشروط أو متعددة
لا تحب المصفوفات وتبحث عن صيغة عادية سيسمح لك بالتجميع مع معايير متعددة في خلايا مختلفة؟ لا مشكلة. بدلاً من SUM ، استخدم الدالة SUMPRODUCT التي تتعامل مع المصفوفات في الأصل:
SUMPRODUCT (SUMIF (range ، crireria_range ، sum_range))
بافتراض أن الشروط موجودة في الخلايا E1 ، E2 و E3 ، تأخذ الصيغة هذا الشكل:
=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
كيف تعمل هذه الصيغة:
مثل في المثال السابق ، تُرجع الدالة SUMIF صفيفًا من الأرقام ، يمثل مجاميع كل شرط على حدة. يجمع SUMPRODUCT هذه الأرقام معًا ويخرج الإجمالي النهائي. بخلاف دالة SUM ، تم تصميم SUMPRODUCT لمعالجة المصفوفات ، لذا فهي تعمل كصيغة عادية دون الحاجة إلى الضغط على Ctrl + Shift + Enter.
SUMIF باستخدام معايير متعددة مع أحرف البدل
منذ تدعم وظيفة Excel SUMIF أحرف البدل ، يمكنك ذلكقم بتضمينها في معايير متعددة إذا لزم الأمر.
على سبيل المثال ، لجمع المبيعات لجميع أنواع التفاح و الموز ، الصيغة هي:
=SUM(SUMIF(A2:A10, {"*Apples","*Bananas"}, B2:B10))
إذا كان من المفترض أن يتم إدخال الشروط الخاصة بك في خلايا فردية ، فيمكنك كتابة أحرف البدل مباشرةً في تلك الخلايا وتوفير مرجع نطاق كمعايير لصيغة SUMPRODUCT SUMIF:
في هذا المثال ، نضع حرف بدل (*) قبل أسماء العناصر لمطابقة أي تسلسل سابق للأحرف مثل Green apples و Goldfinger bananas . للحصول على إجمالي للعناصر التي تحتوي على نص معين في أي مكان في الخلية ، ضع علامة النجمة على كلا الجانبين ، على سبيل المثال "* apple *".
هذه هي طريقة استخدام SUMIF في Excel بشروط متعددة. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل!
تدرب على تنزيل المصنف
معايير SUMIF المتعددة (ملف .xlsx)
