У вашых працоўных аркушах шмат памылак #N/A і вам цікава даведацца, ці ёсць замест гэтага спосаб адлюстравання ўласнага тэксту? Формула IFNA - гэта рашэнне, якое вам трэба.

Калі формула Excel не можа ідэнтыфікаваць або знайсці нешта, выдаецца памылка #N/A. Каб выявіць такую ​​​​памылку і замяніць яе зручным паведамленнем, вы можаце выкарыстоўваць функцыю IFNA. Іншымі словамі, #N/A - гэта спосаб Excel сказаць, што значэння, якое вы шукаеце, няма ў наборы даных, на які спасылаецца. IFNA - гэта ваш спосаб захопу і апрацоўкі гэтай памылкі.

Функцыя IFNA ў Excel

Функцыя IFNA Excel прызначана для выяўлення і апрацоўкі памылак #N/A. Калі формула дае ацэнку #N/A, IFNA фіксуе гэтую памылку і замяняе яе карыстальніцкім значэннем, якое вы ўказваеце; інакш вяртае звычайны вынік формулы.

Сінтаксіс IFNA

Сінтаксіс функцыі IFNA наступны:

Дзе:

Значэнне (абавязкова) - формула, значэнне або спасылка для праверкі на наяўнасць памылкі #N/A.

Значэнне_калі_на (абавязкова) - значэнне каб вярнуцца, калі выяўленая памылка #N/A.

Заўвагі па выкарыстанні

• Функцыя IFNA апрацоўвае толькі #N/A без падаўлення іншых памылак.
• Калі аргумент значэнне з'яўляецца формулай масіва , IFNA вяртае масіў вынікаў, па адным на ячэйку, як паказана ў гэтым прыкладзе.

Даступнасць IFNA

Функцыя IFNA была ўведзена ўExcel 2013 і даступны ва ўсіх наступных версіях, уключаючы Excel 2016, Excel 2019, Excel 2021 і Microsoft 365.

У больш ранніх версіях вы можаце выявіць памылкі #N/A, выкарыстоўваючы разам функцыі IF і ISNA.

Як выкарыстоўваць функцыю IFNA ў Excel

Каб эфектыўна выкарыстоўваць IFNA ў Excel, прытрымлівайцеся гэтага агульнага падыходу:

1. У першым аргументе ( значэнне ), увядзіце формулу, на якую ўплывае памылка #N/A.
2. У другім аргументе ( value_if_na ) увядзіце тэкст, які вы хочаце вярнуць, замест стандартнага абазначэння памылкі. Каб вярнуць пустую ячэйку, калі нічога не знойдзена, увядзіце пусты радок ('"").

Каб вярнуць карыстальніцкі тэкст , агульная формула:

Каб вярнуць пустую ячэйку , агульная формула:

Давайце паглядзім, як гэта працуе на простым прыкладзе. Выкажам здагадку, што ў прыведзенай ніжэй табліцы вы хочаце ведаць, які бал дадзенага студэнта займае месца сярод іншых. Паколькі даныя сартуюцца па слупку Ацэнка ад самага высокага да самага нізкага, рэйтынг будзе адпавядаць адноснаму становішчу студэнта ў табліцы. А каб атрымаць пазіцыю, вы можаце выкарыстоўваць функцыю MATCH у яе самай простай форме:

=MATCH(E1, A2:A10, 0)

Паколькі шуканае значэнне (Neal) недаступнае ў масіве пошуку (A2:A10), узнікае памылка #N/A.

Сутыкнуўшыся з гэтай памылкай, нявопытныя карыстальнікі могуць падумаць, што нешта не так зформула, і вы, як стваральнік працоўнай кніжкі, атрымаеце шмат пытанняў. Каб пазбегнуць гэтага, вы можаце яўна паказаць, што формула правільная, яна проста не можа знайсці значэнне, якое яе просяць шукаць. Такім чынам, вы ўкладваеце формулу MATCH у першы аргумент IFNA, а ў другі аргумент уводзіце ўласны тэкст, у нашым выпадку "Не знойдзена":

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Зараз замест стандартная натацыя памылак, ваш уласны тэкст адлюстроўваецца ў ячэйцы, інфармуючы карыстальнікаў аб тым, што значэння пошуку няма ў наборы даных:

Як выкарыстоўваць IFNA з VLOOKUP

Часцей за ўсё памылка #N/A узнікае ў функцыях, якія шукаюць нешта накшталт VLOOKUP, HLOOKUP, LOOKUP і MATCH. Прыведзеныя ніжэй прыклады ахопліваюць некалькі тыповых выпадкаў выкарыстання.

Прыклад 1. Базавая формула IFNA VLOOKUP

Каб зафіксаваць памылкі #N/A, якія ўзнікаюць, калі VLOOKUP не можа знайсці супадзенне, праверце яго вынік з дапамогай IFNA і ўкажыце значэнне, якое будзе адлюстроўвацца замест памылкі. Звычайная практыка заключаецца ў абгортванні функцыі IFNA вакол існуючай формулы VLOOKUP з выкарыстаннем наступнага сінтаксісу:

У нашым прыкладзе табліцы, выкажам здагадку, што вы хочаце атрымаць адзнаку канкрэтнага студэнта (E1). Для гэтага вы выкарыстоўваеце гэтую класічную формулу VLOOKUP:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Праблема ў тым, што Ніл не здаў экзамен, таму яго імя няма ў спісе, і, відавочна, VLOOKUP не можа знайсці супадзенне.

Каб схаваць памылку, мыабгарніце VLOOKUP у IFNA так:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Цяпер вынік не выглядае такім страшным для карыстальніка і нашмат больш інфарматыўным:

Прыклад 2. IFNA VLOOKUP для пошуку на некалькіх аркушах

Функцыя IFNA таксама карысная для выканання так званых паслядоўных або ланцуговых пошукаў на некалькіх аркушах або розных працоўных сшытках. Ідэя заключаецца ў тым, што вы ўкладваеце некалькі розных формул IFNA(VLOOKUP(…)) адна ў адну такім чынам:

Калі асноўны ВПР нічога не знаходзіць, яго функцыя IFNA запускае наступны ВПР, пакуль не будзе знойдзена патрэбнае значэнне. Калі ні адзін пошук не атрымоўваецца, формула верне ўказаны тэкст.

Выкажам здагадку, што ў вас ёсць вынікі розных класаў, пералічаныя на розных аркушах (з назвамі Клас A , Клас B і Клас C ). Ваша мэта складаецца ў тым, каб атрымаць адзнаку канкрэтнага студэнта, чыё імя ўведзена ў ячэйку B1 вашага бягучага аркуша. Каб выканаць задачу, скарыстайцеся гэтай формулай:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Формула паслядоўна шукае зададзенае імя на трох розных аркушах у парадку ўкладання VLOOKUP і прыносіць першае знойдзенае супадзенне:

Прыклад 3. IFNA з INDEX MATCH

Аналагічным чынам IFNA можа выяўляць памылкі #N/A, якія ствараюцца іншымі функцыямі пошуку. У якасці прыкладу, давайце выкарыстоўваць яго разам з INDEX MATCHformula:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Сутнасць формулы такая ж, як і ва ўсіх папярэдніх прыкладах - INDEX MATCH выконвае пошук, а IFNA ацэньвае вынік і выяўляе памылку #N/A, калі значэнне, на якое спасылаецца, не знойдзена.

IFNA для вяртання некалькіх вынікаў

У выпадку, калі ўнутраная функцыя (напрыклад, формула, змешчаная ў значэнне аргумент) вяртае некалькі значэнняў, IFNA правярае кожнае вяртанае значэнне асобна і выводзіць масіў вынікаў. Напрыклад:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

У дынамічным масіве Excel (Microsoft 365 і Excel 2021) звычайная формула ў самай верхняй ячэйцы (E2) аўтаматычна разлівае ўсе вынікі ў суседніх ячэйках (у тэрмінах Excel, гэта называецца дыяпазонам разліву).

У папярэдне дынамічных версіях (Excel 2019 і ніжэй) падобнага эфекту можна дасягнуць, выкарыстоўваючы шматячэйкавы масіў формула, якая завяршаецца спалучэннем клавіш Ctrl + Shift + Enter.

У чым розніца паміж IFNA і IFERROR?

У залежнасці ад асноўнай прычыны праблема, формула Excel можа выклікаць розныя памылкі, такія як #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM і іншыя. Функцыя IFERROR выяўляе ўсе гэтыя памылкі, у той час як IFNA абмежаваная толькі #N/A. Які з іх лепш абраць? Гэта залежыць ад сітуацыі.

Калі вы жадаеце схаваць памылку любога роду , выкарыстоўвайце функцыю IFERROR. Гэта асабліва карысна ў складаных разліках, калі формулауключае ў сябе некалькі функцый, якія могуць ствараць розныя памылкі.

З функцыямі пошуку вам лепш выкарыстоўваць IFNA, паколькі ён адлюстроўвае карыстальніцкі вынік толькі тады, калі пошукавае значэнне не знойдзена і не хавае асноўнае праблемы з самой формулай.

Каб праілюстраваць розніцу, давайце вернем нашу асноўную формулу IFNA VLOOKUP і «выпадкова» памылімся ў назве функцыі (VLOKUP замест VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA не адхіляе гэтую памылку, так што вы можаце ясна бачыць, што нешта не так з адной з назваў функцый:

Зараз давайце паглядзім, што адбудзецца, калі вы выкарыстоўваеце IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Хм… там напісана, што Алівія не здавала экзамен, што няпраўда! Гэта таму, што функцыя IFERROR захоплівае #NAME? памылка і замест гэтага вяртае карыстальніцкі тэкст. У гэтай сітуацыі ён не толькі вяртае няправільную інфармацыю, але і хавае праблему з формулай.

Вось як выкарыстоўваць формулу IFNA ў Excel. Я дзякую вам за чытанне і з нецярпеннем чакаю сустрэчы з вамі ў нашым блогу на наступным тыдні!

Даступныя загрузкі

Прыклады формул Excel IFNA (файл .xlsx)