Этот учебник научит вас, как построить формулу "Если совпадает" в Excel, чтобы она возвращала логические значения, пользовательский текст или значение из другой ячейки.

Формула Excel для проверки совпадения двух ячеек может быть такой же простой, как A1=B1. Однако могут возникнуть различные обстоятельства, когда это очевидное решение не будет работать или даст результаты, отличные от ожидаемых. В этом уроке мы обсудим различные способы сравнения ячеек в Excel, чтобы вы могли найти оптимальное решение для вашей задачи.

Как проверить, совпадают ли две ячейки в Excel

Существует множество вариантов формулы Excel If match. Просто просмотрите приведенные ниже примеры и выберите тот, который лучше всего подходит для вашего сценария.

Если две ячейки равны, возвращается TRUE

Самый простой " Если одна клетка равна другой, то true". Формула Excel выглядит следующим образом:

Например, чтобы сравнить ячейки в столбцах A и B в каждой строке, введите эту формулу в C2, а затем скопируйте ее вниз по столбцу:

=A2=B2

В результате вы получите TRUE, если две ячейки одинаковы, FALSE в противном случае:

Примечания:

• Эта формула возвращает два булевых значения: если две ячейки равны - TRUE; если не равны - FALSE. Чтобы вернуть только значения TRUE, используйте оператор IF, как показано в следующем примере.
• Эта формула без учета регистра Если регистр текста имеет значение, то используйте формулу с учетом регистра.

Если две ячейки совпадают, возвращается значение

Чтобы вернуть собственное значение при совпадении двух ячеек, постройте оператор IF, используя этот шаблон:

Например, чтобы сравнить A2 и B2 и вернуть "да", если они содержат одинаковые значения, и "нет" в противном случае, формула будет следующей:

=IF(A2=B2, "да", "нет")

Если вы хотите вернуть значение только в том случае, если ячейки равны, то введите пустую строку ("") для значение_если_ложно .

Если совпадает, то да :

=IF(A2=B2, "да", "")

Если совпадает, то TRUE:

=IF(A2=B2, TRUE, "")

Примечание. Чтобы вернуть логическое значение TRUE, не заключайте его в двойные кавычки. Использование двойных кавычек преобразует логическое значение в обычную текстовую строку.

Если одна ячейка равна другой, то возвращается другая ячейка

А вот вариация на тему Excel, если совпадает формула, которая решает эту конкретную задачу: сравнить значения в двух ячейках и, если данные совпадают, то скопировать значение из другой ячейки.

На языке Excel это формулируется следующим образом:

Например, чтобы проверить элементы в столбцах A и B и вернуть значение из столбца C, если текст совпадает, формула в D2, скопированная вниз, имеет следующий вид:

=IF(A2=B2, C2, "")

Формула с учетом регистра для проверки совпадения двух ячеек

В ситуации, когда вы имеете дело с текстовыми значениями, чувствительными к регистру, используйте функцию EXACT для точного сравнения ячеек, включая регистр букв:

Например, чтобы сравнить элементы в A2 и B2 и вернуть "да", если текст точно совпадает, и "нет", если найдены различия, вы можете использовать эту формулу:

=IF(EXACT(A2, B2), "Да", "Нет")

Как проверить, равны ли несколько ячеек

Как и при сравнении двух ячеек, проверка нескольких ячеек на совпадение также может быть выполнена несколькими различными способами.

Формула AND для проверки совпадения нескольких ячеек

Чтобы проверить совпадение нескольких значений, можно использовать функцию AND с двумя или более логическими тестами:

Например, чтобы проверить, равны ли ячейки A2, B2 и C2, используется формула:

=AND(A2=B2, A2=C2)

В Excel с динамическими массивами (365 и 2021) вы также можете использовать приведенный ниже синтаксис. В Excel 2019 и ниже это будет работать только как традиционная формула массива CSE, завершенная нажатием клавиш Ctrl + Shift + Enter вместе.

=AND(A2=B2:C2)

Результатом обеих формул AND являются логические значения TRUE и FALSE.

Чтобы вернуть собственные значения, оберните AND в функцию IF следующим образом:

=IF(AND(A2=B2:C2), "yes", "")

Эта формула возвращает "да", если все три ячейки равны, в противном случае - пустую ячейку.

Формула COUNTIF для проверки совпадения нескольких столбцов

Другим способом проверки множественных совпадений является использование функции COUNTIF в данной форме:

Где ассортимент это диапазон ячеек, которые необходимо сравнить друг с другом, ячейка это любая отдельная ячейка в диапазоне, и n это количество ячеек в диапазоне.

Для нашего набора данных формула может быть записана в следующем виде:

=COUNTIF(A2:C2, A2)=3

Если вы сравниваете много столбцов, функция COLUMNS может автоматически получить количество ячеек (n):

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

А функция IF поможет вам вернуть в качестве результата все, что вы хотите:

=IF(COUNTIF(A2:C2, A2)=3, "Все совпадает", "")

Формула с учетом регистра для множественных совпадений

Как и при проверке двух ячеек, мы используем функцию EXACT для точного сравнения, включая регистр букв. Для работы с несколькими ячейками EXACT нужно вложить в функцию AND следующим образом:

В Excel 365 и Excel 2021, благодаря поддержке динамических массивов, это работает как обычная формула. В Excel 2019 и ниже, не забудьте нажать Ctrl + Shift + Enter, чтобы сделать это формулой. формула массива .

Например, чтобы проверить, содержат ли ячейки A2:C2 одинаковые значения, формула, чувствительная к регистру, имеет вид:

=AND(EXACT(A2:C2, A2))

В сочетании с IF он принимает такую форму:

=IF(AND(EXACT(A2:C2, A2)), "Да", "Нет")

Проверьте, совпадает ли ячейка с любой ячейкой в диапазоне

Чтобы узнать, совпадает ли ячейка с любой ячейкой в заданном диапазоне, используйте одну из следующих формул:

функция ИЛИ

Его лучше всего использовать для проверки 2 - 3 клеток.

Excel 365 и Excel 2021 также понимают этот синтаксис:

В Excel 2019 и ниже это следует ввести как формулу массива, нажав сочетание клавиш Ctrl + Shift + Enter.

Функция COUNTIF

Например, чтобы проверить, равна ли A2 любой ячейке в B2:D2, подойдет любая из этих формул:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Если вы используете Excel 2019 или ниже, не забудьте нажать Ctrl + Shift + Enter, чтобы вторая формула ИЛИ выдала правильные результаты.

Вернуться Да/Нет или любые другие нужные вам значения, вы знаете, что делать - вложите одну из приведенных выше формул в логический тест функции ЕСЛИ. Например:

=IF(COUNTIF(B2:D2, A2)>0, "Да", "Нет")

Для получения дополнительной информации см. раздел Проверка наличия значения в диапазоне.

Проверьте, равны ли два диапазона

Чтобы сравнить два диапазона по ячейкам и вернуть логическое значение TRUE, если все ячейки в соответствующих позициях совпадают, подставьте одинаковые по размеру диапазоны в логический тест функции AND:

Например, для сравнения матрицы A в B3:F6 и матрицы B в B11:F14, формула имеет вид:

=AND(B3:F6= B11:F14)

Чтобы получить Да / Нет в качестве результата используйте следующую комбинацию IF AND:

=IF(AND(B3:F6=B11:F14), "Да", "Нет")

Вот как использовать формулу If match в Excel. Я благодарю вас за чтение и надеюсь увидеть вас в нашем блоге на следующей неделе!

Практическая тетрадь

Если ячейки совпадают в Excel - примеры формул (файл .xlsx)