Kéngingkeun seueur kasalahan #N/A dina lembar kerja anjeun sareng hoyong terang upami aya cara pikeun nampilkeun téks khusus? Rumus IFNA mangrupikeun solusi anu anjeun peryogikeun.

Lamun hiji rumus Excel teu bisa ngaidentipikasi atawa manggihan hiji hal, éta miceun kasalahan #N/A. Pikeun nyekel kasalahan sapertos kitu sareng ngagentos pesen anu ramah-pamaké, anjeun tiasa nganggo fungsi IFNA. Kalayan kecap sanésna, #N/A mangrupikeun cara Excel nyarios yén nilai anu anjeun milarian henteu aya dina set data anu dirujuk. IFNA mangrupikeun cara anjeun pikeun nangkep sareng nanganan kasalahan éta.

Fungsi IFNA dina Excel

Pungsi Excel IFNA ditujukeun pikeun nyekel sareng nanganan kasalahan #N/A. Lamun rumus ngaevaluasi ka #N / ​​A, IFNA bubu kasalahan éta sarta ngaganti eta ku nilai custom Anjeun tangtukeun; Upami teu kitu, ngabalikeun hasil normal tina rumus.

Sintaksis IFNA

Sintaksis fungsi IFNA nyaéta kieu:

Dimana:

Nilai (diperlukeun) - rumus, nilai, atawa rujukan pikeun mariksa kasalahan #N/A.

Nilai_if_na (diperlukeun) - nilai pikeun mulang upami aya kasalahan #N/A dideteksi.

Catatan pamakean

• Pungsi IFNA ngan ukur nanganan #N/A tanpa nyegah kasalahan anu sanés.
• Lamun argumen value mangrupa rumus array , IFNA bakal ngabalikeun susunan hasil, hiji per sél, sakumaha ditémbongkeun dina conto ieu.

kasadiaan IFNA

Pungsi IFNA diwanohkeun dinaExcel 2013 sareng sayogi dina sadaya vérsi salajengna kalebet Excel 2016, Excel 2019, Excel 2021, sareng Microsoft 365.

Dina vérsi sateuacana, anjeun tiasa nangkep kasalahan #N/A ku ngagunakeun fungsi IF sareng ISNA babarengan.

Kumaha cara ngagunakeun pungsi IFNA dina Excel

Pikeun éféktif ngagunakeun IFNA dina Excel, tuturkeun pendekatan generik ieu:

1. Dina argumen kahiji ( nilai ), nempatkeun rumus anu dipangaruhan ku kasalahan #N/A.
2. Dina argumen kadua ( value_if_na ), ketik teks anu anjeun hoyong balikkeun tibatan notasi kasalahan standar. Pikeun mulangkeun sél kosong lamun euweuh nu kapanggih, asupkeun string kosong ('"").

Pikeun mulangkeun téks custom , rumus umumna nyaéta:

Pikeun mulangkeun sél kosong , rumus umumna nyaéta:

Hayu urang tingali kumaha gawéna dina conto basajan. Dina tabél di handap, anggap anjeun hoyong terang kumaha skor hiji murid anu dipasihkeun antara anu sanésna. Kusabab data diurutkeun dumasar kana kolom Skor ti pangluhurna ka panghandapna, rengking bakal cocog sareng posisi relatif murid dina tabél. Sarta pikeun meunangkeun posisi, Anjeun bisa make fungsi MATCH dina bentuk pangbasajanna:

=MATCH(E1, A2:A10, 0)

Kusabab nilai lookup (Neal) teu sadia dina array lookup (A2:A10), aya kasalahan #N/A.

Ngajalankeun kasalahan ieu, pamaké nu teu boga pangalaman bisa nyangka aya nu lepat dinarumus, sareng anjeun salaku panyipta buku kerja bakal nampi seueur patarosan. Pikeun ngahindarkeun ieu, anjeun sacara eksplisit tiasa nunjukkeun yén rumusna leres, éta henteu tiasa mendakan nilai anu dipénta pikeun milarian. Janten, anjeun nyarang rumus MATCH dina argumen kahiji IFNA sareng, dina argumen kadua, ketik téks khusus anjeun, "Teu kapanggih" dina kasus urang:

=IFNA(MATCH(E1, A2:A10, 0), "Not found")

Ayeuna, tinimbang notasi kasalahan standar, téks anjeun sorangan dipintonkeun dina sél, informing pamaké yén nilai lookup teu aya dina dataset:

Kumaha ngagunakeun IFNA kalawan VLOOKUP

Paseringna kasalahan #N/A lumangsung dina fungsi anu milarian hal sapertos VLOOKUP, HLOOKUP, LOOKUP, sareng MATCH. Conto di handap nutupan sababaraha kasus pamakean anu umum.

Conto 1. Rumus dasar IFNA VLOOKUP

Pikeun bubu #N/A kasalahan anu lumangsung nalika VLOOKUP henteu tiasa mendakan patandingan, pariksa hasilna. ngagunakeun IFNA sarta nangtukeun nilai pikeun dipintonkeun tinimbang kasalahan. Prakték umum nyaéta ngabungkus fungsi IFNA kana rumus VLOOKUP anjeun anu tos aya nganggo sintaksis ieu:

Dina tabel sampel kami, anggap anjeun hoyong meunangkeun skor hiji murid tangtu (E1). Pikeun ieu, anjeun nganggo rumus VLOOKUP klasik ieu:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Masalahna Neal henteu nyandak ujian, janten namina teu aya dina daptar, sareng écés VLOOKUP gagal mendakan. hiji patandingan.

Pikeun nyumputkeun kasalahan, urangBungkus VLOOKUP dina IFNA sapertos kieu:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Ayeuna, hasilna henteu matak pikasieuneun pikeun pangguna sareng langkung informatif:

Conto 2. IFNA VLOOKUP pikeun milarian sababaraha lembar

Pungsi IFNA ogé tiasa dianggo pikeun ngalakukeun anu disebut sequential atanapi chained lookups. sakuliah sababaraha lembar atawa workbooks béda. Gagasanna nyaéta anjeun nyarang sababaraha rumus IFNA(VLOOKUP(…)) anu béda-béda dina cara kieu:

Lamun hiji VLOOKUP primér teu manggihan nanaon, fungsi IFNA na ngajalankeun VLOOKUP salajengna nepi ka nilai nu dipikahoyong kapanggih. Upami sadaya pamaluruhan gagal, rumusna bakal ngabalikeun téks anu ditangtukeun.

Anggap anjeun gaduh skor kelas anu béda-béda didaptarkeun dina lembar anu béda (ngaranna Kelas A , Kelas B , jeung Kelas C ). Tujuan anjeun nyaéta pikeun kéngingkeun skor murid anu khusus, anu namina input dina sél B1 dina lembar kerja anjeun ayeuna. Pikeun ngalaksanakeun tugas, gunakeun rumus ieu:

=IFNA(VLOOKUP(B1, 'Class A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Class C'!A2:B5, 2, FALSE), "Not found")))

Rumusna sacara berurutan milarian nami anu ditunjuk dina tilu lembar anu béda dina urutan VLOOKUP anu disarangkeun sareng ngahasilkeun pertandingan anu munggaran kapanggih:

Conto 3. IFNA kalawan INDEX MATCH

Ku cara nu sarua, IFNA bisa nyekel #N/A kasalahan nu dihasilkeun ku fungsi lookup séjén. Salaku conto, hayu urang nganggo éta babarengan sareng INDEKS MATCHrumus:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Not found")

Inti rumusna sarua jeung dina sagala conto samemehna - INDEX MATCH ngalakukeun pamariksaan, sarta IFNA ngaevaluasi hasilna sarta nyekel kasalahan #N/A lamun nilai referenced teu kapanggih.

IFNA pikeun mulangkeun sababaraha hasil

Upami fungsi batin (nyaéta rumus disimpen dina nilai argumen) mulih sababaraha nilai, IFNA bakal nguji unggal nilai balik individual tur kaluaran Asép Sunandar Sunarya hasil. Contona:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Not found")

Dina Dynamic Array Excel (Microsoft 365 and Excel 2021), rumus biasa dina sél paling luhur (E2) sacara otomatis ngancurkeun sakabéh hasil dina sél tatangga (dina istilah. Excel, disebut rentang spill).

Dina vérsi pra-dinamis (Excel 2019 sareng handap), pangaruh anu sami tiasa dihontal ku ngagunakeun susunan multi-sél. rumus, anu réngsé ku potong kompas Ctrl + Shift + Enter.

Naon bédana antara IFNA jeung IFERROR?

Gumantung kana akar panyababna. Masalahna, rumus Excel tiasa nyababkeun kasalahan anu béda sapertos #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM, sareng anu sanésna. Fungsi IFERROR nangkep sadaya kasalahan éta bari IFNA dugi ka ukur #N/A. Mana anu langkung saé pikeun dipilih? Éta gumantung kana situasina.

Upami anjeun badé nahan salah naon waé , teras nganggo fungsi IFERROR. Ieu hususna kapaké dina itungan kompléks nalika rumusngawengku sababaraha pungsi nu bisa ngahasilkeun kasalahan béda.

Kalayan fungsi lookup , Anjeun leuwih sae make IFNA sabab mintonkeun hasil custom ngan lamun nilai lookup teu kapanggih jeung teu nyumputkeun kaayaan. masalah jeung rumus sorangan.

Pikeun ngagambarkeun bédana, hayu urang balikkeun rumus dasar IFNA VLOOKUP urang jeung "teu kahaja" salah ngeja ngaran fungsi urang (VLOKUP tinimbang VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

IFNA henteu ngeureunkeun kasalahan ieu, ku kituna anjeun tiasa ningali sacara jelas yén aya anu salah dina salah sahiji nami fungsi:

Ayeuna, hayu urang tingali naon anu bakal kajadian upami anjeun nganggo IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Did not take the exam")

Hmm… nyebutkeun yen Olivia teu lulus ujian, nu teu bener! Ieu kusabab fungsi IFERROR bubu #NAME? kasalahan sarta mulih téks custom gantina. Dina kaayaan ieu, éta henteu ngan ukur ngabalikeun inpormasi anu salah tapi ogé ngaleungitkeun masalah sareng rumus.

Kitu kumaha cara ngagunakeun rumus IFNA dina Excel. Abdi ngahaturkeun nuhun pikeun maca sareng ngarep-ngarep ningali anjeun dina blog kami minggu payun!

Unduh anu sayogi

Conto rumus Excel IFNA (file .xlsx)