Tutoriali shpjegon se si të përdoret funksioni IF i ndërlidhur në Excel për të kontrolluar kushte të shumta. Do të mësoni gjithashtu disa funksione të tjera që mund të jenë alternativa të mira për përdorimin e një formule të ndërthurur në Excel.

Si e zbatoni zakonisht një logjikë vendimmarrëse në fletët tuaja të punës në Excel? Në shumicën e rasteve, ju do të përdorni një formulë IF për të testuar gjendjen tuaj dhe për të kthyer një vlerë nëse kushti plotësohet, një vlerë tjetër nëse kushti nuk plotësohet. Për të vlerësuar më shumë se një kusht dhe për të kthyer vlera të ndryshme në varësi të rezultateve, ju futni IF të shumta brenda njëri-tjetrit.

Megjithëse shumë popullor, deklarata IF e mbivendosur nuk është mënyra e vetme për të kontrolluar kushte të shumta në Excel. Në këtë tutorial, do të gjeni një sërë alternativash që patjetër ia vlen t'i eksploroni.

Deklarata IF e mbivendosur e Excel

Këtu është formula klasike IF e mbivendosur në Excel në një formë të përgjithshme :

Mund të shihni se çdo funksion pasues IF është i përfshirë në argumentin value_if_false të funksionit të mëparshëm. Çdo funksion IF është i mbyllur në grupin e vet të kllapave, por të gjitha kllapat mbyllëse janë në fund të formulës.

Formula jonë gjenerike e mbivendosur IF vlerëson 3 kushte dhe kthen 4 rezultate të ndryshme (rezultati 4 kthehet nëse asnjë ngalibër pune për shkarkim

Excel i ndërthurur If - shembuj (skedar .xlsx)

test kushti2 , nëse TRUE - ktheni r rezultat2 , nëse FALSE -

test kushti3 , nëse TRUE - ktheni rezultat3 , nëse E FALSE -

kthimi rezultati4

Si shembull, le të gjejmë komisionet për një numër shitësish bazuar në sasinë e shitjeve që ata kanë bërë:

Në matematikë, ndryshimi i renditjes së shtesave nuk e ndryshon shumën. Në Excel, ndryshimi i renditjes së funksioneve IF ndryshon rezultatin. Pse? Sepse një formulë e ndërlidhur IF kthen një vlerë që korrespondon me kushtin e parë TRUE . Prandaj, në deklaratat tuaja të mbivendosura IF, është shumë e rëndësishme të rregulloni kushtet në drejtimin e duhur - nga lart në të ulët ose nga poshtë në të lartë, në varësi të logjikës së formulës suaj. Në rastin tonë, ne kontrollojmë së pari kushtin "më të lartë", pastaj "të dytën më të lartë" dhe kështu me radhë:

=IF(B2>150, 10%, IF(B2>=101, 7%, IF(B2>=51, 5%, IF(B2>=1, 3%, ""))))

Nëse vendosim kushtet në rendin e kundërt, nga poshtë lart, rezultatet do të ishin të gjitha të gabuara sepse formula jonë do të ndalonte pas testit të parë logjik (B2>=1) për çdo vlerë më të madhe se 1. Le të themi, kemi 100 dollarënë shitje - është më i madh se 1, kështu që formula nuk do të kontrollonte kushtet e tjera dhe do të kthente 3% si rezultat.

Nëse preferoni t'i rregulloni kushtet nga më e ulëta në të lartë, atëherë përdorni "më pak se " operatori dhe vlerësoni së pari kushtin "më të ulët", pastaj "të dytën më të ulët" dhe kështu me radhë:

=IF($B2<1, 0%, IF($B2<51, 3%, IF($B2<101, 5%, IF($B2<=150, 7%, 10%))))

Siç e shihni, duhet shumë mendim për të ndërtuar logjikën i një deklarate IF të mbivendosur saktë deri në fund. Dhe megjithëse Microsoft Excel lejon futjen e deri në 64 funksione IF në një formulë, kjo nuk është diçka që vërtet do të dëshironit ta bënit në fletët tuaja të punës. Pra, nëse ju (ose dikush tjetër) po shikoni formulën tuaj IF të mbivendosur në Excel duke u përpjekur të kuptoni se çfarë bën në të vërtetë, është koha të rishqyrtoni strategjinë tuaj dhe ndoshta të zgjidhni një mjet tjetër në arsenalin tuaj.

Për më shumë informacion , ju lutemi shihni deklaratën e mbivendosur IF të Excel.

Nëse e ndërlidhur me kushte OR/AND

Në rast se ju duhet të vlerësoni disa grupe kushtesh të ndryshme, mund t'i shprehni ato kushte duke përdorur OR si dhe Funksioni AND, futni funksionet brenda deklaratave IF dhe më pas vendosni IF në njëra-tjetrën.

IF e ndërlidhur në Excel me deklarata OR

Duke përdorur funksionin OR mund të kontrolloni dy ose më shumë kushte të ndryshme në testin logjik të secilit funksion IF dhe ktheni TRUE nëse ndonjë (të paktën një) nga argumentet OR vlerësohet në TRUE. Për të parë se si funksionon në të vërtetë, ju lutemi merrni parasyshshembullin e mëposhtëm.

Si të supozojmë se keni dy kolona shitjesh, le të themi shitjet e janarit në kolonën B dhe shitjet e shkurtit në kolonën C. Ju dëshironi të kontrolloni numrat në të dy kolonat dhe të llogarisni komisionin bazuar në një numër më të lartë. Me fjalë të tjera, ju ndërtoni një formulë me logjikën e mëposhtme: nëse shitjet në janar ose në shkurt janë më të mëdha se 150 dollarë, shitësi merr 10% komision, nëse shitjet në janar ose shkurt janë më të mëdha ose të barabarta me 101 dollarë, shitësi merr 7% komision. , dhe kështu me radhë.

Për ta bërë këtë, shkruani disa deklarata OF si OR(B2>150, C2>150) dhe futini ato në testet logjike të funksioneve IF të diskutuara më sipër. Si rezultat, ju merrni këtë formulë:

=IF(OR(B2>150, C2>150), 10%, IF(OR(B2>=101, C2>=101),7%, IF(OR(B2>=51, C2>=51), 5%, IF(OR(B2>=1, C2>=1), 3%, ""))))

Dhe komisioni caktohet në bazë të shumës më të lartë të shitjeve:

Për më shumë shembuj formule, ju lutemi shihni deklaratën Excel IF OR.

Nëse e ndërlidhur IF në Excel me deklarata AND

Nëse testet tuaja logjike përfshijnë kushte të shumta dhe të gjitha këto kushte duhet të vlerësohen në TRUE, shprehni ato duke përdorur funksionin AND.

Për shembull, për të caktuar komisionet bazuar në një numër më të vogël shitjesh, merrni formulën e mësipërme dhe zëvendësoni OSE me deklaratat AND. Për ta thënë ndryshe, ju i thoni Excel të kthejë 10% vetëm nëse shitjet në janar dhe shkurt janë më të mëdha se 150 dollarë, 7% nëse shitjet në janar dhe shkurt janë më të mëdha se ose të barabarta me 101 dollarë, e kështu me radhë.

=IF(AND(B2>150, C2>150), 10%, IF(AND(B2>=101, C2>=101), 7%, IF(AND(B2>=51, C2>=51), 5%, IF(AND(B2>=1, C2>=1), 3%, ""))))

Si rezultat, formula jonë e mbivendosur IF llogarit komisioninbazuar në numrin më të ulët në kolonat B dhe C. Nëse secila kolonë është bosh, nuk ka fare komision sepse asnjë nga kushtet AND nuk plotësohet:

Nëse ju' d dëshironi të ktheni 0% në vend të qelizave bosh, zëvendësoni një varg bosh (''") në argumentin e fundit me 0%:

=IF(AND(B2>150, C2>150), 10%, IF(AND(B2>=101, C2>=101), 7%, IF(AND(B2>=51, C2>=51), 5%, IF(AND(B2>=1, C2>=1), 3%, 0%))))

Më shumë informacion mund të gjeni këtu: Excel IF me kushte të shumta DHE/OR.

VLOOKUP në vend të IF të mbivendosur në Excel

Kur keni të bëni me "peshore", d.m.th. vargje të vazhdueshme të vlerave numerike që së bashku mbulojnë të gjithë gamën, në shumicën e rasteve ju mund të përdorni funksionin VLOOKUP në vend të IF-ve të mbivendosur.

Për fillestarët, bëni një tabelë referimi siç tregohet në pamjen e mëposhtme. Dhe më pas, ndërtoni një formulë Vlookup me përputhje e përafërt , d.m.th. me argumentin range_lookup të vendosur në TRUE.

Duke supozuar se vlera e kërkimit është në B2 dhe tabela e referencës është F2:G5, formula shkon si më poshtë :

=VLOOKUP(B2,$F$2:$G$5,2,TRUE)

Ju lutemi vini re se ne rregullojmë array_tabela me referenca absolute ($F$2:$G$5) që formula të kopjohet saktë në qelizat e tjera:

Duke vendosur argumentin e fundit të formulës tuaj Vlookup në TRUE, ju i thoni Excel të kërkoni për përputhjen më të afërt - nëse nuk gjendet një përputhje e saktë, ktheni vlerën tjetër më të madhe që është më e vogël se vlera e kërkuar. Si rezultat, formula juaj do të përputhet jo vetëm me vlerat e sakta në tabelën e kërkimit, por edhe me çdovlerat që bien në mes.

Për shembull, vlera e kërkimit në B3 është 95 $. Ky numër nuk ekziston në tabelën e kërkimit dhe Vlookup me përputhje të saktë do të kthente një gabim #N/A në këtë rast. Por Vlookup me përputhje të përafërt vazhdon kërkimin derisa të gjejë vlerën më të afërt që është më e vogël se vlera e kërkuar (e cila është 50 $ në shembullin tonë) dhe kthen një vlerë nga kolona e dytë në të njëjtin rresht (që është 5%).

Por, çka nëse vlera e kërkimit është më e vogël se numri më i vogël në tabelën e kërkimit ose qeliza e kërkimit është bosh? Në këtë rast, një formulë Vlookup do të kthejë gabimin #N/A. Nëse nuk është ajo që dëshironi, futni VLOOKUP brenda IFERROR dhe jepni vlerën në dalje kur vlera e kërkimit nuk gjendet. Për shembull:

=IFERROR(VLOOKUP(B2, $F$2:$G$5, 2, TRUE), "Outside range")

Shënim i rëndësishëm! Që një formulë Vlookup me përputhje të përafërt të funksionojë si duhet, kolona e parë në tabelën e kërkimit duhet të renditet sipas rendit në rritje , nga më e vogla te më e madhja.

Për më shumë informacion, ju lutemi shikoni "Përputhja e saktë" VLOOKUP kundër përputhjes së përafërt VLOOKUP.

Deklarata IFS si alternativë ndaj funksionit IF të ndërlidhur

Në Excel 2016 dhe versionet e mëvonshme, Microsoft prezantoi një funksion të veçantë për të vlerësuar kushte të shumta - funksionin IFS.

Një formulë IFS mund të trajtojë deri në 127 çifte test_logjik / value_if_true dhe testi i parë logjik që vlerësohet në TRUE "fiton":

Në përputhje me sintaksën e mësipërme, formula jonë e mbivendosur IF mund të rindërtohet në këtë mënyrë:

=IFS(B2>150, 10%, B2>=101, 7%, B2>=51, 5%, B2>0, 3%)

Ju lutemi kushtoni vëmendje që Funksioni IFS kthen gabimin #N/A nëse asnjë nga kushtet e specifikuara nuk plotësohet. Për të shmangur këtë, mund të shtoni një tjetër test_logjik / value_if_true në fund të formulës suaj që do të kthejë 0 ose varg bosh ("") ose çfarëdo vlere që dëshironi nëse asnjë nga testet e mëparshme logjike janë të TRUE:

=IFS(B2>150, 10%, B2>=101, 7%, B2>=51, 5%, B2>0, 3%, TRUE, "")

Si rezultat, formula jonë do të kthejë një varg bosh (qelizë bosh) në vend të gabimit #N/A nëse një qelizë përkatëse në kolonën B është bosh ose përmban tekst ose numër negativ.

Shënim. Ashtu si IFS i ndërlidhur, funksioni IFS i Excel kthen një vlerë që korrespondon me kushtin e parë që vlerësohet në TRUE, kjo është arsyeja pse renditja e testeve logjike në një formulë IFS ka rëndësi.

Për më shumë informacion, ju lutemi shikoni funksionin Excel IFS në vend të kësaj të IF të mbivendosur.

CHOOSE në vend të formulës së mbivendosur IF në Excel

Një mënyrë tjetër për të testuar kushte të shumta brenda një formule të vetme në Excel është përdorimi i funksionit CHOOSE, i cili është krijuar për të kthyer një vlerë nga lista e bazuar në një pozicion të asaj vlere.

Zbatuar në grupin tonë të të dhënave të mostrës, formula merr formën e mëposhtme:

=CHOOSE((B2>=1) + (B2>=51) + (B2>=101) + (B2>150), 3%, 5%, 7%, 10%)

Në argumentin e parë ( index_num ), ju vlerësoni të gjitha kushtet dhe shtoni rezultatet. E dhënëqë TRUE barazohet me 1 dhe FALSE me 0, në këtë mënyrë ju llogaritni pozicionin e vlerës që duhet kthyer.

Për shembull, vlera në B2 është 150 $. Për këtë vlerë, 3 kushtet e para janë TRUE dhe e fundit (B2 > 150) është FALSE. Pra, indeksi_num është i barabartë me 3, që do të thotë se është kthyer vlera e 3-të, e cila është 7%.

Këshillë. Nëse asnjë nga testet logjike nuk është TRUE, indeksi_num është i barabartë me 0, dhe formula kthen #VALUE! gabim. Një rregullim i lehtë është mbështjellja e CHOOSE në funksionin IFERROR si kjo:

=IFERROR(CHOOSE((B2>=1) + (B2>=51) + (B2>=101) + (B2>150), 3%, 5%, 7%, 10%), "")

Për më shumë informacion, ju lutemi shihni funksionin CHOOSE Excel me shembuj formulash.

Funksioni SWITCH si një formë koncize e IF të mbivendosur në Excel

Në situatat kur keni të bëni me një grup fiks vlerash të paracaktuara, jo shkallë, funksioni SWITCH mund të jetë një alternativë kompakte ndaj kompleksit deklaratat e mbivendosura IF:

Funksioni SWITCH vlerëson shprehjen kundrejt një liste vlerash dhe kthen rezultatin që korrespondon me përputhjen e parë të gjetur.

Në rast se dëshironi të llogarisni komisionin bazuar në notat e mëposhtme, në vend të shumave të shitjeve, mund të përdorni këtë kompakt versioni i formulës IF të mbivendosur në Excel:

=SWITCH(C2, "A", 10%, "B", 7%, "C", 5%, "D", 3%, "")

Ose, mund të bëni një tabelë referimi siç tregohet në pamjen e mëposhtme dhe të përdorni referencat e qelizave në vend të vlerave të koduara:

=SWITCH(C2, $F$2, $G$2, $F$3, $G$3, $F$4, $G$4, $F$5, $G$5, "")

Ju lutemvini re se ne mbyllim të gjitha referencat përveç të parës me shenjën $ për t'i parandaluar ato të ndryshojnë kur kopjoni formulën në qeliza të tjera:

Shënim. Funksioni SWITCH disponohet vetëm në Excel 2016 dhe më të lartë.

Për më shumë informacion, ju lutemi shihni funksionin SWITCH - forma kompakte e deklaratës IF të ndërlidhur.

Lidhja e shumë funksioneve IF në Excel

Siç u përmend në shembullin e mëparshëm, funksioni SWITCH u prezantua vetëm në Excel 2016. Për të trajtuar detyra të ngjashme në versionet më të vjetra të Excel, mund të kombinoni dy ose më shumë deklarata IF duke përdorur operatorin Concatenate (&) ose funksionin CONCATENATE .

Për shembull:

=(IF(C2="a", 10%, "") & IF(C2="b", 7%, "") & IF(C2="c", 5%, "") & IF(C2="d", 3%, ""))*1

Ose

=CONCATENATE(IF(C2="a", 10%, ""), IF(C2="b", 7%, ""), IF(C2="c", 5%, "") & IF(C2="d", 3%, ""))*1

Siç mund të keni vërejmë, ne e shumëzojmë rezultatin me 1 në të dyja formulat. Bëhet për të kthyer një varg të kthyer nga formula Concatenate në një numër. Nëse dalja juaj e pritur është tekst, atëherë operacioni i shumëzimit nuk është i nevojshëm.

Për më shumë informacion, ju lutemi shihni funksionin CONCATENATE në Excel.

Mund të shihni se Microsoft Excel ofron një sërë alternativash të mira në formulat e mbivendosura IF, dhe shpresojmë se ky tutorial ju ka dhënë disa të dhëna se si t'i përdorni ato në fletët tuaja të punës. Për të parë më nga afër shembujt e diskutuar në këtë tutorial, jeni të mirëpritur të shkarkoni mostrën e librit tonë të punës më poshtë. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme!

Praktikoni