Bạn có biết cách tính tổng các số trong một cột nhất định khi một giá trị trong cột khác đáp ứng bất kỳ điều kiện nào được chỉ định không? Trong bài viết này, bạn sẽ tìm hiểu 3 cách khác nhau để tính SUMIF bằng cách sử dụng nhiều tiêu chí và logic OR.

Microsoft Excel có một hàm đặc biệt để tính tổng các ô có nhiều điều kiện - hàm SUMIFS. Hàm này được thiết kế để hoạt động với logic AND - một ô chỉ được thêm khi tất cả các tiêu chí đã chỉ định là ĐÚNG cho ô đó. Tuy nhiên, trong một số trường hợp, bạn có thể cần tính tổng với nhiều tiêu chí OR, tức là để thêm một ô khi bất kỳ điều kiện nào là TRUE. Và đây chính là lúc hàm SUMIF phát huy tác dụng.

SUMIF + SUMIF để tính tổng các ô bằng giá trị này hoặc giá trị kia

Khi bạn muốn tính tổng các số trong một cột khi một cột khác bằng A hoặc B, giải pháp rõ ràng nhất là xử lý từng điều kiện riêng lẻ rồi cộng các kết quả lại với nhau:

Trong bảng bên dưới, giả sử bạn muốn cộng doanh số cho hai sản phẩm khác nhau, chẳng hạn như Táo và Chanh . Đối với điều này, bạn có thể cung cấp các mục quan tâm trực tiếp trong các đối số tiêu chí của 2 hàm SUMIF khác nhau:

=SUMIF(A2:A10, "apples", B2:B10) + SUMIF(A2:A10, "lemons", B2:B10)

Hoặc bạn có thể nhập tiêu chí vào các ô riêng biệt, và tham khảo các ô đó:

=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)

Trong đó A2:A10 là danh sách các mục ( phạm vi ), B2:B10là các số cần tính tổng ( sum_rage ), E1 và E2 là các mục đích ( criteria ):

Cách thức hoạt động của công thức này:

Hàm SUMIF đầu tiên cộng doanh số Táo , hàm SUMIF thứ hai tính tổng doanh số Chanh . Phép toán cộng cộng các tổng phụ lại với nhau và xuất ra tổng.

SUMIF với hằng số mảng - công thức thu gọn với nhiều tiêu chí

Phương pháp SUMIF + SUMIF hoạt động tốt với 2 điều kiện. Nếu bạn cần tính tổng với 3 tiêu chí trở lên, công thức sẽ trở nên quá lớn và khó đọc. Để đạt được kết quả tương tự với một công thức nhỏ gọn hơn, hãy cung cấp tiêu chí của bạn trong một hằng số mảng:

Hãy nhớ rằng công thức này hoạt động dựa trên logic OR - một ô được tính tổng khi bất kỳ điều kiện đơn lẻ nào được đáp ứng.

Trong trường hợp của chúng tôi, để tính tổng doanh số cho 3 ô khác nhau items, công thức là:

=SUM(SUMIF(A2:A10, {"Apples","Lemons","Oranges"}, B2:B10))

Trong ảnh chụp màn hình ở trên, các điều kiện được mã hóa cứng trong một mảng, nghĩa là bạn sẽ phải cập nhật công thức với mỗi thay đổi trong các tiêu chí. Để tránh điều này, bạn có thể nhập tiêu chí vào các ô được xác định trước và cung cấp cho một công thức dưới dạng tham chiếu phạm vi (E1:E3 trong ví dụ này).

=SUM(SUMIF(A2:A10, E1:E3, B2:B10))

Trong Excel 365 hỗ trợ mảng động , nó hoạt động như một công thức thông thường được hoàn thành bằng phím Enter. Trong các phiên bản tiền động của Excel 2019, Excel 2016, Excel2013 trở về trước, nó phải được nhập dưới dạng công thức mảng bằng phím tắt Ctrl + Shift + Enter:

Cách thức hoạt động của công thức này:

Một hằng số mảng được cắm vào tiêu chí của SUMIF buộc nó trả về nhiều kết quả dưới dạng một mảng. Trong trường hợp của chúng tôi, đó là 3 số tiền khác nhau: đối với Táo , Chanh và Cam :

{425;425;565}

Để lấy tổng, chúng tôi sử dụng hàm SUM và bao hàm nó xung quanh công thức SUMIF.

SUMPRODUCT và SUMIF để tính tổng các ô có nhiều điều kiện OR

Không thích mảng và đang tìm kiếm một công thức bình thường sẽ cho phép bạn tính tổng với nhiều tiêu chí trong các ô khác nhau? Không vấn đề gì. Thay vì SUM, hãy sử dụng hàm SUMPRODUCT xử lý các mảng nguyên bản:

SUMPRODUCT(SUMIF(range, crireria_range , sum_range))

Giả sử các điều kiện nằm trong các ô E1, E2 và E3, công thức có dạng như sau:

=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))

Cách thức hoạt động của công thức này:

Giống như trong ví dụ trước, hàm SUMIF trả về một mảng số, biểu thị tổng cho từng điều kiện riêng lẻ. TÓM TẮT cộng các số này lại với nhau và đưa ra tổng cuối cùng. Không giống như hàm SUM, SUMPRODUCT được thiết kế để xử lý mảng, vì vậy hàm này hoạt động như một công thức thông thường mà bạn không cần phải nhấn Ctrl + Shift + Enter .

SUMIF sử dụng nhiều tiêu chí với ký tự đại diện

Vì Hàm SUMIF của Excel hỗ trợ ký tự đại diện, bạn có thểđưa chúng vào nhiều tiêu chí nếu cần.

Ví dụ: để tính tổng doanh số cho tất cả các loại Táo và Chuối , công thức là:

=SUM(SUMIF(A2:A10, {"*Apples","*Bananas"}, B2:B10))

Nếu các điều kiện của bạn được cho là nhập vào trong các ô riêng lẻ, thì bạn có thể nhập ký tự đại diện trực tiếp vào các ô đó và cung cấp tham chiếu phạm vi làm tiêu chí cho công thức TỔNG HỢP SẢN PHẨM:

Trong ví dụ này, chúng tôi đặt ký tự đại diện (*) trước tên mục để khớp với bất kỳ chuỗi ký tự nào trước đó, chẳng hạn như Táo xanh và Chuối ngón tay vàng . Để có tổng số cho các mục chứa văn bản cụ thể ở bất kỳ đâu trong ô, hãy đặt dấu hoa thị ở cả hai bên, ví dụ: "*apple*".

Đó là cách sử dụng SUMIF trong Excel với nhiều điều kiện. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!

Sách bài tập thực hành để tải xuống

SUMIF nhiều tiêu chí (tệp .xlsx)