يشرح البرنامج التعليمي كيفية تقسيم الخلايا في Excel باستخدام الصيغ وميزة Split Text. سوف تتعلم كيفية فصل النص عن طريق الفاصلة أو المسافة أو أي محدد آخر ، وكيفية تقسيم السلاسل إلى نصوص وأرقام .

تقسيم النص من خلية واحدة إلى عدة خلايا هي المهمة التي يقوم بها جميع مستخدمي Excel التعامل معها من حين لآخر. في إحدى مقالاتنا السابقة ، ناقشنا كيفية تقسيم الخلايا في Excel باستخدام ميزة Text to Column و Flash Fill . اليوم ، سنلقي نظرة متعمقة على كيفية تقسيم السلاسل باستخدام الصيغ وأداة تقسيم النص .

كيفية تقسيم النص في Excel باستخدام الصيغ

لتقسيم السلسلة في Excel ، يمكنك عمومًا استخدام الدالة LEFT أو RIGHT أو MID مع إما FIND أو SEARCH. للوهلة الأولى ، قد تبدو بعض الصيغ معقدة ، لكن المنطق في الواقع بسيط للغاية ، وستعطيك الأمثلة التالية بعض الأدلة.

تقسيم السلسلة بفاصلة أو فاصلة منقوطة أو شرطة مائلة أو شرطة أو محدد آخر

عند تقسيم الخلايا في Excel ، يكون المفتاح هو تحديد موضع المحدد داخل السلسلة النصية. اعتمادًا على مهمتك ، يمكن القيام بذلك باستخدام إما بحث غير حساس لحالة الأحرف أو البحث عن حالة الأحرف. بمجرد حصولك على موضع المحدد ، استخدم الدالة RIGHT أو LEFT أو MID لاستخراج الجزء المقابل من السلسلة النصية. لفهم أفضل ، دعنا نفكر في ما يلي(التاريخ)

أتمنى لك أحببت هذه الطريقة السريعة والمباشرة لتقسيم السلاسل في Excel. إذا كنت مهتمًا بتجربته ، يتوفر إصدار تقييمي للتنزيل أدناه. أشكركم على القراءة وآمل أن أراكم على مدونتنا الأسبوع المقبل!

التنزيلات المتاحة

صيغ Excel Split Cells (ملف .xlsx)

Ultimate Suite 14 يومًا إصدار كامل الوظائف (ملف. exe)

لنفترض أن لديك قائمة من وحدات SKU للنمط عنصر - لون - حجم ، وتريد تقسيم العمود إلى 3 أعمدة منفصلة:

1. لاستخراج اسم العنصر (كل الأحرف قبل الواصلة الأولى) ، أدخل الصيغة التالية في B2 ، ثم انسخها أسفل العمود:

   =LEFT(A2, SEARCH("-",A2,1)-1)

   في هذه الصيغة ، تحدد SEARCH موضع الواصلة الأولى ("-") في السلسلة ، وتستخرج الدالة LEFT جميع الأحرف المتبقية لها (يمكنك طرح 1 من موضع الواصلة لأنك لا تفعل ذلك. تريد استخراج الواصلة نفسها).

   

2. لاستخراج اللون (جميع الأحرف بين الواصلة الأولى والثانية) ، أدخل ما يلي الصيغة في C2 ، ثم انسخها إلى خلايا أخرى:

   =MID(A2, SEARCH("-",A2) + 1, SEARCH("-",A2,SEARCH("-",A2)+1) - SEARCH("-",A2) - 1)

   

   في هذه الصيغة ، نستخدم وظيفة Excel MID لاستخراج النص من A2.

   موضع البداية وعدد الأحرف المراد استخراجها يتم حسابها بمساعدة 4 وظائف بحث مختلفة:

   • رقم البداية هو موضع الواصلة الأولى +1:

     SEARCH("-",A2) + 1

   • عدد الأحرف المراد استخلاصها : الفرق بين موضع الواصلة الثانية والواصلة الأولى ، ناقص 1:

     SEARCH("-", A2, SEARCH("-",A2)+1) - SEARCH("-",A2) -1

3. لاستخراج الحجم (كل الأحرف بعد الواصلة الثالثة) ، أدخل الصيغة التالية في D2:

   =RIGHT(A2,LEN(A2) - SEARCH("-", A2, SEARCH("-", A2) + 1))

   في هذه الصيغة ، ترجع الدالة LEN الطول الإجمالي للسلسلة ،التي تطرح منها موضع الواصلة الثانية. الفرق هو عدد الأحرف بعد الواصلة الثانية ، وتقوم الدالة RIGHT باستخراجها.

   

بطريقة مماثلة ، يمكنك تقسيم العمود على أي شخصية أخرى. كل ما عليك فعله هو استبدال "-" بالمحدد المطلوب ، على سبيل المثال مسافة ("") ، فاصلة ("،") ، شرطة مائلة ("/") ، نقطتان ("؛") ، فاصلة منقوطة ("؛") ، وهكذا.

نصيحة. في الصيغ أعلاه ، يتوافق +1 و -1 مع عدد الأحرف في المحدد. في هذا المثال ، تكون الواصلة (حرف واحد). إذا كان المحدد يتكون من حرفين ، على سبيل المثال فاصلة ومسافة ، ثم قم بتوفير الفاصلة فقط ("،") لوظيفة البحث ، واستخدم +2 و -2 بدلاً من +1 و -1.

كيفية تقسيم السلسلة عن طريق فاصل الأسطر Excel

لتقسيم النص بمسافة ، استخدم الصيغ المشابهة لتلك الموضحة في المثال السابق. الاختلاف الوحيد هو أنك ستحتاج إلى وظيفة CHAR لتوفير حرف فاصل الأسطر حيث لا يمكنك كتابته مباشرة في الصيغة.

لنفترض أن الخلايا التي تريد تقسيمها تبدو مشابهة لهذا:

خذ الصيغ من المثال السابق واستبدل الواصلة ("-") بـ CHAR (10) حيث 10 هو رمز ASCII لتغذية الخط.

• لاستخراج اسم العنصر :

  =LEFT(A2, SEARCH(CHAR(10),A2,1)-1)

• لاستخراج اللون :

  =MID(A2, SEARCH(CHAR(10),A2) + 1, SEARCH(CHAR(10),A2,SEARCH(CHAR(10),A2)+1) - SEARCH(CHAR(10),A2) - 1)

• لاستخراج الحجم :

  =RIGHT(A2,LEN(A2) - SEARCH(CHAR(10), A2, SEARCH(CHAR(10), A2) + 1))

وهذه هي الطريقة التي تبدو بها النتيجة:

كيفية تقسيم النص والأرقام في Excel

بادئ ذي بدء ، لا يوجد حل عالمي يعمل مع جميع السلاسل الأبجدية الرقمية. تعتمد الصيغة التي يجب استخدامها على نمط السلسلة المحدد. ستجد أدناه الصيغتين للسيناريوهين الشائعين.

تقسيم السلسلة لنمط 'text + number'

لنفترض أن لديك عمودًا من السلاسل مع النص والأرقام مجتمعة ، حيث يوجد رقم دائما يتبع النص. تريد كسر السلاسل الأصلية بحيث يظهر النص والأرقام في خلايا منفصلة ، مثل هذا:

يمكن تحقيق النتيجة بطريقتين مختلفتين.

الطريقة 1: عد الأرقام واستخرج العديد من الأحرف

أسهل طريقة لتقسيم السلسلة النصية حيث يأتي الرقم بعد النص هي:

إلى استخراج الأرقام ، أنت ابحث في السلسلة عن كل رقم ممكن من 0 إلى 9 ، واحصل على إجمالي الأرقام ، وأعد العديد من الأحرف من نهاية السلسلة.

مع السلسلة الأصلية في A2 ، تصبح الصيغة كما يلي:

=RIGHT(A2,SUM(LEN(A2) - LEN(SUBSTITUTE(A2, {"0","1","2","3","4","5","6","7","8","9"},"")))) ​​

لاستخراج نص ، يمكنك حساب عدد الأحرف النصية التي تحتوي عليها السلسلة عن طريق طرح عدد الأرقام المستخرجة (C2) من إجمالي طول السلسلة الأصلية في A2 . بعد ذلك ، يمكنك استخدام الدالة LEFT لإرجاع العديد من الأحرف من بداية السلسلة.

=LEFT(A2,LEN(A2)-LEN(C2))

حيث A2 هي السلسلة الأصلية ،و C2 هو الرقم المستخرج ، كما هو موضح في لقطة الشاشة:

الطريقة 2: اكتشف موضع الرقم الأول في سلسلة

بديل سيكون الحل هو استخدام الصيغة التالية لتحديد موضع الرقم الأول في السلسلة:

=MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))

بمجرد العثور على موضع الرقم الأول ، يمكنك تقسيم النص والأرقام باستخدام صيغتي LEFT و RIGHT بسيطة للغاية.

لاستخراج نص :

=LEFT(A2, B2-1)

لاستخراج رقم :

=RIGHT(A2, LEN(A2)-B2+1)

حيث A2 هي السلسلة الأصلية ، و B2 هو موضع الرقم الأول.

للتخلص من العمود المساعد الذي يحمل الرمز موضع الرقم الأول ، يمكنك تضمين صيغة MIN في الدالتين LEFT و RIGHT:

الصيغة لاستخراج نص :

=LEFT(A2,MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))-1)

Formula لاستخراج أرقام :

=RIGHT(A2,LEN(A2)-MIN(SEARCH({0,1,2,3,4,5,6,7,8,9},A2&"0123456789"))+1)

تقسيم السلسلة لنمط 'الرقم + النص'

إذا كنت تقوم بتقسيم الخلايا حيث يظهر النص بعد الرقم ، يمكن استخراج الأرقام بالصيغة التالية:

=LEFT(A2, SUM(LEN(A2) - LEN(SUBSTITUTE(A2, {"0","1","2","3","4","5","6","7","8","9"}, ""))))

الصيغة مشابهة للصيغة التي تمت مناقشتها في المثال السابق ، باستثناء أنك تستخدم الدالة LEFT بدلاً من RIGHT للحصول على الرقم من الجانب الأيسر من السلسلة.

بمجرد حصولك على الأرقام ، استخراج نص بطرح عدد الأرقام من إجمالي طول السلسلة الأصلية:

=RIGHT(A2,LEN(A2)-LEN(B2))

حيث A2 هي السلسلة الأصلية و B2 هو الرقم المستخرج ،كما هو موضح في لقطة الشاشة أدناه:

نصيحة. للحصول على رقم من أي موضع في السلسلة النصية ، استخدم إما هذه الصيغة أو أداة الاستخراج.

هذه هي الطريقة التي يمكنك بها تقسيم السلاسل في Excel باستخدام مجموعات مختلفة من الوظائف المختلفة. كما ترى ، فإن الصيغ بعيدة كل البعد عن الوضوح ، لذلك قد ترغب في تنزيل نموذج مصنف Excel Split Cells لفحصها عن قرب.

إذا لم يكن اكتشاف التقلبات الغامضة لصيغ Excel مهنتك المفضلة ، فأنت قد ترغب في الطريقة المرئية لتقسيم الخلايا في Excel ، والتي يتم توضيحها في الجزء التالي من هذا البرنامج التعليمي.

كيفية تقسيم الخلايا في Excel باستخدام أداة Split Text

طريقة بديلة لتقسيم العمود في Excel يستخدم ميزة Split Text المضمنة في Ultimate Suite for Excel ، والتي توفر الخيارات التالية:

لتوضيح الأمور ، دعنا نلقي نظرة فاحصة على كل خيار ، واحد في كل مرة.

تقسيم الخلايا حسب الحرف

اختر هذا الخيار عندما تريد تقسيم محتويات الخلية عند كل تكرار للحرف المحدد .

في هذا المثال ، دعنا نأخذ سلاسل النمط Item-Color-Size الذي استخدمناه في الجزء الأول من هذا البرنامج التعليمي. كما قد تتذكر ، قمنا بفصلهم إلى 3 أعمدة مختلفة باستخدام 3 صيغ مختلفة. وإليك كيفية تحقيق نفس النتيجة في خطوتين سريعتين:

1. بافتراض أن لديك Ultimate Suiteمثبتًا ، حدد الخلايا المراد تقسيمها ، وانقر فوق الرمز تقسيم النص في علامة التبويب بيانات Ablebits .

   

2. تقسيم النص سيتم فتح جزء على الجانب الأيمن من نافذة Excel ، وستقوم بما يلي:
   • قم بتوسيع مجموعة تقسيم حسب الحرف ، وحدد أحد المحددات المحددة مسبقًا أو اكتب أي حرف آخر في المربع مخصص.
   • اختر ما إذا كنت تريد تقسيم الخلايا إلى أعمدة أو صفوف.
   • راجع النتيجة ضمن معاينة ، وانقر فوق الزر انقسام .

نصيحة. إذا كان هناك العديد من المحددات المتتالية في الخلية (على سبيل المثال ، أكثر من حرف مسافة واحد) ، فحدد معاملة المحددات المتتالية كمربع واحد.

تم! المهمة التي تتطلب 3 صيغ و 5 وظائف مختلفة الآن تستغرق ثانيتين فقط ثم نقرة زر.

تقسيم الخلايا حسب السلسلة

يتيح هذا الخيار تقوم بتقسيم السلاسل باستخدام أي مجموعة من الأحرف كمحدد. تقنيًا ، تقوم بتقسيم سلسلة إلى أجزاء باستخدام سلسلة فرعية مختلفة أو عدة سلاسل كحدود لكل جزء.

على سبيل المثال ، لتقسيم جملة بواسطة أدوات العطف " و " و " أو "، قم بتوسيع تقسيم حسب السلاسل المجموعة ، وإدخال سلاسل المحدد ، واحد لكل سطر: يتم فصل العبارة المصدر عند كل ظهور لكل محدد:

نصيحة.غالبًا ما تكون الأحرف "أو" بالإضافة إلى "و" جزءًا من كلمات مثل "برتقالي" أو "أندلسية" ، لذا تأكد من كتابة مسافة مسافة قبل وبعد و و أو لمنع تقسيم الكلمات.

وهنا مثال آخر من الحياة الواقعية. لنفترض أنك قمت باستيراد عمود تواريخ من مصدر خارجي ، والذي يبدو كالتالي:

5.1.2016 12:20

5.2.2016 14:50

هذا التنسيق ليس تقليديًا لبرنامج Excel ، وبالتالي لن تتعرف أي من وظائف التاريخ على أي من عناصر التاريخ أو الوقت. لتقسيم اليوم والشهر والسنة والساعات والدقائق إلى خلايا منفصلة ، أدخل الأحرف التالية في المربع التقسيم بالسلاسل :

• النقطة (.) للفصل بين اليوم والشهر ، والسنة
• القولون (:) لفصل الساعات والدقائق
• مسافة لفصل التاريخ والوقت

اضغط على الزر انقسام ، وستحصل على الفور على النتيجة:

تقسيم الخلايا حسب القناع (النمط)

فصل خلية عن طريق القناع يعني تقسيم سلسلة نصية بناءً على نمط .

يكون هذا الخيار مفيدًا جدًا عندما تحتاج إلى تقسيم قائمة سلاسل متجانسة إلى بعض العناصر أو السلاسل الفرعية. التعقيد هو أن النص المصدر لا يمكن تقسيمه عند كل تكرار لمحدد معين ، فقط في بعض التكرارات المحددة. المثال التالي سيجعل الأمور أسهل في الفهم.

لنفترض أن لديك قائمة بالسلاسل المستخرجة من بعض السجلاتالملف:

ما تريده هو أن يكون لديك التاريخ والوقت ، إن وجد ، رمز الخطأ وتفاصيل الاستثناء في 3 أعمدة منفصلة. لا يمكنك استخدام مسافة كمحدد لأن هناك مسافات بين التاريخ والوقت ، والتي يجب أن تظهر في عمود واحد ، وهناك مسافات داخل نص الاستثناء ، والتي يجب أن تظهر أيضًا في عمود واحد.

الحل هو تقسيم سلسلة بواسطة القناع التالي: * خطأ: * استثناء: *

حيث تمثل العلامة النجمية (*) أي عدد من الأحرف.

النقطتان (:) تم تضمينها في المحددات لأننا لا نريدها أن تظهر في الخلايا الناتجة.

والآن ، قم بتوسيع القسم تقسيم حسب القناع في القسم تقسيم النص ، اكتب القناع في المربع أدخل المحددات ، وانقر فوق انقسام :

ستبدو النتيجة مشابهة لما يلي:

ملاحظة. يعتبر تقسيم السلسلة حسب القناع حساسًا لحالة الأحرف . لذا ، تأكد من كتابة الأحرف في القناع تمامًا كما تظهر في سلاسل المصدر.

الميزة الكبيرة لهذه الطريقة هي المرونة. على سبيل المثال ، إذا كانت جميع السلاسل الأصلية تحتوي على قيم تاريخ ووقت ، وتريد ظهورها في أعمدة مختلفة ، فاستخدم هذا القناع:

* * خطأ: * استثناء: *