¿Tiene muchos errores #N/A en sus hojas de cálculo y quiere saber si hay alguna forma de mostrar un texto personalizado en su lugar? La fórmula IFNA es la solución que necesita.

Cuando una fórmula de Excel no puede identificar o encontrar algo, lanza el error #N/A. Para capturar un error de este tipo y sustituirlo por un mensaje fácil de usar, puede utilizar la función IFNA. En otras palabras, #N/A es la forma que tiene Excel de decir que el valor que está buscando no está presente en el conjunto de datos de referencia. IFNA es su forma de atrapar y gestionar ese error.

Función IFNA en Excel

La función IFNA de Excel está pensada para capturar y manejar errores #N/A. Si una fórmula se evalúa como #N/A, IFNA atrapa ese error y lo sustituye por un valor personalizado que usted especifique; en caso contrario devuelve un resultado normal de la fórmula.

Sintaxis IFNA

La sintaxis de la función IFNA es la siguiente:

Dónde:

Valor (obligatorio) - la fórmula, el valor o la referencia para comprobar si hay un error #N/A.

Valor_si_na (obligatorio) - el valor a devolver si se detecta un error #N/A.

Notas de uso

• La función IFNA sólo gestiona #N/A sin suprimir ningún otro error.
• Si el valor es un argumento fórmula de matriz IFNA devuelve una matriz de resultados, uno por celda, como se muestra en este ejemplo.

Disponibilidad de IFNA

La función IFNA se introdujo en Excel 2013 y está disponible en todas las versiones posteriores, incluidas Excel 2016, Excel 2019, Excel 2021 y Microsoft 365.

En versiones anteriores, es posible detectar errores #N/A utilizando conjuntamente las funciones IF e ISNA.

Cómo utilizar la función IFNA en Excel

Para utilizar eficazmente IFNA en Excel, siga este enfoque genérico:

1. En el primer argumento ( valor ), ponga una fórmula afectada por el error #N/A.
2. En el segundo argumento ( valor_si_na ), escriba el texto que desea devolver en lugar de la notación de error estándar. Para devolver una celda vacía cuando no se encuentra nada, proporcione una cadena vacía ('"").

Para volver texto personalizado la fórmula genérica es:

Para devolver un celda en blanco la fórmula genérica es:

Veamos cómo funciona en un ejemplo sencillo. En la tabla siguiente, supongamos que desea saber cómo se clasifica la puntuación de un alumno determinado entre los demás. Dado que los datos están ordenados por el valor Puntuación de mayor a menor, el rango coincidirá con la posición relativa del alumno en la tabla. Y para obtener la posición, puede utilizar la función MATCH en su forma más simple:

=MATCH(E1, A2:A10, 0)

Como el valor de búsqueda (Neal) no está disponible en la matriz de búsqueda (A2:A10), se produce un error #N/A.

Al encontrarse con este error, los usuarios inexpertos podrían pensar que hay algo mal con la fórmula, y usted como creador del libro de trabajo recibirá un montón de preguntas. Para evitar esto, puede indicar explícitamente que la fórmula es correcta, sólo que no puede encontrar el valor que se le pide que busque. Por lo tanto, anida la fórmula MATCH en el primer argumento de IFNA y, en el segundo argumento, escriba su personalizadotexto, "No encontrado" en nuestro caso:

=IFNA(MATCH(E1, A2:A10, 0), "No encontrado")

Ahora, en lugar de la notación de error estándar, se muestra su propio texto en una celda, informando a los usuarios de que el valor de búsqueda no está presente en el conjunto de datos:

Cómo utilizar IFNA con VLOOKUP

La mayoría de las veces, el error #N/A se produce en funciones que buscan algo, como VLOOKUP, HLOOKUP, LOOKUP y MATCH. Los ejemplos siguientes cubren algunos casos de uso típicos.

Ejemplo 1. Fórmula básica IFNA VLOOKUP

Para atrapar los errores #N/A que se producen cuando VLOOKUP no puede encontrar una coincidencia, compruebe su resultado utilizando IFNA y especifique el valor que se mostrará en lugar del error. La práctica común es envolver la función IFNA alrededor de su fórmula VLOOKUP existente utilizando esta sintaxis:

En nuestra tabla de ejemplo, supongamos que desea recuperar la puntuación de un alumno en particular (E1). Para ello, utiliza esta fórmula VLOOKUP clásica:

=VLOOKUP(E1, A2:B10, 2, FALSE)

El problema es que Neal no hizo el examen, por lo tanto su nombre no está en la lista, y obviamente VLOOKUP no encuentra ninguna coincidencia.

Para ocultar el error, envolvemos VLOOKUP en IFNA de la siguiente manera:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "No se presentó al examen")

Ahora, el resultado no parece tan intimidatorio para el usuario y es mucho más informativo:

Ejemplo 2. IFNA VLOOKUP para buscar en varias hojas

La función IFNA también resulta útil para realizar el llamado secuencial o encadenado La idea es anidar diferentes fórmulas IFNA(VLOOKUP(...)) una dentro de otra de esta manera:

Si un VLOOKUP primario no encuentra nada, su función IFNA ejecuta el siguiente VLOOKUP hasta encontrar el valor deseado. Si todas las búsquedas fallan, la fórmula devolverá el texto especificado.

Supongamos que tiene las puntuaciones de diferentes clases en diferentes hojas (denominadas Clase A , Clase B y Clase C Tu objetivo es obtener la puntuación de un alumno concreto, cuyo nombre se introduce en la celda B1 de la hoja de cálculo actual. Para cumplir la tarea, utiliza esta fórmula:

=IFNA(VLOOKUP(B1, 'Clase A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Clase B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Clase C'!A2:B5, 2, FALSE), "No encontrado"))

La fórmula busca secuencialmente el nombre especificado en tres hojas diferentes en el orden en que se anidan los VLOOKUP y trae la primera coincidencia encontrada:

Ejemplo 3. IFNA con INDEX MATCH

De forma similar, IFNA puede detectar errores #N/A generados por otras funciones de búsqueda. A modo de ejemplo, utilicémoslo junto con la fórmula INDEX MATCH:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "No encontrado")

La esencia de la fórmula es la misma que en los ejemplos anteriores: INDEX MATCH realiza una búsqueda e IFNA evalúa el resultado y genera un error #N/A si no se encuentra el valor de referencia.

IFNA devolverá múltiples resultados

En caso de que la función interna (es decir, la fórmula colocada en el campo valor ) devuelve varios valores, IFNA comprobará cada valor devuelto individualmente y mostrará una matriz de resultados. Por ejemplo:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "No encontrado")

En Dynamic Array Excel (Microsoft 365 y Excel 2021), una fórmula regular en la celda superior (E2) derrama todos los resultados en las celdas vecinas automáticamente (en términos de Excel, se llama rango de derrame).

En las versiones predinámicas (Excel 2019 e inferiores), se puede conseguir un efecto similar utilizando una fórmula de matriz de varias celdas, que se completa con el atajo de teclado Ctrl + Mayús + Intro.

¿Cuál es la diferencia entre IFNA e IFERROR?

Dependiendo de la causa del problema, una fórmula de Excel puede desencadenar diferentes errores como #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM, etc. La función IFERROR captura todos esos errores mientras que IFNA se limita sólo a #N/A. ¿Cuál es mejor elegir? Depende de la situación.

Si desea suprimir cualquier tipo de error Es especialmente útil en cálculos complejos cuando una fórmula incluye varias funciones que pueden generar diferentes errores.

Con funciones de búsqueda es mejor que utilice IFNA, ya que sólo muestra un resultado personalizado cuando no se encuentra un valor de búsqueda y no oculta los problemas subyacentes de la propia fórmula.

Para ilustrar la diferencia, volvamos a nuestra fórmula básica IFNA VLOOKUP y "accidentalmente" escribamos mal el nombre de la función (VLOKUP en lugar de VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "No se presentó al examen")

IFNA no suprime este error, por lo que se ve claramente que algo falla en uno de los nombres de las funciones:

Ahora, veamos qué ocurre si utilizas IFERROR:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "No se presentó al examen")

Hmm... dice que Olivia no hizo el examen, ¡lo cual no es cierto! Esto se debe a que la función IFERROR atrapa el error #NAME? y devuelve el texto personalizado en su lugar. En esta situación, no sólo devuelve información errónea, sino que también oculta el problema con la fórmula.

Así es como se utiliza la fórmula IFNA en Excel. Gracias por leer y ¡espero verte en nuestro blog la semana que viene!

Descargas disponibles

Ejemplos de fórmulas IFNA en Excel (archivo .xlsx)