В урока ще научите как да конструирате формулата If match в Excel, така че тя да връща логически стойности, потребителски текст или стойност от друга клетка.

Формулата на Excel за проверка на съответствието на две клетки може да бъде толкова проста, колкото A1=B1. Възможно е обаче да има различни обстоятелства, при които това очевидно решение няма да работи или ще даде резултати, различни от очакваните. В този урок ще обсъдим различни начини за сравняване на клетки в Excel, за да можете да намерите оптимално решение за вашата задача.

Как да проверите дали две клетки съвпадат в Excel

Съществуват много варианти на формулата If match в Excel. Просто прегледайте примерите по-долу и изберете този, който е най-подходящ за вашия сценарий.

Ако две клетки са равни, връща TRUE

Най-простият " Ако една клетка е равна на друга, тогава true" Формулата на Excel е следната:

Например, за да сравните клетките в колони A и B на всеки ред, въведете тази формула в C2 и след това я копирайте надолу по колоната:

=A2=B2

В резултат ще получите TRUE, ако две клетки са еднакви, и FALSE в противен случай:

Забележки:

• Тази формула връща две булеви стойности: ако две клетки са равни - TRUE (Вярно); ако не са равни - FALSE (Невярно). За да върнете само стойностите TRUE (Вярно), използвайте оператора IF, както е показано в следващия пример.
• Тази формула е без значение на големи и малки букви , така че тя третира главните и малките букви като едни и същи знаци. Ако регистърът на текста е от значение, тогава използвайте тази формула, която е чувствителна към регистъра на буквите.

Ако две клетки съвпадат, връща се стойност

За да върнете собствена стойност, ако две клетки съвпадат, съставете оператор IF, като използвате този модел:

Например, за да сравните A2 и B2 и да върнете "да", ако съдържат еднакви стойности, и "не" в противен случай, формулата е:

=IF(A2=B2, "да", "не")

Ако искате да върнете стойност само ако клетките са равни, въведете празен низ ("") за value_if_false .

Ако има съвпадение, тогава да :

=IF(A2=B2, "yes", "")

Ако има съвпадение, тогава TRUE:

=IF(A2=B2, TRUE, "")

Забележка: За да върнете логическата стойност TRUE, не я ограждайте в двойни кавички. Използването на двойни кавички ще превърне логическата стойност в обикновен текстов низ.

Ако една клетка е равна на друга, върнете друга клетка

А ето и вариант на Excel, ако има съвпадение формула, която решава тази конкретна задача: сравнява стойностите в две клетки и ако данните съвпадат, копира стойност от друга клетка.

На езика на Excel тя е формулирана по следния начин:

Например, за да проверите елементите в колони A и B и да върнете стойност от колона C, ако текстът съвпада, формулата в D2, копирана надолу, е:

=IF(A2=B2, C2, "")

Формула за проверка на съвпадение на две клетки, чувствителна към големи букви

Когато работите с текстови стойности, чувствителни към малки и големи букви, използвайте функцията EXACT, за да сравните клетките точно, включително и буквените падежи:

Например за сравняване на елементите в A2 и B2 и връщане на отговор "да", ако текстът съвпада точно, и "не", ако се открие разлика, можете да използвате тази формула:

=IF(EXACT(A2, B2), "Yes", "No")

Как да проверите дали няколко клетки са равни

Както при сравняването на две клетки, проверката на няколко клетки за съвпадения също може да се извърши по няколко различни начина.

Формула AND, за да видите дали няколко клетки съвпадат

За да проверите дали няколко стойности съвпадат, можете да използвате функцията AND с два или повече логически теста:

Например, за да проверите дали клетките A2, B2 и C2 са равни, формулата е:

=И(A2=B2, A2=C2)

В Excel с динамичен масив (365 и 2021) можете също да използвате синтаксиса по-долу. В Excel 2019 и по-ниски версии това ще работи само като традиционна формула за масив CSE, завършена чрез натискане на клавишите Ctrl + Shift + Enter заедно.

=AND(A2=B2:C2)

Резултатът от двете формули AND са логическите стойности TRUE и FALSE.

За да върнете собствени стойности, обвийте AND във функцията IF по следния начин:

=IF(AND(A2=B2:C2), "yes", "")

Тази формула връща отговор "да", ако и трите клетки са равни, а в противен случай - празна клетка.

Формула COUNTIF за проверка на съвпадение на няколко колони

Друг начин за проверка за множество съвпадения е използването на функцията COUNTIF в този вид:

Къде: обхват е диапазон от клетки, които трябва да бъдат сравнени една с друга, клетка е всяка отделна клетка в обхвата, а n е броят на клетките в обхвата.

За нашата примерна съвкупност от данни формулата може да бъде записана по следния начин:

=COUNTIF(A2:C2, A2)=3

Ако сравнявате много колони, функцията COLUMNS може автоматично да получи броя на клетките (n) за вас:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

А функцията IF ще ви помогне да върнете всичко, което искате, като резултат:

=IF(COUNTIF(A2:C2, A2)=3, "Всички съвпадат", "")

Формула за множествени съвпадения с отчитане на буквите

Както и при проверката на две клетки, използваме функцията EXACT, за да извършим точното сравнение, включително и на буквените падежи. За работа с множество клетки функцията EXACT трябва да се вложи във функцията AND по следния начин:

В Excel 365 и Excel 2021, поради поддръжката на динамични масиви, това работи като нормална формула. В Excel 2019 и по-ниски версии не забравяйте да натиснете Ctrl + Shift + Enter, за да я превърнете в формула за масив .

Например, за да проверите дали клетките A2:C2 съдържат едни и същи стойности, формулата, чувствителна към големи и малки букви, е:

=AND(EXACT(A2:C2, A2))

В комбинация с IF тя придобива следната форма:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Проверка дали клетката съвпада с някоя клетка от обхвата

За да проверите дали дадена клетка съвпада с която и да е клетка в даден диапазон, използвайте една от следните формули:

Функция ИЛИ

Най-добре е да се използва за проверка на 2 - 3 клетки.

Excel 365 и Excel 2021 също разбират този синтаксис:

В Excel 2019 и по-ниски версии това трябва да се въведе като формула за масив, като се натисне клавишната комбинация Ctrl + Shift + Enter.

Функция COUNTIF

Например, за да проверите дали А2 е равна на някоя клетка в B2:D2, е подходяща всяка от тези формули:

=ИЛИ(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Ако използвате Excel 2019 или по-ниска версия, не забравяйте да натиснете Ctrl + Shift + Enter, за да накарате втората формула OR да даде правилните резултати.

Да се върнете Да/Не или други желани стойности, знаете какво да направите - вмъкнете една от горните формули в логическия тест на функцията IF. Например:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

За повече информация вижте Проверка за наличие на стойност в диапазон.

Проверка дали два диапазона са равни

За да сравните два диапазона клетка по клетка и да върнете логическата стойност TRUE, ако всички клетки в съответните позиции съвпадат, подайте еднакво големи диапазони към логическия тест на функцията AND:

Например за сравняване на Матрица A в B3:F6 и Матрица B в B11:F14 формулата е:

=И(B3:F6= B11:F14)

За да получите Да / Не като резултат, използвайте следната комбинация IF AND:

=IF(AND(B3:F6=B11:F14), "Да", "Не")

Това е начинът за използване на формулата If match в Excel. Благодаря ви, че прочетохте, и се надявам да се видим в нашия блог следващата седмица!

Практическа работна тетрадка

Ако клетките съвпадат в Excel - примери за формули (.xlsx файл)