Cuprins
Știți cum să însumați numerele dintr-o anumită coloană atunci când o valoare dintr-o altă coloană îndeplinește oricare dintre condițiile specificate? În acest articol, veți învăța 3 moduri diferite de a face SUMIF folosind criterii multiple și logica OR.
Microsoft Excel dispune de o funcție specială pentru a însuma celule cu mai multe condiții - funcția SUMIFS. Această funcție este concepută pentru a lucra cu logica ȘI - o celulă este adăugată numai atunci când toate criteriile specificate sunt ADEVĂRATE pentru acea celulă. În unele situații, totuși, este posibil să aveți nevoie să însumați cu mai multe criterii OR, adică să adăugați o celulă atunci când oricare dintre condiții este ADEVĂRATĂ. Și acesta este momentul în care funcția SUMIFse dovedește utilă.
SUMIF + SUMIF pentru a aduna celule egale cu aceasta sau aceea
Atunci când doriți să adunați numere dintr-o coloană atunci când o altă coloană este egală cu A sau B, cea mai evidentă soluție este să tratați fiecare condiție în parte, iar apoi să adăugați rezultatele împreună:
SUMIF(interval, criterii1 , sum_range) + SUMIF(range, criterii2 , sum_range)În tabelul de mai jos, să presupunem că doriți să adunați vânzările pentru două produse diferite, de exemplu Mere și Lămâi În acest scop, puteți furniza elementele de interes direct în rubrica criterii argumentele a 2 funcții SUMIF diferite:
=SUMIF(A2:A10, "mere", B2:B10) + SUMIF(A2:A10, "lămâi", B2:B10)
Sau puteți introduce criteriile în celule separate și să faceți trimitere la aceste celule:
=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)
Unde A2:A10 este lista de elemente ( gama ), B2:B10 sunt numerele de adunat ( sum_rage ), E1 și E2 sunt elementele țintă ( criterii ):
Cum funcționează această formulă:
Prima funcție SUMIF însumează Mere vânzări, al doilea SUMIF însumează Lămâi Operațiunea de adunare însumează subtotalurile și obține totalul.
SUMIF cu constantă de matrice - formulă compactă cu criterii multiple
Abordarea SUMIF + SUMIF funcționează bine pentru 2 condiții. Dacă trebuie să adunați cu 3 sau mai multe criterii, formula va deveni prea mare și greu de citit. Pentru a obține același rezultat cu o formulă mai compactă, furnizați criteriile într-o constantă de matrice:
SUM(SUMIF(interval, { crireria1 , crireria2 , crireria3 , ...}, sum_range)))Vă rugăm să rețineți că această formulă funcționează pe baza logicii OR - o celulă este însumată atunci când este îndeplinită o singură condiție.
În cazul nostru, pentru a însuma vânzările pentru 3 articole diferite, formula este:
=SUM(SUMIF(A2:A10, {"Mere", "Lămâi", "Portocale"}, B2:B10))
În captura de ecran de mai sus, condițiile sunt codificate într-o matrice, ceea ce înseamnă că va trebui să actualizați formula la fiecare modificare a criteriilor. Pentru a evita acest lucru, puteți introduce criteriile în celule predefinite și le puteți furniza unei formule ca referință la un interval (E1:E3 în acest exemplu).
=SUM(SUMIF(A2:A10, E1:E3, B2:B10))
În Excel 365, care acceptă matrice dinamice, funcționează ca o formulă obișnuită completată cu tasta Enter. În versiunile pre-dinamice ale Excel 2019, Excel 2016, Excel 2013 și anterioare, trebuie introdusă ca o formulă de matrice cu ajutorul comenzii rapide Ctrl + Shift + Enter:
Cum funcționează această formulă:
O constantă de tablou introdusă în criteriile SUMIF îl forțează să returneze mai multe rezultate sub forma unui tablou. În cazul nostru, este vorba de 3 sume diferite: pentru Mere , Lămâi și Portocale :
{425;425;565}
Pentru a obține totalul, folosim funcția SUM și o înfășurăm în jurul formulei SUMIF.
SUMPRODUCT și SUMIF pentru a aduna celule cu mai multe condiții OR
Nu vă plac array-urile și căutați o formulă normală care să vă permită să adunați mai multe criterii în celule diferite? Nicio problemă. În loc de SUM, utilizați funcția SUMPRODUCT care gestionează array-urile în mod nativ:
SUMPRODUCT(SUMIF(range, crireria_range , sum_range)))
Presupunând că condițiile se află în celulele E1, E2 și E3, formula are următoarea formă:
=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
Cum funcționează această formulă:
La fel ca în exemplul anterior, funcția SUMIF returnează un tablou de numere, reprezentând sumele pentru fiecare condiție individuală. SUMPRODUCT adună aceste numere și produce un total final. Spre deosebire de funcția SUM, SUMPRODUCT este concepută pentru a procesa tablouri, astfel încât funcționează ca o formulă obișnuită, fără a fi nevoie să apăsați Ctrl + Shift + Enter .
SUMIF utilizând criterii multiple cu caractere wildcards
Deoarece funcția Excel SUMIF acceptă caractere wildcard, le puteți include în mai multe criterii, dacă este necesar.
De exemplu, pentru a însuma vânzările pentru toate tipurile de Mere și Banane , formula este:
=SUM(SUMIF(A2:A10, {"*Mere", "*Banane"}, B2:B10))
În cazul în care condițiile dvs. trebuie să fie introduse în celule individuale, puteți tasta wildcards direct în acele celule și puteți furniza o referință de interval ca și criteriu pentru formula SUMPRODUCT SUMIF:
În acest exemplu, am pus un caracter wildcard (*) înainte de numele elementelor pentru a se potrivi cu orice secvență de caractere anterioare, cum ar fi Mere verzi și Banane Goldfinger Pentru a obține un total pentru elementele care conțin un text specific oriunde într-o celulă, puneți un asterisc în ambele părți, de exemplu "*apple*".
Iată cum se utilizează SUMIF în Excel cu condiții multiple. Vă mulțumesc pentru lectură și sper să ne vedem pe blog săptămâna viitoare!
Caietul de practică pentru descărcare
SUMIF criterii multiple (fișier .xlsx)
