سيعلمك البرنامج التعليمي كيفية إنشاء صيغة If match في Excel ، بحيث تُرجع القيم المنطقية أو النص المخصص أو قيمة من خلية أخرى.

صيغة Excel لمشاهدة إذا كانت مطابقة خليتين يمكن أن تكون بسيطة مثل A1 = B1. ومع ذلك ، قد تكون هناك ظروف مختلفة عندما لا يعمل هذا الحل الواضح أو ينتج عنه نتائج مختلفة عما كنت تتوقعه. في هذا البرنامج التعليمي ، سنناقش طرقًا مختلفة لمقارنة الخلايا في Excel ، حتى تتمكن من العثور على الحل الأمثل لمهمتك.

كيفية التحقق من تطابق خليتين في Excel

توجد العديد من الاختلافات في صيغة Excel If Match. ما عليك سوى مراجعة الأمثلة أدناه واختيار أفضل ما يناسب السيناريو الخاص بك.

إذا تساوت خليتان ، فارجع TRUE

الأبسط " إذا كانت إحدى الخلايا تساوي أخرى ، فهذا يعني أنه صحيح" صيغة Excel هي:

الخلية A= الخلية B

على سبيل المثال ، لمقارنة الخلايا في العمودين A و B في كل صف ، يمكنك إدخال هذه الصيغة في C2 ، ثم انسخها أسفل العمود:

=A2=B2

كنتيجة لذلك ، ستحصل على TRUE إذا كانت خليتان متماثلتان ، FALSE وإلا:

ملاحظات:

• ترجع هذه الصيغة قيمتين منطقيتين: إذا تساوت خليتان - TRUE ؛ إن لم يكن يساوي - خطأ. لإرجاع قيم TRUE فقط ، استخدم في عبارة IF كما هو موضح في المثال التالي.
• هذه الصيغة غير حساسة لحالة الأحرف ، لذا فهي تتعامل مع الأحرف الكبيرة والصغيرة على أنها نفس الأحرف. إذا كان النصالحالة مهمة ، ثم استخدم هذه الصيغة الحساسة لحالة الأحرف.

إذا تطابقت خليتان ، فقم بإرجاع القيمة

لإرجاع القيمة الخاصة بك إذا تطابقت خليتان ، قم بإنشاء عبارة IF باستخدام هذا النمط :

IF ( الخلية A = الخلية B ، value_if_true ، value_if_false)

على سبيل المثال ، لمقارنة A2 و B2 وإرجاع "نعم" إذا كانتا تحتويان على نفس القيم ، "لا" بخلاف ذلك ، تكون الصيغة:

=IF(A2=B2, "yes", "no")

إذا كنت تريد إرجاع قيمة فقط إذا كانت الخلايا متساوية ، فقم بتوفير سلسلة فارغة ("") لـ value_if_false .

إذا تطابق ، إذن نعم :

=IF(A2=B2, "yes", "")

إذا تطابق ، إذن TRUE:

=IF(A2=B2, TRUE, "")

ملاحظة. لإرجاع القيمة المنطقية TRUE ، لا تضعها بين علامتي اقتباس. سيؤدي استخدام علامات الاقتباس المزدوجة إلى تحويل القيمة المنطقية إلى سلسلة نصية عادية.

إذا كانت إحدى الخلايا مساوية لأخرى ، فقم بإرجاع خلية أخرى

وهنا تباين من الصيغة Excel إذا تطابق التي تحل هذه المهمة المحددة: قارن القيم في خليتين وإذا كان تطابق البيانات ، ثم انسخ قيمة من خلية أخرى.

في لغة Excel ، تتم صياغتها على النحو التالي:

IF ( الخلية A = الخلية B ، الخلية C ، "")

على سبيل المثال ، للتحقق من العناصر في العمودين A و B وإرجاع قيمة من العمود C إذا تطابق النص ، فإن الصيغة في D2 ، المنسوخة لأسفل ، هي:

=IF(A2=B2, C2, "")

صيغة حساسة لحالة الأحرف لمعرفة ما إذا كانت خليتان متطابقتان

في الحالة التي تتعامل فيها مع قيم نصية حساسة لحالة الأحرف ، استخدم الصيغة EXACTوظيفة لمقارنة الخلايا تمامًا ، بما في ذلك حالة الأحرف:

إذا (بالضبط ( الخلية A ، الخلية B ) ، value_if_true ، value_if_false)

على سبيل المثال ، للمقارنة العناصر الموجودة في A2 و B2 وإرجاع "نعم" إذا تطابق النص تمامًا ، "لا" إذا تم العثور على أي اختلاف ، يمكنك استخدام هذه الصيغة:

=IF(EXACT(A2, B2), "Yes", "No")

كيفية التحقق من وجود عدة خلايا متساوية

كما هو الحال مع مقارنة خليتين ، يمكن أيضًا التحقق من خلايا متعددة للمطابقات بعدة طرق مختلفة.

صيغة AND لمعرفة ما إذا كانت الخلايا المتعددة تتطابق مع

إلى تحقق من تطابق القيم المتعددة ، يمكنك استخدام الدالة AND مع اختبارين منطقيين أو أكثر:

AND ( الخلية A = الخلية B ، الخلية A = الخلية C ،…)

على سبيل المثال ، لمعرفة ما إذا كانت الخلايا A2 و B2 و C2 متساوية ، تكون الصيغة:

=AND(A2=B2, A2=C2)

في المصفوفة الديناميكية Excel (365 و 2021) يمكنك أيضًا استخدام الصيغة أدناه. في Excel 2019 والإصدارات السابقة ، سيعمل هذا فقط كصيغة صفيف CSE تقليدية ، مكتملة بالضغط على مفتاحي Ctrl + Shift + Enter معًا.

=AND(A2=B2:C2)

نتيجة كلا الصيغتين هي القيم المنطقية TRUE و FALSE.

لإرجاع القيم الخاصة بك ، قم بلف AND في دالة IF على النحو التالي:

=IF(AND(A2=B2:C2), "yes", "")

تعرض هذه الصيغة "نعم" إذا كانت الخلايا الثلاث جميعها متساوية ، خلية فارغة خلاف ذلك.

صيغة COUNTIF للتحقق مما إذا كانت الأعمدة المتعددة تتطابق مع

هناك طريقة أخرى للتحقق من التطابقات المتعددة وهي استخدام وظيفة COUNTIF في هذا النموذج:

COUNTIF ( النطاق ، الخلية ) = n

حيث النطاق هو نطاق من الخلايا يمكن مقارنتها ببعضها البعض ، الخلية هي أي خلية مفردة في النطاق ، و n هو عدد الخلايا في النطاق.

بالنسبة لمجموعة البيانات النموذجية الخاصة بنا ، يمكن كتابة الصيغة بهذا النموذج :

=COUNTIF(A2:C2, A2)=3

إذا كنت تقارن عددًا كبيرًا من الأعمدة ، فيمكن لوظيفة COLUMNS الحصول على عدد الخلايا (n) نيابةً عنك تلقائيًا:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

وستساعدك وظيفة IF على إرجاع أي شيء تريده كنتيجة:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

صيغة حساسة لحالة الأحرف لمطابقات متعددة

كما هو الحال مع التحقق من خليتين ، استخدم الدالة EXACT لإجراء المقارنة الدقيقة ، بما في ذلك حالة الأحرف. للتعامل مع خلايا متعددة ، يجب أن يتم دمج EXACT في الدالة AND مثل هذا:

AND (بالضبط ( النطاق ، الخلية ))

في Excel 365 و Excel 2021 بسبب دعم المصفوفات الديناميكية ، يعمل هذا كصيغة عادية. في Excel 2019 والإصدارات الأقل ، تذكر أن تضغط على Ctrl + Shift + Enter لجعلها صيغة مصفوفة .

على سبيل المثال ، للتحقق مما إذا كانت الخلايا A2: C2 تحتوي على نفس القيم ، حالة - الصيغة الحساسة هي:

=AND(EXACT(A2:C2, A2))

بالاقتران مع IF ، تأخذ هذا الشكل:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

تحقق مما إذا كانت الخلية تطابق أي خلية في النطاق

لمعرفة ما إذا كانت الخلية تطابق أي خلية في نطاق معين ، استخدم إحدى الصيغ التالية:

أو وظيفة

من الأفضل استخدامها لفحص 2-3 خلايا.

OR ( الخلية A = الخلية B ، الخلية A = الخلية C ، الخلية A = الخلية D ،…)

يفهم كل من Excel 365 و Excel 2021 بناء الجملة هذا أيضًا:

أو ( الخلية = النطاق )

في Excel 2019 و أقل ، يجب إدخال هذا كصيغة مصفوفة بالضغط على Ctrl + Shift + Enter الاختصار.

وظيفة COUNTIF

COUNTIF ( النطاق ، cell ) & gt؛ 0

على سبيل المثال ، للتحقق مما إذا كانت A2 تساوي أي خلية في B2: D2 ، ستعمل أي من هذه الصيغ:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

إذا كنت تستخدم Excel 2019 أو أقل ، فتذكر الضغط على Ctrl + Shift + Enter للحصول على صيغة OR الثانية لتقديم النتائج الصحيحة.

لإرجاع نعم / لا أو أي قيم أخرى تريدها ، فأنت تعرف ما يجب فعله - قم بتداخل إحدى الصيغ أعلاه في الاختبار المنطقي لوظيفة IF. على سبيل المثال:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

لمزيد من المعلومات ، يرجى الاطلاع على التحقق مما إذا كانت القيمة موجودة في نطاق.

تحقق مما إذا كان النطاقان متساويان

للمقارنة نطاقان خلية بخلية وإرجاع القيمة المنطقية TRUE إذا تطابق جميع الخلايا في المواضع المقابلة ، قم بتوفير نطاقات متساوية الحجم للاختبار المنطقي لوظيفة AND:

AND ( النطاق A = النطاق B )

على سبيل المثال ، لمقارنة المصفوفة A في B3: F6 والمصفوفة B في B11: F14 ، الصيغة هي:

=AND(B3:F6= B11:F14)

إلى الحصول على نعم / لا كنتيجة لذلك ، استخدم تركيبة IF AND التالية:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

هذه هي كيفية استخدام صيغة If matchفي Excel. أشكرك على القراءة وآمل أن أراك على مدونتنا الأسبوع المقبل!

تدرب على المصنف

إذا تطابق الخلايا في Excel - أمثلة على الصيغ (ملف .xlsx)