Mục lục
Hướng dẫn giới thiệu ngắn gọn về cú pháp hàm ADDRESS và cho biết cách sử dụng nó để trả về một địa chỉ ô Excel và hơn thế nữa.
Để tạo một tham chiếu ô trong Excel, bạn có thể nhập tọa độ cột và hàng theo cách thủ công. Ngoài ra, bạn có thể lấy địa chỉ ô Excel từ số hàng và số cột được cung cấp cho hàm ADDRESS. Bản thân nó gần như vô nghĩa, khi kết hợp với các hàm khác, kỹ thuật này có thể là giải pháp duy nhất trong các trường hợp không thể tham chiếu trực tiếp đến một ô.
Hàm ADDRESS Excel - cú pháp và cách sử dụng cơ bản
Hàm ADDRESS được thiết kế để lấy địa chỉ ô trong Excel dựa trên số hàng và số cột đã chỉ định. Địa chỉ ô được trả về dưới dạng chuỗi văn bản, không phải tham chiếu thực tế.
Hàm này có sẵn trong tất cả các phiên bản Excel cho Microsoft 365 - Excel 2007.
Cú pháp của hàm ADDRESS là như sau:
ADDRESS(row_num, column_num, [abs_num], [a1], [sheet_text])Hai đối số đầu tiên là bắt buộc:
row_num - hàng số để sử dụng trong tham chiếu ô.
column_num - số cột để tạo tham chiếu ô.
Ba đối số cuối cùng chỉ định định dạng tham chiếu ô là tùy chọn:
abs_num - loại tham chiếu, tuyệt đối hoặc tương đối. Nó có thể lấy bất kỳ số nào dưới đây; giá trị mặc định là tuyệt đối.
- 1 hoặc bỏ qua -tham chiếu ô tuyệt đối như $A$1
- 2 - tham chiếu hỗn hợp: cột tương đối và hàng tuyệt đối như A$1
- 3 - tham chiếu hỗn hợp: cột tuyệt đối và hàng tương đối như $A1
- 4 - tham chiếu ô tương đối, chẳng hạn như A1
a1 - kiểu tham chiếu, A1 hoặc R1C1. Nếu bị bỏ qua, kiểu A1 mặc định sẽ được sử dụng.
- 1 hoặc TRUE hoặc bị bỏ qua - trả về địa chỉ ô theo kiểu tham chiếu A1 trong đó cột là chữ cái và hàng là số.
- 0 hoặc FALSE - trả về địa chỉ ô theo kiểu tham chiếu R1C1 trong đó các hàng và cột được biểu thị bằng số.
sheet_text - tên của trang tính sẽ bao gồm trong tham chiếu bên ngoài. Tên trang tính phải được cung cấp dưới dạng chuỗi văn bản và được đặt trong dấu ngoặc kép, ví dụ: "Tờ2". Nếu bỏ qua, không có tên trang tính nào được sử dụng và địa chỉ sẽ mặc định cho trang tính hiện tại.
Ví dụ:
=ADDRESS(1,1) - trả về địa chỉ của ô đầu tiên (tức là ô ở giao điểm của hàng đầu tiên và cột đầu tiên) dưới dạng tham chiếu ô tuyệt đối $A$1.
=ADDRESS(1,1,4) - trả về địa chỉ của ô đầu tiên dưới dạng tham chiếu ô tương đối A1.
Trong bảng sau, bạn sẽ tìm thấy thêm một số loại tham chiếu có thể được trả về bằng công thức ADDRESS.
| Công thức | Kết quả | Mô tả |
| =ADDRESS(1,2) | $B$1 | Ô tuyệt đốitham chiếu |
| =ADDRESS(1,2,4) | B1 | Tham chiếu ô tương đối |
| =ADDRESS(1,2,2) | B$1 | Cột tương đối và hàng tuyệt đối |
| =ADDRESS(1,2,3) | $B1 | Cột tuyệt đối và hàng tương đối |
| =ADDRESS(1,2,1,FALSE) | R1C2 | Tham chiếu tuyệt đối theo kiểu R1C1 |
| =ADDRESS(1,2,4,FALSE) | R[1]C[2] | Tham chiếu tương đối theo kiểu R1C1 |
| =ADDRESS(1,2,1,,"Sheet2") | Sheet2!$B$1 | Tham chiếu tuyệt đối đến trang tính khác |
| =ADDRESS(1,2,4,,"Sheet2") | Sheet2!B1 | Tham chiếu tương đối sang trang tính khác |
Cách sử dụng hàm ADDRESS trong Excel - ví dụ về công thức
Các ví dụ bên dưới cho biết cách sử dụng hàm ADDRESS bên trong các công thức lớn hơn để thực hiện nhiều việc hơn nhiệm vụ khó khăn.
Trả về giá trị ô trong một hàng và cột nhất định
Nếu mục tiêu của bạn là lấy giá trị từ một ô cụ thể dựa trên số hàng và cột của ô đó, hãy sử dụng ADDRESS fun ction cùng với INDIRECT:
INDIRECT(ADDRESS(row_num, column_num))Hàm ADDRESS xuất địa chỉ ô dưới dạng văn bản. Hàm INDIRECT biến văn bản đó thành tham chiếu bình thường và trả về giá trị từ ô tương ứng.
Ví dụ: để lấy giá trị ô dựa trên số hàng trong E1 và số cột trong E2, hãy sử dụng công thức này :
=INDIRECT(ADDRESS(E1,E2))
Lấy địa chỉcủa một ô có giá trị cao nhất hoặc thấp nhất
Trong ví dụ này, trước tiên chúng ta sẽ tìm các giá trị cao nhất và thấp nhất trong phạm vi B2:B7 bằng cách sử dụng các hàm MAX và MIN rồi xuất các giá trị đó vào các ô đặc biệt:
Ô E2: =MAX(B2:B7)
Ô F2: =MIN(B2:B7)
Sau đó, chúng ta sẽ sử dụng ADDRESS kết hợp với hàm MATCH để lấy địa chỉ ô.
Ô có giá trị lớn nhất:
=ADDRESS(MATCH(E2,B:B,0), COLUMN(B2))
Ô có giá trị nhỏ nhất:
=ADDRESS(MATCH(F2,B:B,0), COLUMN(B2))
Trong trường hợp bạn không muốn các giá trị cao nhất và thấp nhất trong các ô riêng biệt, bạn có thể lồng hàm MAX/MIN vào đối số đầu tiên của MATCH. Ví dụ:
Ô có giá trị cao nhất:
=ADDRESS(MATCH(MAX(B2:B7),B:B,0), COLUMN(B2))
Ô có giá trị thấp nhất:
=ADDRESS(MATCH(MIN(B2:B7),B:B,0), COLUMN(B2))
Các công thức này như thế nào work
Để tìm số hàng, bạn sử dụng hàm MATCH(lookup_value, lookup_array, [match_type]) trả về vị trí tương đối của lookup_value trong lookup_array. Trong công thức của chúng tôi, giá trị tra cứu là số được hàm MAX hoặc MIN trả về và mảng tra cứu là toàn bộ cột. Do đó, vị trí tương đối của giá trị tra cứu trong mảng khớp chính xác với số hàng trên trang tính.
Để tìm số cột, bạn sử dụng hàm COLUM. Tất nhiên, không có gì ngăn cản bạn nhập số trực tiếp vào công thức, nhưng COLUMN giúp tránh rắc rối khi đếm thủ công trong trường hợp cột mục tiêu nằm ở giữa trang tính.
Nhận ký tự cộttừ số cột
Để biến bất kỳ số đã cho nào thành ký tự cột, hãy sử dụng hàm ADDRESS bên trong SUBSTITUTE:
SUBSTITUTE(ADDRESS(1, column_number,4),"1 ","")Ví dụ, hãy tìm ký tự cột tương ứng với số trong A2:
=SUBSTITUTE(ADDRESS(1,A2,4),"1","")
Nhìn vào kết quả bên dưới, chúng ta có thể nói rằng cột đầu tiên trên trang tính là A, điều này là hiển nhiên; cột thứ 10 là J, cột thứ 50 là AX và cột thứ 100 là CV:
Cách thức hoạt động của công thức này
Đối với người mới bắt đầu, hãy thiết lập Hàm ADDRESS để trả về tham chiếu tương đối đến ô đầu tiên trong cột mục tiêu:
- Đối với số hàng, hãy sử dụng 1.
- Đối với số cột, hãy cung cấp tham chiếu đến ô chứa số, A2 trong ví dụ của chúng tôi.
- Đối với đối số abs_num, hãy nhập 4.
Kết quả là ADDRESS(1,A2,4) sẽ trả về A1.
Để loại bỏ tọa độ hàng, hãy bọc công thức trên trong hàm SUBSTITUTE và thay thế "1" bằng một chuỗi rỗng (""). Xong!
Lấy địa chỉ của dải ô đã đặt tên
Để tìm địa chỉ của dải ô đã đặt tên trong Excel, trước tiên bạn cần lấy tham chiếu ô đầu tiên và ô cuối cùng, sau đó nối chúng lại với nhau . Điều này hoạt động hơi khác một chút trong Excel tiền động (2019 trở lên) và Dynamic Array Excel (Office 365 và Excel 2021). Các ví dụ dưới đây dành cho Excel 2019 - Excel 2007. Hướng dẫn dành cho Excel 365 và Excel 2021 làtại đây.
Cách lấy địa chỉ của ô đầu tiên trong một dải ô
Để trả về một tham chiếu đến ô đầu tiên trong một dải ô đã đặt tên, hãy sử dụng công thức chung sau:
ĐỊA CHỈ(ROW( phạm vi),COLUMN( phạm vi))Giả sử phạm vi được đặt tên là "Sales", công thức thực sẽ như sau:
=ADDRESS(ROW(Sales), COLUMN(Sales))
Và trả về địa chỉ của ô phía trên bên trái trong phạm vi:
Trong công thức này, các hàm ROW và COLUMN trả về một mảng gồm tất cả các số hàng và cột trong phạm vi, tương ứng. Dựa trên những con số đó, hàm ADDRESS xây dựng một mảng các địa chỉ ô. Nhưng vì công thức được nhập trong một ô duy nhất nên chỉ có mục đầu tiên của mảng được hiển thị, tương ứng với ô đầu tiên trong dải ô.
Cách lấy địa chỉ của ô cuối cùng trong dải ô
Để tìm địa chỉ của ô cuối cùng trong một dải ô đã đặt tên, hãy sử dụng công thức chung sau:
ADDRESS(ROW( range)+ROWS( range)-1 ,COLUMN( range)+COLUMNS( range)-1)Được áp dụng cho dải ô có tên "Sales", công thức có dạng sau:
=ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)
Và trả về tham chiếu đến ô dưới cùng bên phải của dải ô:
Lần này, chúng ta cần các phép tính phức tạp hơn một chút để tìm ra hàng con số. Giống như trong ví dụ trước, hàm ROW cung cấp cho chúng ta một mảng gồm tất cả các số hàng trong phạm vi, {4;5;6;7} trong trường hợp của chúng ta. Chúng ta cần "dịch chuyển" các số này bằng tổng số hàng trừ đi 1, sao chomục đầu tiên trong mảng trở thành số hàng cuối cùng. Để tìm tổng số hàng, chúng tôi sử dụng hàm ROWS và trừ 1 từ kết quả của nó: (4-1=3). Sau đó, chúng ta thêm 3 vào mỗi phần tử của mảng ban đầu để thực hiện phép dịch được yêu cầu: {4;5;6;7} + 3 = {7;8;9;10}.
Số cột là được tính theo cách tương tự: {2,3,4}+3-1 = {4,5,6}
Từ các mảng số hàng và số cột ở trên, hàm ADDRESS sẽ tập hợp một mảng các địa chỉ ô , nhưng chỉ trả về giá trị đầu tiên tương ứng với ô cuối cùng trong phạm vi.
Bạn cũng có thể đạt được kết quả tương tự bằng cách chọn các giá trị lớn nhất từ các mảng của số hàng và số cột. Tuy nhiên, điều này chỉ hoạt động trong công thức mảng, yêu cầu nhấn Ctrl + Shift + Enter để hoàn thành chính xác:
=ADDRESS(MAX(ROW(Sales)), MAX(COLUMN(Sales)))
Cách lấy địa chỉ đầy đủ của một dải ô đã đặt tên
Để trả về địa chỉ đầy đủ của một dải ô đã đặt tên, bạn chỉ cần nối hai công thức từ các ví dụ trước đó và chèn toán tử dải ô (:) vào giữa.
ADDRESS(ROW( range) , COLUMN( range)) & ":" & ĐỊA CHỈ(ROW( range) + ROWS( range)-1, COLUMN( range) + COLUMNS( range)-1)Để làm cho nó hoạt động cho tập dữ liệu mẫu của chúng tôi, chúng tôi thay thế "phạm vi" chung bằng tên phạm vi thực "Sales":
=ADDRESS(ROW(Sales), COLUMN(Sales)) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1)
Và lấy địa chỉ phạm vi đầy đủ làm địa chỉ Tham chiếu tuyệt đối $B$4:$D$7:
Để trả về phạm viđịa chỉ dưới dạng tham chiếu tương đối (không có ký hiệu $, chẳng hạn như B4:D7), hãy đặt đối số abs_num trong cả hai hàm ADDRESS thành 4:
=ADDRESS(ROW(Sales), COLUMN(Sales), 4) & ":" & ADDRESS(ROW(Sales) + ROWS(Sales)-1, COLUMN(Sales) + COLUMNS(Sales)-1, 4)
Đương nhiên, những thay đổi tương tự có thể được thực hiện trong các công thức riêng lẻ cho ô đầu tiên và ô cuối cùng, và kết quả sẽ giống như sau:
Cách lấy địa chỉ của một dải ô đã đặt tên trong Excel 365 và Excel 2021
Không giống như hành vi "một công thức - một ô" truyền thống trong các phiên bản cũ hơn, trong Excel mới, bất kỳ công thức nào có thể trả về nhiều giá trị đều tự động thực hiện điều này. Hành vi như vậy được gọi là tràn ra.
Ví dụ: thay vì trả về địa chỉ của ô đầu tiên, công thức bên dưới sẽ xuất địa chỉ của từng và mọi ô trong một dải ô đã đặt tên:
=ADDRESS(ROW(Sales), COLUMN(Sales))
Để chỉ lấy địa chỉ của ô đầu tiên , bạn cần bật giao lộ ẩn, tính năng này được kích hoạt theo mặc định trong Excel 2019 trở lên. Đối với điều này, hãy đặt ký hiệu @ (toán tử giao nhau ngầm định) trước tên dải ô:
=ADDRESS(@ROW(Sales), @COLUMN(Sales))
Theo cách tương tự, bạn có thể sửa các công thức khác.
Để nhận được ô cuối cùng trong phạm vi:
=ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
Để lấy địa chỉ của một phạm vi đã đặt tên :
=ADDRESS(@ROW(Sales), @COLUMN(Sales)) & ":" & ADDRESS(@ROW(Sales) + ROWS(Sales)-1, @COLUMN(Sales) + COLUMNS(Sales)-1)
Ảnh chụp màn hình bên dưới hiển thị kết quả:
Mẹo. Khi mở một trang tính có các công thức được tạo trong phiên bản cũ hơn trong Excel mảng động, một toán tử giao ngầm ẩn sẽ được Excel tự động chèn vào.
Đó là cách bạntrả về một địa chỉ ô trong Excel. Để xem kỹ hơn tất cả các công thức được thảo luận trong hướng dẫn này, bạn có thể tải xuống sổ làm việc mẫu của chúng tôi bên dưới. Tôi cảm ơn bạn đã đọc và hy vọng sẽ gặp bạn trên blog của chúng tôi vào tuần tới!
Sách bài tập thực hành để tải xuống
Hàm ADDRESS Excel - ví dụ về công thức (tệp .xlsx)
