Dobijate puno #N/A grešaka u vašim radnim listovima i radoznali ste da znate postoji li način da se umjesto toga prikaže prilagođeni tekst? IFNA formula je rješenje koje vam treba.

Kada Excel formula ne može identificirati ili pronaći nešto, ispušta grešku #N/A. Da biste uhvatili takvu grešku i zamijenili je porukom prilagođenom korisniku, možete koristiti IFNA funkciju. Drugim riječima, #N/A je Excelov način da kaže da vrijednost koju tražite nije prisutna u referentnom skupu podataka. IFNA je vaš način zarobljavanja i rukovanja tom greškom.

IFNA funkcija u Excelu

Excel IFNA funkcija je namijenjena za hvatanje i rukovanje #N/A greškama. Ako formula dobije vrijednost #N/A, IFNA hvata tu grešku i zamjenjuje je prilagođenom vrijednošću koju navedete; inače vraća normalan rezultat formule.

IFNA sintaksa

Sintaksa IFNA funkcije je sljedeća:

Gdje:

Vrijednost (obavezno) - formula, vrijednost ili referenca za provjeru #N/A greške.

Vrijednost_ako_na (obavezno) - vrijednost za povratak ako je otkrivena greška #N/A.

Napomene o upotrebi

• Funkcija IFNA obrađuje samo #N/A bez potiskivanja bilo koje druge greške.
• Ako je argument value formula niza , IFNA vraća niz rezultata, jedan po ćeliji, kao što je prikazano u ovom primjeru.

IFNA dostupnost

Funkcija IFNA uvedena je uExcel 2013 i dostupan je u svim narednim verzijama uključujući Excel 2016, Excel 2019, Excel 2021 i Microsoft 365.

U starijim verzijama možete uhvatiti #N/A greške koristeći funkcije IF i ISNA zajedno.

Kako koristiti IFNA funkciju u Excelu

Da biste učinkovito koristili IFNA u Excelu, slijedite ovaj generički pristup:

1. U prvom argumentu ( vrijednost ), stavite formulu na koju utiče #N/A greška.
2. U drugom argumentu ( value_if_na ), upišite tekst koji želite vratiti umjesto standardne oznake greške. Da biste vratili praznu ćeliju kada ništa nije pronađeno, navedite prazan niz ('"").

Da biste vratili prilagođeni tekst , generička formula je:

Da biste vratili praznu ćeliju , generička formula je:

Da vidimo kako to funkcionira na jednostavnom primjeru. Pretpostavimo da u donjoj tabeli želite da znate kako se rezultat nekog učenika rangira među ostalima. Pošto su podaci sortirani po koloni Score od najvišeg do najnižeg, rang će odgovarati relativnoj poziciji učenika u tabeli. A da biste dobili poziciju, možete koristiti funkciju MATCH u njenom najjednostavnijem obliku:

=MATCH(E1, A2:A10, 0)

Zato što vrijednost pretraživanja (Neal) nije dostupna u nizu pretraživanja (A2:A10), javlja se greška #N/A.

Naišavši na ovu grešku, neiskusni korisnici mogu pomisliti da nešto nije u redu saformula, a vi kao kreator radne sveske dobit ćete mnogo pitanja. Da biste to izbjegli, možete eksplicitno naznačiti da je formula ispravna, samo ne može pronaći vrijednost koju se traži. Dakle, ugnijezdite MATCH formulu u prvi argument IFNA i, u drugi argument, upišite svoj prilagođeni tekst, "Nije pronađeno" u našem slučaju:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Sada, umjesto standardna notacija greške, vaš vlastiti tekst se prikazuje u ćeliji, obavještavajući korisnike da vrijednost pretraživanja nije prisutna u skupu podataka:

Kako koristiti IFNA sa VLOOKUP

Najčešće se greška #N/A javlja u funkcijama koje traže nešto kao što su VLOOKUP, HLOOKUP, LOOKUP i MATCH. Primjeri u nastavku pokrivaju nekoliko tipičnih slučajeva upotrebe.

Primjer 1. Osnovna IFNA VLOOKUP formula

Da biste uhvatili #N/A greške koje se javljaju kada VLOOKUP ne može pronaći podudaranje, provjerite njegov rezultat koristeći IFNA i navedite vrijednost koja će se prikazati umjesto greške. Uobičajena praksa je da omotate IFNA funkciju oko vaše postojeće VLOOKUP formule koristeći ovu sintaksu:

U našoj tablici uzorka, pretpostavimo da želite dohvati rezultat određenog učenika (E1). Za ovo koristite ovu klasičnu VLOOKUP formulu:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Problem je u tome što Neal nije polagao ispit, stoga njegovo ime nije na listi i očigledno VLOOKUP ne uspijeva pronaći podudarnost.

Da bismo sakrili grešku, miomotajte VLOOKUP u IFNA ovako:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Sada, rezultat ne izgleda toliko zastrašujuće za korisnika i puno je informativniji:

Primjer 2. IFNA VLOOKUP za traženje na više listova

Funkcija IFNA također je zgodna za obavljanje takozvanih uzastopnih ili lančanih pretraživanja na više listova ili različitih radnih knjiga. Ideja je da ugnijezdite nekoliko različitih IFNA(VLOOKUP(…)) formula jedna u drugu na ovaj način:

Ako primarni VLOOKUP ne pronađe ništa, njegova IFNA funkcija pokreće sljedeći VLOOKUP dok se ne pronađe željena vrijednost. Ako sva traženja ne uspiju, formula će vratiti navedeni tekst.

Pretpostavimo da imate rezultate različitih klasa navedeni u različitim listovima (pod nazivom Klasa A , Klasa B i Klasa C ). Vaš cilj je da dobijete rezultat određenog učenika čije je ime uneseno u ćeliju B1 na vašem trenutnom radnom listu. Da biste ispunili zadatak, koristite ovu formulu:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Formula sekvencijalno traži navedeno ime u tri različita lista po redoslijedu ugniježđenja VLOOKUP-a i donosi prvo pronađeno podudaranje:

Primjer 3. IFNA s INDEX MATCH

Na sličan način, IFNA može uhvatiti #N/A greške generirane drugim funkcijama pretraživanja. Kao primjer, koristimo ga zajedno sa INDEX MATCHformula:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Suština formule je ista kao u svim prethodnim primjerima - INDEX MATCH vrši traženje, a IFNA procjenjuje rezultat i hvata #N/A grešku ako referentna vrijednost nije pronađena.

IFNA za vraćanje više rezultata

U slučaju da je unutrašnja funkcija (tj. formula smještena u vrijednost argument) vraća više vrijednosti, IFNA će testirati svaku vraćenu vrijednost pojedinačno i ispisati niz rezultata. Na primjer:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

U Dynamic Array Excel-u (Microsoft 365 i Excel 2021), regularna formula u najvišoj ćeliji (E2) automatski prebacuje sve rezultate u susjedne ćelije (u smislu Excela, to se zove raspon prelivanja).

U preddinamičkim verzijama (Excel 2019 i starije verzije), sličan efekat se može postići korištenjem niza s više ćelija formule, koja se završava prečicom Ctrl + Shift + Enter.

Koja je razlika između IFNA i IFERROR?

U zavisnosti od osnovnog uzroka Problem, Excel formula može pokrenuti različite greške kao što su #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM i druge. Funkcija IFERROR hvata sve te greške dok je IFNA ograničena na samo #N/A. Koje je bolje izabrati? To zavisi od situacije.

Ako želite da potisnete bilo koju vrstu greške , onda koristite funkciju IFERROR. Posebno je koristan u složenim proračunima kada je formulauključuje nekoliko funkcija koje mogu generirati različite greške.

Sa funkcijama traženja , bolje je koristiti IFNA jer prikazuje prilagođeni rezultat samo kada tražena vrijednost nije pronađena i ne skriva temeljnu vrijednost problemi sa samom formulom.

Da bismo ilustrirali razliku, vratimo našu osnovnu formulu IFNA VLOOKUP i "slučajno" pogrešno napišemo ime funkcije (VLOKUP umjesto VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA ne potiskuje ovu grešku, tako da možete jasno vidjeti da nešto nije u redu s jednim od naziva funkcija:

Sada, da vidimo šta će se dogoditi ako koristite AKO GREŠKA:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hm… piše da Olivia nije polagala ispit, što nije tačno! To je zato što funkcija IFERROR zarobi #NAME? greška i umjesto toga vraća prilagođeni tekst. U ovoj situaciji, ne samo da vraća pogrešne informacije, već i prikriva problem s formulom.

Tako se koristi IFNA formula u Excelu. Zahvaljujem vam na čitanju i radujem se što ću vas vidjeti na našem blogu sljedeće sedmice!

Dostupna preuzimanja

Primjeri Excel IFNA formule (.xlsx datoteka)