Gelek xeletiyên #N/A di pelên xebata xwe de digirin û hûn meraq dikin ku hûn zanibin gelo rêyek heye ku li şûna nivîsek xwerû nîşan bide? Formula IFNA çareseriya ku hûn hewce ne.

Gava ku formula Excel nikaribe tiştekî nas bike an bibîne, ew xeletiya #N/A derdixe. Ji bo ku hûn xeletiyek wusa bigirin û wê bi peyamek bikarhêner-heval veguherînin, hûn dikarin fonksiyona IFNA bikar bînin. Bi gotinek din, #N/A awayê Excel e ku dibêje ku nirxa ku hûn lê digerin di databasa referansê de tune ye. IFNA awayê we ye ku hûn wê xeletiyê bişopînin û bi rê ve bibin.

Fonksiyon IFNA di Excel de

Fonksiyona Excel IFNA ji bo girtin û birêvebirina xeletiyên #N/A tê armanc kirin. Ger formulek bi #N/A dinirxîne, IFNA wê xeletiyê hildide û wê bi nirxek xwerû ya ku hûn diyar dikin diguhezîne; Wekî din encamek normal ya formula vedigerîne.

Sîntaksa IFNA

Sîntaksa fonksiyona IFNA wiha ye:

Li ku:

Nirx (pêdivî) - formula, nirx, an referansa ku ji bo xeletiyek #N/A kontrol bike.

Nirx_if_na (pêwîst) - nirx ger xeletiyek #N/A hat dîtin vegere.

Têbînîyên bikaranînê

• Fonksiyona IFNA tenê #N/A bêyî ku tu xeletiyên din bitepisîne bi rê ve dibe.
• Heke argumana nirx formûlê rêzê ye , IFNA komek encaman vedigerîne, ji her şaneyê yek, wekî ku di vê nimûneyê de tê nîşandan.

Hebûna IFNA

Fonksiyon IFNA di nav de hate destnîşan kirinExcel 2013 û di hemî guhertoyên paşîn de heye, di nav de Excel 2016, Excel 2019, Excel 2021, û Microsoft 365.

Di guhertoyên berê de, hûn dikarin bi karanîna fonksiyonên IF û ISNA bi hev re xeletiyên #N/A bigirin.

Meriv çawa fonksiyona IFNA di Excel de bikar tîne

Ji bo ku IFNA bi bandor li Excel bikar bîne, vê nêzîkatiya gelemperî bişopînin:

1. Di argumana yekem de ( nirx ), formuleke ku ji ber xeletiya #N/A bandor bûye, deyne.
2. Di argumana duyemîn de ( value_if_na ), li şûna nîşaneya xeletiya standard nivîsa ku hûn dixwazin vegerînin binivîsin. Ji bo vegerandina şaneyek vala dema ku tiştek neyê dîtin, rêzek vala ('"") peyda bike.

Ji bo vegerandina nivîsa xwerû , formula giştî ev e:

Ji bo vegerandina xaneyeke vala , formula giştî ev e:

Ka em bibînin ka ew li ser mînakek hêsan çawa dixebite. Di tabloya jêrîn de, bifikirin ku hûn dixwazin zanibin ka puanek xwendekarek diyar di nav yên din de çawa di rêzê de ye. Ji ber ku dane li gorî stûna Pûan ji herî bilind ber bi herî nizm ve têne rêz kirin, rêz dê bi pozîsyona têkildar a xwendekarê di tabloyê de li hev bike. Û ji bo bidestxistina pozîsyonê, hûn dikarin fonksiyona MATCH di forma xweya herî hêsan de bikar bînin:

=MATCH(E1, A2:A10, 0)

Ji ber ku nirxa lêgerînê (Neal) di rêzika lêgerînê de peyda nabe (A2:A10), çewtiyek #N/Na çêdibe.

Ji ber vê xeletiyê, bikarhênerên bê tecrube dibe ku bifikirin ku tiştek di xeletiyê de heye.formula, û hûn wekî afirînerê pirtûka xebatê dê gelek pirsan bistînin. Ji bo ku hûn ji vê yekê dûr nekevin, hûn dikarin bi eşkere destnîşan bikin ku formula rast e, ew tenê nikare nirxa ku jê tê xwestin ku lê bigere bibîne. Ji ber vê yekê, hûn formula MATCH-ê di argumana yekem a IFNA-yê de hêlîn dikin û, di argumana duyemîn de, di doza me de nivîsa xweya xwerû, "Nehat dîtin" binivîsin:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Naha, li şûna nîşana xeletiya standard, nivîsa we di şaneyek de tê xuyang kirin, û bikarhêneran agahdar dike ku nirxa lêgerînê di databasê de tune:

Çawa bi VLOOKUP re IFNA bikar bînin

Pir caran di fonksiyonên ku li tiştekî wek VLOOKUP, HLOOKUP, LOOKUP, û MATCH digerin de xeletiya #N/A çêdibe. Nimûneyên jêrîn çend rewşên karanîna tîpîk vedigirin.

Mînak 1. Formula bingehîn a IFNA VLOOKUP

Ji bo ku xeletiyên #N/A yên ku dema ku VLOOKUP nikaribe hevberdanê bibîne çêbibin, encama wê kontrol bikin. IFNA bikar bînin û nirxa ku li şûna xeletiyê were xuyang kirin diyar bikin. Pratîka hevpar ev e ku hûn fonksiyona IFNA li dora formula VLOOKUP-a xweya heyî bi karanîna vê hevoksaziyê bipêçin:

Di tabloya nimûneya me de, bifikirin ku hûn dixwazin pûanek xwendekarek taybetî (E1) bistînin. Ji bo vê yekê, hûn vê formula VLOOKUP-a klasîk bikar tînin:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Mijar ev e ku Neal îmtîhanê negirt, ji ber vê yekê navê wî ne di navnîşê de ye, û eşkere ye ku VLOOKUP nikare bibîne lihevhatinek.

Ji bo veşartina xeletiyê, emVLOOKUP-ê di IFNA de bi vî rengî bipêçin:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Naha, encam ji bikarhêner re ew qas tirsnak xuya nake û pir agahdartir e:

Nimûne 2. IFNA VLOOKUP ku li gelek pelan bigere

Fonksiyona IFNA jî ji bo pêkanîna lêgerînên li pey hev an zincîrekirî bi kêr tê. li ser gelek pelan an pirtûkên xebatê yên cihêreng. Fikir ev e ku hûn çend formulên cûda yên IFNA(VLOOKUP(…)) bi vî rengî di nav hev de bihêlin:

Heke VLOOKUPeke seretayî tiştekî nabîne, fonksiyona wê ya IFNA VLOOKUP-a din dimeşîne heta ku nirxa xwestî were dîtin. Ger hemî lêgerîn biser nekevin, formula dê nivîsa diyarkirî vegerîne.

Tê guman kirin ku hûn pûanên çînên cihêreng di pelên cihêreng de hatine rêz kirin (bi navên çîn A , çîn B , û Pola C ). Armanca we ev e ku hûn pûanek xwendekarek taybetî bistînin, ku navê wî di hucreya B1 de di pelgeya xebata weya heyî de tête navnîş kirin. Ji bo bicihanîna peywirê, vê formulê bikar bînin:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Formula bi rêzê ve li navê diyarkirî di sê pelên cihêreng de li gorî rêza ku VLOOKUP-yên hêlkirî ne digere û hevbera yekem a ku hatiye dîtin tîne:

Nimûne 3. IFNA bi MATCH INDEX re

Bi vî rengî, IFNA dikare xeletiyên #N/A yên ku ji hêla fonksiyonên lêgerînê yên din ve hatine çêkirin bigire. Wek mînak, bila em bi hev re bi MATCH INDEX re bikar bîninformula:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Gelê formulê wekî hemî mînakên berê ye - INDEX MATCH lêgerek dike, û IFNA encamê dinirxîne û xeletiyek #N/A digire heke nirxa referansê nehatiye dîtin.

IFNA ji bo vegerandina gelek encaman

Di rewşê de ku fonksiyona hundurîn (ango formula ku di nirxê de cih digire arguman) gelek nirxan vedigerîne, IFNA dê her nirxê vegerî yekalî biceribîne û komek encam derxe. Mînakî:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

Di Array Dînamîk Excel de (Microsoft 365 û Excel 2021), formulak birêkûpêk di şaneya herî jorîn (E2) de hemî encaman di şaneyên cîran de bixweber diherikîne (di nav de ya Excel, jê re tê gotin rêzek rijandin).

Di guhertoyên pêş-dînamîkî de (Excel 2019 û jêrîn), bandorek bi vî rengî dikare bi karanîna rêzek pir-hucreyî were bidestxistin. formula, ku bi kurteya Ctrl + Shift + Enter temam dibe.

Cûdahiya di navbera IFNA û IFERROR de çi ye?

Li gorî sedema bingehîn ya pirsgirêk, formula Excel dikare xeletiyên cûda yên wekî #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM, û yên din derxe holê. Fonksiyona IFERROR hemî wan xeletiyan digire dema ku IFNA tenê bi #N/A ve sînorkirî ye. Ji bo hilbijartina kîjan çêtir e? Ew bi rewşê ve girêdayî ye.

Heke hûn dixwazin her cûre xeletiyek bitepisînin , wê hingê fonksiyona IFERROR bikar bînin. Ew bi taybetî di hesabên tevlihev de dema ku formula bikêr egelek fonksiyonan dihewîne ku dikarin xeletiyên cihêreng biafirînin.

Bi fonksîyonên lêgerînê , hûn çêtir e ku hûn IFNA bikar bînin ji ber ku ew encamek xwerû nîşan dide tenê dema ku nirxek lêgerînê neyê dîtin û binê xwe veneşêre. pirsgirêkên bi formulê bi xwe re.

Ji bo ronîkirina ferqê, werin em formula xweya bingehîn a IFNA VLOOKUP vegerînin û "bi xeletî" navê fonksiyonê xelet binivîsin (li şûna VLOOKUP VLOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA vê xeletiyê napejirîne, ji ber vê yekê hûn dikarin bi zelalî bibînin ku tiştek bi yek ji navên fonksiyonê re xelet e:

Niha, em bibînin ka çi dibe bila bibe heke hûn bikar bînin IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hmm… ew dibêje ku Olivia neçû îmtîhanê, ku ne rast e! Ev e ji ber ku fonksiyona IFERROR #NAME digire? xeletî dike û li şûna nivîsa xwerû vedigerîne. Di vê rewşê de, ew ne tenê agahdariya xelet vedigerîne, lê di heman demê de pirsgirêkê bi formulê re jî vedişêre.

Bi vî awayî meriv formula IFNA li Excel-ê bikar tîne. Ez spasiya we dikim ji bo xwendinê û li hêviya dîtina we di hefteya pêş de li ser bloga me me!

Daxistinên berdest

Mînakên formula Excel IFNA (pelê xlsx)