Inhoudsopgave
Weet u hoe u getallen in een bepaalde kolom kunt optellen wanneer een waarde in een andere kolom aan een van de opgegeven voorwaarden voldoet? In dit artikel leert u 3 verschillende manieren om SUMIF uit te voeren met behulp van meerdere criteria en OR-logica.
Microsoft Excel heeft een speciale functie om cellen met meerdere voorwaarden op te tellen - de SUMIFS-functie. Deze functie is ontworpen om te werken met EN-logica - een cel wordt alleen toegevoegd wanneer alle opgegeven criteria voor die cel WAAR zijn. In sommige situaties moet u echter optellen met meerdere OF-criteria, d.w.z. een cel toevoegen wanneer een van de voorwaarden WAAR is. En dit is wanneer de SUMIF-functiekomt goed van pas.
SUMIF + SUMIF om cellen gelijk aan dit of dat op te tellen
Wanneer u getallen in een kolom wilt optellen wanneer een andere kolom gelijk is aan A of B, is de meest voor de hand liggende oplossing om elke voorwaarde afzonderlijk te behandelen, en vervolgens de resultaten bij elkaar op te tellen:
SUMIF(range, criteria1 , sum_range) + SUMIF(range, criteria2 , sum_range)Stel dat u in de onderstaande tabel de verkopen van twee verschillende producten wilt optellen, bijvoorbeeld Appels en Citroenen Hiervoor kunt u de items van belang direct in de criteria argumenten van 2 verschillende SUMIF-functies:
=SUMIF(A2:A10, "appels", B2:B10) + SUMIF(A2:A10, "citroenen", B2:B10)
Of u kunt de criteria in afzonderlijke cellen invoeren, en naar die cellen verwijzen:
=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)
Waarbij A2:A10 de lijst van items is ( reeks ), B2:B10 zijn de op te tellen getallen ( sum_rage ), E1 en E2 zijn de doelartikelen ( criteria ):
Hoe deze formule werkt:
De eerste SUMIF-functie telt de Appels verkoop, de tweede SUMIF telt de Citroenen De optelling telt de subtotalen bij elkaar op en geeft het totaal.
SUMIF met matrixconstante - compacte formule met meerdere criteria
De SUMIF + SUMIF aanpak werkt prima voor 2 voorwaarden. Als u moet optellen met 3 of meer criteria, wordt de formule te groot en moeilijk leesbaar. Om hetzelfde resultaat te bereiken met een compactere formule, levert u uw criteria in een matrixconstante:
SUM(SUMIF(range, { crireria1 , crireria2 , crireria3 , ...}, sum_range))Vergeet niet dat deze formule werkt op basis van OR-logica - een cel wordt opgeteld wanneer aan één voorwaarde is voldaan.
In ons geval, om de verkoop van 3 verschillende artikelen op te tellen, is de formule:
=SUM(SUMIF(A2:A10, {"Appels","Citroenen","Sinaasappels"}, B2:B10))
In het bovenstaande screenshot zijn de voorwaarden hard gecodeerd in een array, wat betekent dat u de formule moet bijwerken bij elke wijziging in de criteria. Om dit te vermijden kunt u de criteria invoeren in vooraf gedefinieerde cellen en aan een formule leveren als een bereikreferentie (E1:E3 in dit voorbeeld).
=SUM(SUMIF(A2:A10, E1:E3, B2:B10))
In Excel 365 dat dynamische matrices ondersteunt, werkt het als een gewone formule die wordt ingevuld met de Enter-toets. In pre-dynamische versies van Excel 2019, Excel 2016, Excel 2013 en eerder moet het worden ingevoerd als een matrixformule met de sneltoets Ctrl + Shift + Enter:
Hoe deze formule werkt:
Een matrixconstante in de criteria van SUMIF dwingt het programma om meerdere resultaten in de vorm van een matrix terug te geven. In ons geval zijn het 3 verschillende bedragen: voor Appels , Citroenen en Sinaasappels :
{425;425;565}
Om het totaal te krijgen, gebruiken we de SUM-functie en wikkelen die om de SUMIF-formule.
SUMPRODUCT en SUMIF om cellen met meerdere OF-voorwaarden op te tellen
Houdt u niet van arrays en bent u op zoek naar een normale formule waarmee u meerdere criteria in verschillende cellen kunt optellen? Geen probleem. Gebruik in plaats van SUM de functie SUMPRODUCT, die van nature arrays verwerkt:
SUMPRODUCT(SUMIF(range, crireria_range , sum_range))
Ervan uitgaande dat de voorwaarden in de cellen E1, E2 en E3 staan, krijgt de formule deze vorm:
=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
Hoe deze formule werkt:
Net als in het vorige voorbeeld geeft de SUMIF-functie een matrix van getallen, die de sommen voor elke afzonderlijke voorwaarde weergeven. SUMPRODUCT telt deze getallen bij elkaar op en geeft een eindtotaal. In tegenstelling tot de SUM-functie is SUMPRODUCT ontworpen om matrices te verwerken, dus het werkt als een gewone formule zonder dat u op Ctrl + Shift + Enter hoeft te drukken.
SUMIF met meerdere criteria met jokertekens
Aangezien de Excel SUMIF-functie jokertekens ondersteunt, kunt u deze zo nodig in meerdere criteria opnemen.
Bijvoorbeeld, om de verkoop op te tellen voor alle soorten Appels en Bananen is de formule:
=SUM(SUMIF(A2:A10, {"*Appels","*Bananen"}, B2:B10))
Als uw voorwaarden in afzonderlijke cellen moeten worden ingevoerd, kunt u jokertekens rechtstreeks in die cellen typen en een bereikverwijzing opgeven als criteria voor de SUMPRODUCT SUMIF-formule:
In dit voorbeeld plaatsen we een jokerteken (*) vóór de itemnamen om te voldoen aan elke voorafgaande reeks tekens zoals Groene appels en Goldfinger bananen Om een totaal te krijgen voor items die ergens in een cel specifieke tekst bevatten, plaatst u een sterretje aan beide zijden, bijvoorbeeld "*appel*".
Zo gebruik je SUMIF in Excel met meerdere voorwaarden. Ik dank je voor het lezen en hoop je volgende week op onze blog te zien!
Praktijk werkboek om te downloaden
SUMIF meerdere criteria (.xlsx bestand)
