فهرست مطالب
آیا می دانید چگونه اعداد را در یک ستون خاص جمع کنید، زمانی که یک مقدار در ستون دیگر هر یک از شرایط مشخص شده را برآورده می کند؟ در این مقاله، شما 3 روش مختلف برای انجام SUMIF با استفاده از چندین معیار و منطق OR را یاد خواهید گرفت.
Microsoft Excel یک تابع ویژه برای جمع کردن سلول ها با شرایط چندگانه دارد - تابع SUMIFS. این تابع برای کار با منطق AND طراحی شده است - یک سلول تنها زمانی اضافه می شود که تمام معیارهای مشخص شده برای آن سلول درست باشد. با این حال، در برخی شرایط، ممکن است لازم باشد با چند معیار OR جمع کنید، به عنوان مثال زمانی که هر یک از شرایط درست است، یک سلول اضافه کنید. و این زمانی است که تابع SUMIF به کار می آید.
SUMIF + SUMIF برای جمع کردن سلول های برابر با این یا آن
وقتی به دنبال جمع اعداد در یک ستون هستید هنگامی که ستون دیگری برابر با A یا B باشد، واضح ترین راه حل این است که هر شرط را به صورت جداگانه مدیریت کنید، و سپس نتایج را با هم اضافه کنید:
SUMIF(محدوده، معیار1، مجموع محدوده) + SUMIF(محدوده , criteria2, sum_range)در جدول زیر، فرض کنید می خواهید فروش دو محصول مختلف را جمع آوری کنید، مثلا سیب و لیمو . برای این، می توانید موارد مورد علاقه را مستقیماً در آرگومان های معیار 2 تابع مختلف SUMIF ارائه دهید:
=SUMIF(A2:A10, "apples", B2:B10) + SUMIF(A2:A10, "lemons", B2:B10)
یا می توانید معیارها را در سلول های جداگانه وارد کنید. و به آن سلول ها مراجعه کنید:
=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)
که در آن A2:A10 لیست موارد است ( محدوده )، B2:B10اعدادی هستند که باید جمع شوند ( sum_rage )، E1 و E2 موارد هدف هستند ( معیار ):
نحوه کار این فرمول:
اولین تابع SUMIF فروش سیب را جمع می کند، SUMIF دوم فروش Lemons را جمع می کند. عملیات جمع، مجموع‌های فرعی را با هم جمع می‌کند و کل را به‌دست می‌آورد.
SUMIF با آرایه ثابت - فرمول فشرده با معیارهای متعدد
رویکرد SUMIF + SUMIF برای 2 شرایط به خوبی کار می‌کند. اگر بخواهید با 3 معیار یا بیشتر جمع کنید، فرمول بسیار بزرگ و خواندن آن دشوار می شود. برای رسیدن به همان نتیجه با فرمول فشرده تر، معیارهای خود را در یک آرایه ثابت ارائه دهید:
SUM(SUMIF(range, { crireria1, crireria2, crireria3، …}، sum_range))لطفاً به یاد داشته باشید که این فرمول بر اساس منطق OR کار می کند - یک سلول زمانی جمع می شود که هر شرط واحدی برآورده شود.
در مورد ما، برای جمع کردن فروش برای 3 مختلف موارد، فرمول این است:
=SUM(SUMIF(A2:A10, {"Apples","Lemons","Oranges"}, B2:B10))
در تصویر بالا، شرایط در یک آرایه کدگذاری شده است، به این معنی که شما باید فرمول را با هر تغییر در معیارها برای جلوگیری از این امر، می‌توانید معیارها را در سلول‌های از پیش تعریف‌شده وارد کنید و یک فرمول را به‌عنوان مرجع محدوده (E1:E3 در این مثال) عرضه کنید.
=SUM(SUMIF(A2:A10, E1:E3, B2:B10))
در Excel 365 که از آرایه‌های پویا پشتیبانی می‌کند. ، به عنوان یک فرمول معمولی کار می کند که با کلید Enter تکمیل می شود. در نسخه های پیش پویا اکسل 2019، اکسل 2016، اکسل2013 و قبل از آن، باید به عنوان یک فرمول آرایه با میانبر Ctrl + Shift + Enter وارد شود:
این فرمول چگونه کار می کند:
یک آرایه ثابت که به معیارهای SUMIF متصل است، آن را مجبور می کند چندین نتیجه را در قالب یک آرایه برگرداند. در مورد ما، 3 مقدار متفاوت است: برای سیب ، لیمو و پرتقال :
{425;425;565}
برای دریافت در مجموع، از تابع SUM استفاده می کنیم و آن را به دور فرمول SUMIF می بندیم.
SUMPRODUCT و SUMIF برای جمع سلول های دارای شرایط OR متعدد
آرایه ها را دوست ندارند و به دنبال یک فرمول عادی هستند که آیا به شما اجازه می دهد با معیارهای متعدد در سلول های مختلف جمع کنید؟ مشکلی نیست. به جای SUM، از تابع SUMPRODUCT استفاده کنید که آرایه ها را به صورت بومی مدیریت می کند:
SUMPRODUCT(SUMIF(range, crireria_range , sum_range))
با فرض اینکه شرایط در سلول های E1 باشد، E2 و E3، فرمول به این شکل است:
=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))
این فرمول چگونه کار می کند:
مانند در مثال قبلی، تابع SUMIF آرایه ای از اعداد را برمی گرداند که مجموع هر شرط را نشان می دهد. SUMPRODUCT این اعداد را با هم جمع می کند و مجموع نهایی را به دست می آورد. برخلاف تابع SUM، SUMPRODUCT برای پردازش آرایه‌ها طراحی شده است، بنابراین به‌عنوان یک فرمول معمولی بدون نیاز به فشار دادن Ctrl + Shift + Enter کار می‌کند.
SUMIF با استفاده از چندین معیار با حروف عام
از آنجایی که تابع Excel SUMIF از حروف عام پشتیبانی می کند، شما می توانیددر صورت نیاز، آنها را در چندین معیار قرار دهید.
به عنوان مثال، برای جمع آوری فروش انواع سیب و موز ، فرمول این است:
=SUM(SUMIF(A2:A10, {"*Apples","*Bananas"}, B2:B10))
اگر قرار است شرایط شما در سلول‌های جداگانه وارد شود، می‌توانید حروف عام را مستقیماً در آن سلول‌ها تایپ کنید و مرجع محدوده را به عنوان معیار برای فرمول SUMPRODUCT SUMIF ارائه دهید:
در این مثال، یک کاراکتر عام (*) را قبل از نام آیتم ها قرار می دهیم تا با هر دنباله قبلی از کاراکترها مانند سیب سبز و موزهای انگشت طلایی مطابقت داشته باشد. برای به دست آوردن مجموع مواردی که حاوی متن خاصی در هر نقطه از سلول هستند، یک ستاره در هر دو طرف قرار دهید، به عنوان مثال. "*apple*".
این نحوه استفاده از SUMIF در اکسل با شرایط متعدد است. از خواندن شما سپاسگزارم و امیدوارم هفته آینده شما را در وبلاگ خود ببینم!
کتاب کار را برای دانلود تمرین کنید
SUMIF معیارهای چندگانه (فایل xlsx.)
