Vai zināt, kā summēt skaitļus noteiktā slejā, ja vērtība citā slejā atbilst kādam no norādītajiem nosacījumiem? Šajā rakstā uzzināsiet 3 dažādus veidus, kā veikt SUMIF, izmantojot vairākus kritērijus un OR loģiku.

Microsoft Excel ir īpaša funkcija, lai summētu šūnas ar vairākiem nosacījumiem - funkcija SUMIFS. Šī funkcija ir paredzēta darbam ar AND loģiku - šūna tiek pievienota tikai tad, ja visi norādītie kritēriji šai šūnai ir TRUE. Tomēr dažās situācijās var būt nepieciešams summēt ar vairākiem OR kritērijiem, t. i., pievienot šūnas, ja kāds no nosacījumiem ir TRUE. Un tieši tad funkcija SUMIFir ļoti noderīgs.

SUMIF + SUMIF, lai summētu šūnas, kas vienādas ar šo vai šo

Ja vēlaties saskaitīt skaitļus vienā slejā, ja cita sleja ir vienāda ar A vai B, visvienkāršākais risinājums ir apstrādāt katru nosacījumu atsevišķi un pēc tam saskaitīt rezultātus kopā:

Pieņemsim, ka turpmāk dotajā tabulā vēlaties saskaitīt divu dažādu produktu pārdošanas apjomus, piemēram. Āboli un Citroni . Šim nolūkam interesējošos vienumus varat ievadīt tieši programmā kritēriji 2 dažādu SUMIF funkciju argumenti:

=SUMIF(A2:A10, "āboli", B2:B10) + SUMIF(A2:A10, "citroni", B2:B10)

Varat arī ievadīt kritērijus atsevišķās šūnās un atsaukties uz šīm šūnām:

=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)

kur A2:A10 ir elementu saraksts ( diapazons ), B2:B10 ir skaitļi, kas jāsummē ( sum_rage ), E1 un E2 ir mērķa elementi ( kritēriji ):

Kā šī formula darbojas:

Pirmā SUMIF funkcija summē Āboli pārdošanas apjomu, otrajā SUMIF summē Citroni Saskaitīšanas operācija summē starpsummas un izvada kopsummu.

SUMIF ar masīva konstantu - kompakta formula ar vairākiem kritērijiem

SUMIF + SUMIF pieeja darbojas labi 2 nosacījumu gadījumā. Ja nepieciešams summēt ar 3 vai vairāk kritērijiem, formula kļūs pārāk liela un grūti salasāma. Lai sasniegtu tādu pašu rezultātu ar kompaktāku formulu, norādiet kritērijus masīva konstantē:

Lūdzu, atcerieties, ka šī formula darbojas, pamatojoties uz OR loģiku - šūna tiek summēta, ja ir izpildīts kāds no nosacījumiem.

Mūsu gadījumā, lai summētu 3 dažādu preču pārdošanas apjomu, formula ir šāda:

=SUM(SUMIF(A2:A10, {"Āboli", "Citroni", "Apelsīni"}, B2:B10))

Iepriekš redzamajā ekrānšā attēlā nosacījumi ir kodēti masīvā, kas nozīmē, ka jums būs jāatjaunina formula ar katru kritēriju izmaiņu. Lai no tā izvairītos, varat ievadīt kritērijus iepriekš definētās šūnās un sniegt formulā kā atsauci uz diapazonu (šajā piemērā E1:E3).

=SUM(SUMIF(A2:A10, E1:E3, B2:B10))

Programmā Excel 365, kas atbalsta dinamiskos masīvus, tas darbojas kā parasta formula, kas pabeigta ar taustiņu Enter. Pirms dinamiskās Excel 2019, Excel 2016, Excel 2013 un agrākajās versijās tas jāievada kā masīva formula, izmantojot īsceļu Ctrl + Shift + Enter:

Kā šī formula darbojas:

Masīva konstante, kas iekļauta SUMIF kritērijos, liek tam atgriezt vairākus rezultātus masīva formā. Mūsu gadījumā tās ir 3 dažādas summas: for Āboli , Citroni un Apelsīni :

{425;425;565}

Lai iegūtu kopsummu, mēs izmantojam SUM funkciju un aptinam to ap SUMIF formulu.

SUMPRODUCT un SUMIF, lai summētu šūnas ar vairākiem OR nosacījumiem

Jums nepatīk masīvi un meklējat parastu formulu, kas ļautu summēt vairākus kritērijus dažādās šūnās? Nav problēmu. SUM vietā izmantojiet funkciju SUMPRODUCT, kas dabiski apstrādā masīvus:

SUMPRODUCT(SUMIF(diapazons, crireria_range , sum_range))

Pieņemot, ka nosacījumi ir šūnās E1, E2 un E3, formula ir šāda:

=SUMPRODUKTS(SUMIF(A2:A10, E1:E3, B2:B10))

Kā šī formula darbojas:

Tāpat kā iepriekšējā piemērā, funkcija SUMIF atgriež skaitļu masīvu, kurā ir katra atsevišķā nosacījuma summas. SUMPRODUCT saskaita šos skaitļus kopā un iegūst galīgo kopsummu. Atšķirībā no SUM funkcijas SUMPRODUCT ir paredzēta masīvu apstrādei, tāpēc tā darbojas kā parasta formula, un jums nav jānospiež taustiņi Ctrl + Shift + Enter .

SUMIF, izmantojot vairākus kritērijus ar aizstājējzīmēm

Tā kā Excel SUMIF funkcija atbalsta aizstājējzīmes, vajadzības gadījumā varat tās iekļaut vairākos kritērijos.

Piemēram, lai summētu visu veidu pārdošanas apjomus. Āboli un Banāni , formula ir šāda:

=SUM(SUMIF(A2:A10, {"*Apkoki", "*Banāni"}, B2:B10))

Ja nosacījumi ir jāievada atsevišķās šūnās, varat ievadīt aizstājējzīmes tieši šajās šūnās un kā kritērijus SUMPRODUCT SUMIF formulai norādīt atsauci uz diapazonu:

Šajā piemērā pirms elementu nosaukumiem ievietots aizstājējzīmju simbols (*), lai atbilstu jebkurai iepriekšējai rakstzīmju virknei, piemēram. Zaļie āboli un Goldfinger banāni Lai iegūtu kopsummu vienībām, kas jebkurā šūnas vietā satur konkrētu tekstu, abās pusēs ievietojiet zvaigznīti, piemēram, "*apple*".

Lūk, kā lietot SUMIF programmā Excel ar vairākiem nosacījumiem. Paldies, ka izlasījāt, un ceru, ka nākamnedēļ tiksimies mūsu blogā!

Prakses darba burtnīca lejupielādei

SUMIF vairāki kritēriji (.xlsx fails)