Sie erhalten viele #N/A-Fehler in Ihren Arbeitsblättern und möchten wissen, ob es eine Möglichkeit gibt, stattdessen einen benutzerdefinierten Text anzuzeigen? Die IFNA-Formel ist die Lösung, die Sie brauchen.

Wenn eine Excel-Formel etwas nicht identifizieren oder finden kann, wird die Fehlermeldung #N/A ausgegeben. Um einen solchen Fehler abzufangen und durch eine benutzerfreundliche Meldung zu ersetzen, können Sie die Funktion IFNA verwenden. Mit anderen Worten: #N/A ist die Art und Weise, wie Excel mitteilt, dass der gesuchte Wert im referenzierten Datensatz nicht vorhanden ist. IFNA ist Ihre Art, diesen Fehler abzufangen und zu behandeln.

IFNA-Funktion in Excel

Die Excel-Funktion IFNA dient zum Abfangen und Behandeln von #N/A-Fehlern. Wenn eine Formel zu #N/A ausgewertet wird, fängt IFNA diesen Fehler ab und ersetzt ihn durch einen benutzerdefinierten Wert, den Sie angeben; andernfalls wird ein normales Ergebnis der Formel zurückgegeben.

IFNA-Syntax

Die Syntax der IFNA-Funktion lautet wie folgt:

Wo:

Wert (erforderlich) - die Formel, der Wert oder die Referenz, die auf einen #N/A-Fehler geprüft werden soll.

Wert_wenn_na (erforderlich) - der Wert, der zurückgegeben wird, wenn ein #N/A-Fehler festgestellt wird.

Verwendungshinweise

• Die IFNA-Funktion behandelt nur #N/A, ohne alle anderen Fehler zu unterdrücken.
• Wenn die Wert Argument ist ein Matrixformel IFNA gibt ein Array von Ergebnissen zurück, eines pro Zelle, wie in diesem Beispiel gezeigt.

IFNA-Verfügbarkeit

Die IFNA-Funktion wurde in Excel 2013 eingeführt und ist in allen nachfolgenden Versionen verfügbar, einschließlich Excel 2016, Excel 2019, Excel 2021 und Microsoft 365.

In früheren Versionen können Sie #N/A-Fehler abfangen, indem Sie die Funktionen IF und ISNA zusammen verwenden.

So verwenden Sie die IFNA-Funktion in Excel

Um IFNA in Excel effektiv zu nutzen, folgen Sie diesem allgemeinen Ansatz:

1. Im ersten Argument ( Wert ), setzen Sie eine vom #N/A-Fehler betroffene Formel ein.
2. Im zweiten Argument ( wert_wenn_na ), geben Sie anstelle der Standard-Fehlernotation den Text ein, den Sie zurückgeben möchten. Um eine leere Zelle zurückzugeben, wenn nichts gefunden wurde, geben Sie eine leere Zeichenfolge ('"") ein.

Zur Rückkehr benutzerdefinierter Text lautet die allgemeine Formel:

Zur Rückgabe einer leere Zelle lautet die allgemeine Formel:

Sehen wir uns die Funktionsweise anhand eines einfachen Beispiels an. Nehmen wir an, dass Sie in der folgenden Tabelle wissen möchten, wie die Punktzahl eines bestimmten Schülers im Vergleich zu den anderen abschneidet. Da die Daten nach dem Ergebnis Spalte vom höchsten zum niedrigsten Wert, entspricht der Rang der relativen Position des Schülers in der Tabelle. Und um die Position zu erhalten, können Sie die MATCH-Funktion in ihrer einfachsten Form verwenden:

=MATCH(E1, A2:A10, 0)

Da der Nachschlagewert (Neal) nicht in der Nachschlagematrix (A2:A10) vorhanden ist, tritt ein #N/A-Fehler auf.

Wenn Sie auf diesen Fehler stoßen, könnten unerfahrene Benutzer denken, dass mit der Formel etwas nicht stimmt, und Sie als Ersteller der Arbeitsmappe werden eine Menge Fragen erhalten. Um dies zu vermeiden, können Sie explizit angeben, dass die Formel korrekt ist, aber den gesuchten Wert nicht finden kann. Sie verschachteln also die MATCH-Formel in das erste Argument von IFNA und geben in das zweite Argument Ihre eigeneText, in unserem Fall "Nicht gefunden":

=IFNA(MATCH(E1, A2:A10, 0), "Nicht gefunden")

Anstelle der Standardfehlernotation wird nun Ihr eigener Text in einer Zelle angezeigt, der die Benutzer darüber informiert, dass der Nachschlagewert nicht im Datensatz vorhanden ist:

So verwenden Sie IFNA mit VLOOKUP

Am häufigsten tritt der #N/A-Fehler in Funktionen auf, die nach etwas suchen, wie z. B. VLOOKUP, HLOOKUP, LOOKUP und MATCH. Die folgenden Beispiele decken einige typische Anwendungsfälle ab.

Beispiel 1: IFNA VLOOKUP-Grundformel

Um #N/A-Fehler abzufangen, die auftreten, wenn VLOOKUP keine Übereinstimmung findet, überprüfen Sie das Ergebnis mit IFNA und geben Sie den Wert an, der anstelle des Fehlers angezeigt werden soll. Die gängige Praxis ist, die IFNA-Funktion mit dieser Syntax um Ihre bestehende VLOOKUP-Formel zu wickeln:

Nehmen wir an, Sie möchten in unserer Beispieltabelle die Punktzahl eines bestimmten Schülers (E1) abrufen und verwenden dazu diese klassische VLOOKUP-Formel:

=VLOOKUP(E1, A2:B10, 2, FALSE)

Das Problem ist, dass Neal nicht an der Prüfung teilgenommen hat, daher ist sein Name nicht in der Liste enthalten, und offensichtlich findet VLOOKUP keine Übereinstimmung.

Um den Fehler zu verbergen, verpacken wir VLOOKUP in IFNA wie folgt:

=IFNA(VLOOKUP(E1, A2:B10, 2, FALSE), "Habe die Prüfung nicht abgelegt")

Jetzt sieht das Ergebnis für den Benutzer nicht mehr so einschüchternd aus und ist viel informativer:

Beispiel 2: IFNA VLOOKUP zum Nachschlagen über mehrere Blätter

Die IFNA-Funktion eignet sich auch für die Durchführung der so genannten sequenziell oder verkettet Die Idee ist, dass Sie mehrere verschiedene IFNA(VLOOKUP(...))-Formeln auf diese Weise ineinander verschachteln:

Wenn ein primäres VLOOKUP nichts findet, führt seine Funktion IFNA das nächste VLOOKUP aus, bis der gewünschte Wert gefunden wird. Wenn alle Nachschlagevorgänge fehlschlagen, gibt die Formel den angegebenen Text zurück.

Angenommen, Sie haben die Noten der verschiedenen Klassen in verschiedenen Blättern aufgelistet (namens Klasse A , Klasse B und Klasse C Ihr Ziel ist es, die Punktzahl eines bestimmten Schülers zu ermitteln, dessen Name in die Zelle B1 des aktuellen Arbeitsblatts eingegeben wurde. Um diese Aufgabe zu erfüllen, verwenden Sie diese Formel:

=IFNA(VLOOKUP(B1, 'Klasse A'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Klasse B'!A2:B5, 2, FALSE), IFNA(VLOOKUP(B1, 'Klasse C'!A2:B5, 2, FALSE), "Nicht gefunden")))

Die Formel sucht den angegebenen Namen nacheinander in drei verschiedenen Blättern in der Reihenfolge, in der VLOOKUPs verschachtelt sind, und bringt die erste gefundene Übereinstimmung:

Beispiel 3: IFNA mit INDEX MATCH

In ähnlicher Weise kann IFNA #N/A-Fehler abfangen, die von anderen Lookup-Funktionen erzeugt werden. Als Beispiel wollen wir sie zusammen mit der INDEX MATCH-Formel verwenden:

=IFNA(INDEX(B2:B10, MATCH(E1, A2:A10, 0)), "Nicht gefunden")

Der Kern der Formel ist derselbe wie in allen vorherigen Beispielen - INDEX MATCH führt eine Suche durch, und IFNA wertet das Ergebnis aus und fängt einen #N/A-Fehler auf, wenn der referenzierte Wert nicht gefunden wird.

IFNA soll mehrere Ergebnisse liefern

Für den Fall, dass die innere Funktion (d.h. die Formel, die in der Wert Argument) mehrere Werte zurückgibt, prüft IFNA jeden zurückgegebenen Wert einzeln und gibt ein Array mit den Ergebnissen aus, zum Beispiel:

=IFNA(VLOOKUP(D2:D4, A2:B10, 2, FALSE), "Nicht gefunden")

In Dynamic Array Excel (Microsoft 365 und Excel 2021) spillt eine reguläre Formel in der obersten Zelle (E2) automatisch alle Ergebnisse in die benachbarten Zellen (in Bezug auf Excel nennt man das einen Spillbereich).

In den vordynamischen Versionen (Excel 2019 und niedriger) kann ein ähnlicher Effekt durch die Verwendung einer mehrzelligen Array-Formel erzielt werden, die mit der Tastenkombination Strg + Umschalt + Eingabe abgeschlossen wird.

Was ist der Unterschied zwischen IFNA und IFERROR?

Je nach Ursache des Problems kann eine Excel-Formel verschiedene Fehler auslösen, wie z. B. #N/A, #NAME, #VALUE, #REF, #DIV/0, #NUM usw. Die Funktion IFERROR fängt all diese Fehler ab, während IFNA nur auf #N/A beschränkt ist. Welcher Fehler besser ist, hängt von der jeweiligen Situation ab.

Wenn Sie unterdrücken wollen jede Art von Fehler Sie ist besonders nützlich bei komplexen Berechnungen, wenn eine Formel mehrere Funktionen enthält, die unterschiedliche Fehler erzeugen können.

Mit Nachschlagefunktionen verwenden Sie besser IFNA, da es nur dann ein benutzerdefiniertes Ergebnis anzeigt, wenn ein Nachschlagewert nicht gefunden wird, und die zugrunde liegenden Probleme mit der Formel selbst nicht verbirgt.

Um den Unterschied zu verdeutlichen, kehren wir zu unserer grundlegenden IFNA VLOOKUP-Formel zurück und schreiben "versehentlich" den Namen der Funktion falsch (VLOKUP statt VLOOKUP).

=IFNA(VLOKUP(E1, A2:B10, 2, FALSE), "Habe die Prüfung nicht abgelegt")

IFNA unterdrückt diesen Fehler nicht, so dass Sie deutlich sehen können, dass mit einem der Funktionsnamen etwas nicht stimmt:

Nun wollen wir sehen, was passiert, wenn Sie IFERROR verwenden:

=IFERROR(VLOKUP(E1, A2:B10, 2, FALSE), "Habe die Prüfung nicht abgelegt")

Hmm... es heißt, dass Olivia die Prüfung nicht abgelegt hat, was nicht stimmt! Das liegt daran, dass die Funktion IFERROR den Fehler #NAME? abfängt und stattdessen den benutzerdefinierten Text zurückgibt. In dieser Situation gibt sie nicht nur falsche Informationen zurück, sondern verschleiert auch das Problem mit der Formel.

So funktioniert die IFNA-Formel in Excel. Ich danke Ihnen für die Lektüre und freue mich darauf, Sie nächste Woche in unserem Blog zu sehen!

Verfügbare Downloads

Excel IFNA Formel Beispiele (.xlsx Datei)