Mendapat banyak ralat #N/A dalam lembaran kerja anda dan ingin tahu sama ada terdapat cara untuk memaparkan teks tersuai? Formula IFNA ialah penyelesaian yang anda perlukan.

Apabila formula Excel tidak dapat mengenal pasti atau mencari sesuatu, ia membuang ralat #N/A. Untuk menangkap ralat sedemikian dan menggantikannya dengan mesej mesra pengguna, anda boleh menggunakan fungsi IFNA. Dalam erti kata lain, #N/A ialah cara Excel untuk menyatakan bahawa nilai yang anda cari tidak terdapat dalam set data yang dirujuk. IFNA ialah cara anda memerangkap dan mengendalikan ralat itu.

Fungsi IFNA dalam Excel

Fungsi Excel IFNA bertujuan untuk menangkap dan mengendalikan ralat #N/A. Jika formula menilai kepada #N/A, IFNA memerangkap ralat itu dan menggantikannya dengan nilai tersuai yang anda tentukan; sebaliknya mengembalikan hasil normal formula.

Sintaks IFNA

Sintaks fungsi IFNA adalah seperti berikut:

Di mana:

Nilai (diperlukan) - formula, nilai atau rujukan untuk menyemak ralat #N/A.

Nilai_jika_na (diperlukan) - nilai untuk kembali jika ralat #N/A dikesan.

Nota penggunaan

• Fungsi IFNA hanya mengendalikan #N/A tanpa menyekat sebarang ralat lain.
• Jika argumen nilai ialah formula tatasusunan , IFNA mengembalikan tatasusunan hasil, satu setiap sel, seperti yang ditunjukkan dalam contoh ini.

Ketersediaan IFNA

Fungsi IFNA telah diperkenalkan dalamExcel 2013 dan tersedia dalam semua versi berikutnya termasuk Excel 2016, Excel 2019, Excel 2021 dan Microsoft 365.

Dalam versi terdahulu, anda boleh menangkap ralat #N/A dengan menggunakan fungsi IF dan ISNA bersama-sama.

Cara menggunakan fungsi IFNA dalam Excel

Untuk menggunakan IFNA dalam Excel dengan berkesan, ikut pendekatan generik ini:

1. Dalam hujah pertama ( nilai ), letakkan formula yang dipengaruhi oleh ralat #N/A.
2. Dalam hujah kedua ( value_if_na ), taip teks yang ingin anda kembalikan dan bukannya notasi ralat standard. Untuk mengembalikan sel kosong apabila tiada apa-apa ditemui, bekalkan rentetan kosong ('"").

Untuk mengembalikan teks tersuai , formula generik ialah:

Untuk mengembalikan sel kosong , formula generik ialah:

Mari kita lihat cara ia berfungsi pada contoh mudah. Dalam jadual di bawah, katakan anda ingin mengetahui kedudukan markah pelajar tertentu antara yang lain. Memandangkan data diisih mengikut lajur Skor dari tertinggi ke terendah, pangkat akan sepadan dengan kedudukan relatif pelajar dalam jadual. Dan untuk mendapatkan kedudukan, anda boleh menggunakan fungsi MATCH dalam bentuk paling ringkas:

=MATCH(E1, A2:A10, 0)

Oleh kerana nilai carian (Neal) tidak tersedia dalam tatasusunan carian (A2:A10), ralat #N/A berlaku.

Terdapat ralat ini, pengguna yang tidak berpengalaman mungkin menganggap ada sesuatu yang tidak kena denganformula, dan anda sebagai pencipta buku kerja akan menerima banyak soalan. Untuk mengelakkan ini, anda boleh menunjukkan dengan jelas bahawa formula itu betul, ia tidak dapat mencari nilai yang diminta untuk dicari. Jadi, anda menyusun formula MATCH dalam argumen pertama IFNA dan, dalam argumen kedua, taip teks tersuai anda, "Tidak dijumpai" dalam kes kami:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Sekarang, bukannya notasi ralat standard, teks anda sendiri dipaparkan dalam sel, memaklumkan pengguna bahawa nilai carian tidak terdapat dalam set data:

Cara menggunakan IFNA dengan VLOOKUP

Selalunya ralat #N/A berlaku dalam fungsi yang mencari sesuatu seperti VLOOKUP, HLOOKUP, LOOKUP dan MATCH. Contoh di bawah merangkumi beberapa kes penggunaan biasa.

Contoh 1. Formula asas IFNA VLOOKUP

Untuk memerangkap ralat #N/A yang berlaku apabila VLOOKUP tidak dapat mencari padanan, semak keputusannya menggunakan IFNA dan tentukan nilai yang akan dipaparkan dan bukannya ralat. Amalan biasa ialah membungkus fungsi IFNA di sekeliling formula VLOOKUP sedia ada anda menggunakan sintaks ini:

Dalam jadual sampel kami, katakan anda mahu mendapatkan semula markah pelajar tertentu (E1). Untuk ini, anda menggunakan formula VLOOKUP klasik ini:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Isunya ialah Neal tidak mengambil peperiksaan, oleh itu namanya tiada dalam senarai dan jelas sekali VLOOKUP gagal mencari padanan.

Untuk menyembunyikan ralat, kamibungkus VLOOKUP dalam IFNA seperti ini:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Kini, hasilnya tidak kelihatan begitu menakutkan kepada pengguna dan lebih bermaklumat:

Contoh 2. IFNA VLOOKUP untuk mencari merentas berbilang helaian

Fungsi IFNA juga berguna untuk melakukan carian yang dipanggil berurutan atau berrantai merentas berbilang helaian atau buku kerja yang berbeza. Ideanya ialah anda menyusun beberapa formula IFNA(VLOOKUP(…)) berbeza antara satu sama lain dengan cara ini:

Jika VLOOKUP utama tidak menemui apa-apa, fungsi IFNAnya menjalankan VLOOKUP seterusnya sehingga nilai yang dikehendaki ditemui. Jika semua carian gagal, formula akan mengembalikan teks yang ditentukan.

Andaikata anda mempunyai markah kelas berbeza disenaraikan dalam helaian berbeza (bernama Kelas A , Kelas B , dan Kelas C ). Matlamat anda adalah untuk mendapatkan markah pelajar tertentu, yang namanya dimasukkan dalam sel B1 dalam lembaran kerja semasa anda. Untuk memenuhi tugasan, gunakan formula ini:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Formula secara berurutan mencari nama yang ditentukan dalam tiga helaian berbeza dalam susunan VLOOKUP bersarang dan membawa padanan pertama yang ditemui:

Contoh 3. IFNA dengan INDEX MATCH

Dalam cara yang sama, IFNA boleh menangkap ralat #N/A yang dijana oleh fungsi carian lain. Sebagai contoh, mari kita gunakannya bersama-sama dengan PADANAN INDEXformula:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Intisari formula adalah sama seperti dalam semua contoh sebelumnya - INDEX MATCH melakukan carian dan IFNA menilai keputusan dan menangkap ralat #N/A jika nilai yang dirujuk tidak ditemui.

IFNA untuk mengembalikan berbilang hasil

Sekiranya fungsi dalaman (iaitu formula diletakkan dalam nilai argument) mengembalikan berbilang nilai, IFNA akan menguji setiap nilai yang dikembalikan secara individu dan mengeluarkan tatasusunan hasil. Contohnya:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

Dalam Dynamic Array Excel (Microsoft 365 dan Excel 2021), formula biasa dalam sel paling atas (E2) menumpahkan semua hasil dalam sel jiran secara automatik (dari segi istilah Excel, ia dipanggil julat tumpahan).

Dalam versi pra-dinamik (Excel 2019 dan lebih rendah), kesan yang sama boleh dicapai dengan menggunakan tatasusunan berbilang sel formula, yang dilengkapkan dengan pintasan Ctrl + Shift + Enter.

Apakah perbezaan antara IFNA dan IFERROR?

Bergantung pada punca punca masalah, formula Excel boleh mencetuskan ralat yang berbeza seperti #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM dan lain-lain. Fungsi IFERROR menangkap semua ralat tersebut manakala IFNA terhad kepada #N/A sahaja. Mana satu lebih baik untuk dipilih? Itu bergantung pada situasi.

Jika anda ingin menyekat sebarang jenis ralat , kemudian gunakan fungsi IFERROR. Ia amat berguna dalam pengiraan kompleks apabila formulatermasuk beberapa fungsi yang boleh menjana ralat berbeza.

Dengan fungsi carian , lebih baik anda menggunakan IFNA kerana ia memaparkan hasil tersuai hanya apabila nilai carian tidak ditemui dan tidak menyembunyikan asas masalah dengan formula itu sendiri.

Untuk menggambarkan perbezaannya, mari kita bawa semula formula IFNA VLOOKUP asas kami dan "secara tidak sengaja" tersalah eja nama fungsi (VLOKUP bukannya VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA tidak menyekat ralat ini, jadi anda boleh melihat dengan jelas bahawa ada masalah dengan salah satu nama fungsi:

Sekarang, mari lihat apa yang berlaku jika anda menggunakan IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hmm… ia mengatakan bahawa Olivia tidak mengambil peperiksaan, itu adalah tidak benar! Ini kerana fungsi IFERROR memerangkap #NAME? ralat dan sebaliknya mengembalikan teks tersuai. Dalam situasi ini, ia bukan sahaja mengembalikan maklumat yang salah tetapi juga mengaburkan isu dengan formula.

Begitulah cara menggunakan formula IFNA dalam Excel. Saya mengucapkan terima kasih kerana membaca dan berharap dapat berjumpa anda di blog kami minggu depan!

Muat turun yang tersedia

Contoh formula Excel IFNA (fail.xlsx)