Savez-vous comment additionner les nombres d'une certaine colonne lorsqu'une valeur d'une autre colonne remplit l'une des conditions spécifiées ? Dans cet article, vous apprendrez 3 façons différentes de faire un SUMIF en utilisant des critères multiples et la logique OR.

Microsoft Excel dispose d'une fonction spéciale pour additionner des cellules avec des conditions multiples - la fonction SUMIFS. Cette fonction est conçue pour fonctionner avec la logique ET - une cellule est ajoutée uniquement lorsque tous les critères spécifiés sont VRAIS pour cette cellule. Dans certaines situations, cependant, vous pouvez avoir besoin d'additionner avec des critères OU multiples, c'est-à-dire d'ajouter une cellule lorsque l'une des conditions est VRAIE. C'est alors que la fonction SUMIFSest très utile.

SUMIF + SUMIF pour additionner les cellules égales à ceci ou cela

Lorsque vous cherchez à additionner des nombres dans une colonne lorsqu'une autre colonne est égale à A ou B, la solution la plus évidente est de traiter chaque condition individuellement, puis d'additionner les résultats :

Dans le tableau ci-dessous, supposons que vous souhaitiez additionner les ventes de deux produits différents, par exemple Pommes et Citrons Pour ce faire, vous pouvez fournir les éléments qui vous intéressent directement dans le formulaire de demande. critères arguments de 2 fonctions SUMIF différentes :

=SUMIF(A2:A10, "pommes", B2:B10) + SUMIF(A2:A10, "citrons", B2:B10)

Vous pouvez également saisir les critères dans des cellules séparées et vous référer à ces cellules :

=SUMIF(A2:A10, E1, B2:B10) + SUMIF(A2:A10, E2, B2:B10)

Où A2:A10 est la liste des éléments ( gamme ), B2:B10 sont les nombres à additionner ( sum_rage ), E1 et E2 sont les éléments cibles ( critères ) :

Comment fonctionne cette formule :

La première fonction SUMIF additionne les Pommes ventes, le second SUMIF additionne les Citrons L'opération d'addition additionne les sous-totaux et donne le total.

SUMIF avec constante de tableau - formule compacte avec plusieurs critères

L'approche SUMIF + SUMIF fonctionne bien pour 2 conditions. Si vous devez additionner avec 3 critères ou plus, la formule deviendra trop grande et difficile à lire. Pour obtenir le même résultat avec une formule plus compacte, fournissez vos critères dans une constante de tableau :

N'oubliez pas que cette formule fonctionne selon la logique OU - une cellule est additionnée lorsqu'une seule condition est remplie.

Dans notre cas, pour additionner les ventes de 3 articles différents, la formule est la suivante :

=SUM(SUMIF(A2:A10, {"Pommes", "Citrons", "Oranges"}, B2:B10))

Dans la capture d'écran ci-dessus, les conditions sont codées en dur dans un tableau, ce qui signifie que vous devrez mettre à jour la formule à chaque modification des critères. Pour éviter cela, vous pouvez saisir les critères dans des cellules prédéfinies et les fournir à une formule sous forme de référence de plage (E1:E3 dans cet exemple).

=SUM(SUMIF(A2:A10, E1:E3, B2:B10))

Dans Excel 365 qui prend en charge les tableaux dynamiques, elle fonctionne comme une formule ordinaire complétée par la touche Entrée. Dans les versions pré-dynamiques d'Excel 2019, Excel 2016, Excel 2013 et antérieures, elle doit être saisie comme une formule de tableau avec le raccourci Ctrl + Shift + Entrée :

Comment fonctionne cette formule :

Une constante de tableau insérée dans les critères de SUMIF l'oblige à renvoyer plusieurs résultats sous la forme d'un tableau. Dans notre cas, il s'agit de 3 montants différents : pour Pommes , Citrons et Oranges :

{425;425;565}

Pour obtenir le total, nous utilisons la fonction SUM et l'enroulons autour de la formule SUMIF.

SUMPRODUCT et SUMIF pour additionner des cellules avec plusieurs conditions OR

Vous n'aimez pas les tableaux et vous cherchez une formule normale qui vous permette de faire une somme avec plusieurs critères dans différentes cellules ? Pas de problème, au lieu de SUM, utilisez la fonction SUMPRODUCT qui gère les tableaux de manière native :

SUMPRODUCT(SUMIF(gamme, gamme crireria , sum_range))

En supposant que les conditions se trouvent dans les cellules E1, E2 et E3, la formule prend cette forme :

=SUMPRODUCT(SUMIF(A2:A10, E1:E3, B2:B10))

Comment fonctionne cette formule :

Comme dans l'exemple précédent, la fonction SUMIF renvoie un tableau de nombres, représentant les sommes pour chaque condition individuelle. SUMPRODUCT additionne ces nombres et produit un total final. Contrairement à la fonction SUM, SUMPRODUCT est conçue pour traiter des tableaux, et fonctionne donc comme une formule normale sans que vous ayez à appuyer sur Ctrl + Shift + Enter .

SUMIF utilisant des critères multiples avec des jokers

Comme la fonction SUMIF d'Excel prend en charge les caractères génériques, vous pouvez les inclure dans plusieurs critères si nécessaire.

Par exemple, pour additionner les ventes pour toutes sortes de Pommes et Bananes la formule est :

=SUM(SUMIF(A2:A10, {"*Apples", "*Bananas"}, B2:B10))

Si vos conditions sont censées être saisies dans des cellules individuelles, vous pouvez saisir des caractères génériques directement dans ces cellules et fournir une référence de plage comme critère pour la formule SUMIF SUMPRODUCT :

Dans cet exemple, nous plaçons un caractère générique (*) devant les noms des éléments pour correspondre à toute séquence de caractères précédente, telle que Pommes vertes et Bananes Goldfinger Pour obtenir un total pour les éléments qui contiennent un texte spécifique n'importe où dans une cellule, placez un astérisque des deux côtés, par exemple "*pomme*".

Voilà comment utiliser SUMIF dans Excel avec des conditions multiples. Je vous remercie de votre lecture et j'espère vous voir sur notre blog la semaine prochaine !

Cahier d'exercices à télécharger

SUMIF critères multiples (fichier .xlsx)