Po merrni shumë gabime #N/A në fletët tuaja të punës dhe jeni kurioz të dini nëse ka një mënyrë për të shfaqur një tekst të personalizuar në vend të kësaj? Formula IFNA është zgjidhja që ju nevojitet.

Kur një formulë Excel nuk mund të identifikojë ose gjejë diçka, ajo hedh gabimin #N/A. Për të kapur një gabim të tillë dhe për ta zëvendësuar atë me një mesazh miqësor për përdoruesit, mund të përdorni funksionin IFNA. Me fjalë të tjera, #N/A është mënyra e Excel për të thënë se vlera që po kërkoni nuk është e pranishme në grupin e të dhënave të referuar. IFNA është mënyra juaj për të kapur dhe trajtuar atë gabim.

Funksioni IFNA në Excel

Funksioni IFNA i Excel është menduar për kapjen dhe trajtimin e gabimeve #N/A. Nëse një formulë vlerësohet në #N/A, IFNA e bllokon atë gabim dhe e zëvendëson atë me një vlerë të personalizuar që ju specifikoni; përndryshe kthen një rezultat normal të formulës.

Sintaksa IFNA

Sintaksa e funksionit IFNA është si më poshtë:

Ku:

Vlera (kërkohet) - formula, vlera ose referenca për të kontrolluar për një gabim #N/A.

Vlera_if_na (kërkohet) - vlera për t'u kthyer nëse zbulohet një gabim #N/A.

Shënime përdorimi

• Funksioni IFNA trajton vetëm #N/A pa shtypur ndonjë gabim tjetër.
• Nëse argumenti vlera është një formulë grupi , IFNA kthen një grup rezultatesh, një për qelizë, siç tregohet në këtë shembull.

Disponueshmëria e IFNA

Funksioni IFNA u prezantua nëExcel 2013 dhe është i disponueshëm në të gjitha versionet e mëvonshme duke përfshirë Excel 2016, Excel 2019, Excel 2021 dhe Microsoft 365.

Në versionet e mëparshme, mund të kapni gabimet #N/A duke përdorur funksionet IF dhe ISNA së bashku.

Si të përdoret funksioni IFNA në Excel

Për të përdorur në mënyrë efektive IFNA në Excel, ndiqni këtë qasje të përgjithshme:

1. Në argumentin e parë ( vlera ), vendosni një formulë të ndikuar nga gabimi #N/A.
2. Në argumentin e dytë ( value_if_na ), shkruani tekstin që dëshironi të ktheni në vend të shënimit standard të gabimit. Për të kthyer një qelizë boshe kur nuk gjendet asgjë, jepni një varg bosh ('"").

Për të kthyer tekstin e personalizuar , formula e përgjithshme është:

Për të kthyer një qelizë bosh , formula e përgjithshme është:

Le të shohim se si funksionon në një shembull të thjeshtë. Në tabelën e mëposhtme, supozoni se dëshironi të dini se si renditet një pikë e një studenti të caktuar midis të tjerëve. Meqenëse të dhënat renditen sipas kolonës Rezultati nga më e larta tek më e ulëta, renditja do të përputhet me pozicionin relativ të studentit në tabelë. Dhe për të marrë pozicionin, mund të përdorni funksionin MATCH në formën e tij më të thjeshtë:

=MATCH(E1, A2:A10, 0)

Për shkak se vlera e kërkimit (Neal) nuk është e disponueshme në grupin e kërkimit (A2:A10), ndodh një gabim #N/A.

Në rast të këtij gabimi, përdoruesit e papërvojë mund të mendojnë se ka diçka që nuk shkon meformula, dhe ju si krijues i librit të punës do të merrni shumë pyetje. Për të shmangur këtë, mund të tregoni qartë se formula është e saktë, thjesht nuk mund të gjejë vlerën që kërkohet të kërkojë. Pra, ju futni formulën MATCH në argumentin e parë të IFNA dhe, në argumentin e dytë, shkruani tekstin tuaj të personalizuar, "Nuk u gjet" në rastin tonë:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Tani, në vend të shënimi standard i gabimit, teksti juaj shfaqet në një qelizë, duke informuar përdoruesit se vlera e kërkimit nuk është e pranishme në grupin e të dhënave:

Si të përdorni IFNA me VLOOKUP

Më shpesh, gabimi #N/A ndodh në funksione që kërkojnë diçka të tillë si VLOOKUP, HLOOKUP, LOOKUP dhe MATCH. Shembujt e mëposhtëm mbulojnë disa raste tipike përdorimi.

Shembulli 1. Formula bazë IFNA VLOOKUP

Për të bllokuar gabimet #N/A që ndodhin kur VLOOKUP nuk është në gjendje të gjejë një përputhje, kontrolloni rezultatin e saj duke përdorur IFNA dhe specifikoni vlerën që do të shfaqet në vend të gabimit. Praktika e zakonshme është të mbështillni funksionin IFNA rreth formulës suaj ekzistuese VLOOKUP duke përdorur këtë sintaksë:

Në tabelën tonë të mostrës, supozoni se dëshironi të të marrë një pikë të një studenti të caktuar (E1). Për këtë, ju po përdorni këtë formulë klasike VLOOKUP:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Çështja është se Neal nuk e mori provimin, prandaj emri i tij nuk është në listë dhe padyshim VLOOKUP nuk arrin të gjejë një ndeshje.

Për të fshehur gabimin, nembështillni VLOOKUP në IFNA si kjo:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Tani, rezultati nuk duket aq frikësues për përdoruesin dhe është shumë më informues:

Shembulli 2. IFNA VLOOKUP për të kërkuar nëpër fletë të shumta

Funksioni IFNA është gjithashtu i dobishëm për kryerjen e të ashtuquajturave kërkime sekuenciale ose të zinxhiruara nëpër fletë të shumta ose libra të ndryshëm pune. Ideja është që ju të futni disa formula të ndryshme IFNA(VLOOKUP(…)) njëra në tjetrën në këtë mënyrë:

Nëse një VLOOKUP primar nuk gjen asgjë, funksioni i tij IFNA ekzekuton VLOOKUP-in tjetër derisa të gjendet vlera e dëshiruar. Nëse të gjitha kërkimet dështojnë, formula do të kthejë tekstin e specifikuar.

Duke supozuar se keni rezultatet e klasave të ndryshme të listuara në fletë të ndryshme (të emërtuara Klasa A , Klasa B , dhe Klasa C ). Qëllimi juaj është të merrni rezultatin e një studenti të caktuar, emri i të cilit është futur në qelizën B1 në fletën tuaj aktuale të punës. Për të përmbushur detyrën, përdorni këtë formulë:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Formula kërkon në mënyrë sekuenciale emrin e specifikuar në tre fletë të ndryshme sipas renditjes që VLOOKUP-të janë të mbivendosur dhe sjell përputhjen e parë të gjetur:

Shembulli 3. IFNA me INDEX MATCH

Në një mënyrë të ngjashme, IFNA mund të kapë gabimet #N/A të krijuara nga funksione të tjera kërkimi. Si shembull, le ta përdorim atë së bashku me INDEX MATCHformula:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Thelbi i formulës është i njëjtë si në të gjithë shembujt e mëparshëm - INDEX MATCH kryen një kërkim dhe IFNA vlerëson rezultatin dhe kap një gabim #N/A nëse vlera e referuar nuk gjendet.

IFNA për të kthyer rezultate të shumta

Në rast se funksioni i brendshëm (d.m.th. formula e vendosur në vlera argument) kthen vlera të shumta, IFNA do të testojë secilën vlerë të kthyer individualisht dhe do të nxjerrë një grup rezultatesh. Për shembull:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

Në Excel-in Dynamic Array (Microsoft 365 dhe Excel 2021), një formulë e rregullt në qelizën më të lartë (E2) derdh automatikisht të gjitha rezultatet në qelizat fqinje (në terma i Excel, quhet një varg derdhjeje).

Në versionet paradinamike (Excel 2019 dhe më të ulët), një efekt i ngjashëm mund të arrihet duke përdorur një grup me shumë qeliza formula, e cila plotësohet me shkurtoren Ctrl + Shift + Enter.

Cili është ndryshimi midis IFNA dhe IFERROR?

Në varësi të shkakut rrënjësor të problem, një formulë Excel mund të shkaktojë gabime të ndryshme si #N/A, #EMRI, #VALUE, #REF, #DIV/0, #NUM dhe të tjera. Funksioni IFERROR kap të gjitha ato gabime ndërsa IFNA është i kufizuar vetëm në #N/A. Cilin është më mirë të zgjidhni? Kjo varet nga situata.

Nëse doni të shtypni çdo lloj gabimi , atëherë përdorni funksionin IFERROR. Është veçanërisht i dobishëm në llogaritjet komplekse kur një formulëpërfshin disa funksione që mund të gjenerojnë gabime të ndryshme.

Me funksionet e kërkimit , do të ishte më mirë të përdorni IFNA pasi shfaq një rezultat të personalizuar vetëm kur një vlerë kërkimi nuk gjendet dhe nuk e fsheh bazën probleme me vetë formulën.

Për të ilustruar ndryshimin, le të rikthejmë formulën tonë bazë IFNA VLOOKUP dhe "rastësisht" të shkruajmë gabim emrin e funksionit (VLOKUP në vend të VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA nuk e shtyp këtë gabim, kështu që mund të shihni qartë se diçka nuk është në rregull me një nga emrat e funksioneve:

Tani, le të shohim se çfarë ndodh nëse përdorni IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hmm… thotë se Olivia nuk ka marrë provimin, gjë që nuk është e vërtetë! Kjo ndodh sepse funksioni IFERROR bllokon #EMRI? gabim dhe në vend të kësaj kthen tekstin e personalizuar. Në këtë situatë, jo vetëm që kthen informacione të gabuara, por edhe errëson problemin me formulën.

Kjo është mënyra e përdorimit të formulës IFNA në Excel. Ju falënderoj që lexoni dhe mezi pres t'ju shohim në blogun tonë javën tjetër!

Shkarkimet e disponueshme

Shembuj të formulave Excel IFNA (skedari .xlsx)