Tutoriali do t'ju mësojë se si të ndërtoni formulën If match në Excel, në mënyrë që të kthejë vlera logjike, tekst të personalizuar ose një vlerë nga një qelizë tjetër.

Një formulë Excel për të parë nëse dy qeliza përputhen mund të jetë aq e thjeshtë sa A1=B1. Megjithatë, mund të ketë rrethana të ndryshme kur kjo zgjidhje e dukshme nuk do të funksionojë ose nuk do të prodhojë rezultate të ndryshme nga ato që prisnit. Në këtë tutorial, ne do të diskutojmë mënyra të ndryshme për të krahasuar qelizat në Excel, në mënyrë që të gjeni një zgjidhje optimale për detyrën tuaj.

Si të kontrolloni nëse dy qeliza përputhen në Excel

Ka shumë variacione të formulës Excel If match. Thjesht rishikoni shembujt e mëposhtëm dhe zgjidhni atë që funksionon më mirë për skenarin tuaj.

Nëse dy qeliza janë të barabarta, kthejeni TRUE

Më e thjeshta " Nëse një qelizë është e barabartë me një tjetër, atëherë e vërtetë" Formula e Excel-it është kjo:

qeliza A= qeliza B

Për shembull, për të krahasuar qelizat në kolonat A dhe B në çdo rresht, futni këtë formulë në C2, dhe më pas kopjojeni atë në kolonën:

=A2=B2

Si rezultat, do të merrni TRUE nëse dy qeliza janë të njëjta, FALSE ndryshe:

Shënime:

• Kjo formulë kthen dy vlera Boolean: nëse dy qeliza janë të barabarta - TRUE; nëse nuk është e barabartë - E FALSE. Për të kthyer vetëm vlerat TRUE, përdorni në deklaratën IF siç tregohet në shembullin vijues.
• Kjo formulë është e pandjeshme ndaj gërmave , kështu që i trajton shkronjat e mëdha dhe të vogla si të njëjtat karaktere. Nëse tekstirasti ka rëndësi, atëherë përdorni këtë formulë të ndjeshme ndaj rastit.

Nëse dy qeliza përputhen, ktheni vlerën

Për të kthyer vlerën tuaj nëse dy qeliza përputhen, ndërtoni një deklaratë IF duke përdorur këtë model :

IF( qeliza A = qeliza B , vlera_if_true, vlera_if_false)

Për shembull, për të krahasuar A2 dhe B2 dhe për të kthyer "po" nëse ato përmbajnë të njëjtat vlera , "jo" ndryshe, formula është:

=IF(A2=B2, "yes", "no")

Nëse dëshironi të ktheni një vlerë vetëm nëse qelizat janë të barabarta, atëherë jepni një varg bosh ("") për value_if_false .

Nëse përputhen, atëherë po :

=IF(A2=B2, "yes", "")

Nëse përputhen, atëherë E VËRTETË:

=IF(A2=B2, TRUE, "")

Shënim. Për të kthyer vlerën logjike TRUE, mos e mbyllni në thonjëza të dyfishta. Përdorimi i thonjëzave të dyfishta do të konvertojë vlerën logjike në një varg teksti të rregullt.

Nëse një qelizë është e barabartë me një tjetër, atëherë kthejeni një qelizë tjetër

Dhe këtu është një variacion i formulës Excel if match që zgjidh këtë detyrë specifike: krahasoni vlerat në dy qeliza dhe nëse të dhënat përputhen, më pas kopjoni një vlerë nga një qelizë tjetër.

Në gjuhën Excel, ajo është formuluar kështu:

IF( qeliza A = qeliza B , qeliza C , "")

Për shembull, për të kontrolluar artikujt në kolonat A dhe B dhe për të kthyer një vlerë nga kolona C nëse teksti përputhet, formula në D2, e kopjuar, është:

=IF(A2=B2, C2, "")

Formula e ndjeshme ndaj shkronjave të vogla për të parë nëse përputhen dy qeliza

Në situatën kur keni të bëni me vlera teksti të ndjeshme ndaj shkronjave, përdorni EXACTfunksioni për të krahasuar saktësisht qelizat, duke përfshirë shkronjat:

IF(EXACT( qeliza A , qeliza B ), value_if_true, value_if_false)

Për shembull, për të krahasuar artikujt në A2 dhe B2 dhe ktheni "po" nëse teksti përputhet saktësisht, "jo" nëse gjendet ndonjë ndryshim, mund të përdorni këtë formulë:

=IF(EXACT(A2, B2), "Yes", "No")

Si të kontrolloni nëse disa qeliza janë të barabarta

Ashtu si me krahasimin e dy qelizave, kontrollimi i shumë qelizave për përputhje mund të bëhet gjithashtu në disa mënyra të ndryshme.

DHE formula për të parë nëse disa qeliza përputhen

Për kontrolloni nëse vlerat e shumta përputhen, mund të përdorni funksionin AND me dy ose më shumë teste logjike:

AND( qeliza A = qeliza B , qeliza A = qeliza C , …)

Për shembull, për të parë nëse qelizat A2, B2 dhe C2 janë të barabarta, formula është:

=AND(A2=B2, A2=C2)

Në grup dinamik Excel (365 dhe 2021) mund të përdorni gjithashtu sintaksën e mëposhtme. Në Excel 2019 dhe më poshtë, kjo do të funksionojë vetëm si një formulë tradicionale e grupit CSE, e përfunduar duke shtypur së bashku tastet Ctrl + Shift + Enter.

=AND(A2=B2:C2)

Rezultati i të dyja formulave AND është vlerat logjike TRUE dhe FALSE.

Për të kthyer vlerat tuaja, mbështillni AND në funksionin IF si kjo:

=IF(AND(A2=B2:C2), "yes", "")

Kjo formulë kthen "po" nëse të tre qelizat janë të barabarta, përndryshe një qelizë bosh.

Formula COUNTIF për të kontrolluar nëse disa kolona përputhen

Një mënyrë tjetër për të kontrolluar për përputhje të shumta është përdorimi i funksionit COUNTIF në këtë formë:

COUNTIF( varg , qeliza )= n

Ku vargu është një varg qelizash që duhet krahasuar me njëra-tjetrën, qeliza është çdo qelizë e vetme në interval dhe n është numri i qelizave në interval.

Për grupin tonë të të dhënave të mostrës, formula mund të shkruhet në këtë formë :

=COUNTIF(A2:C2, A2)=3

Nëse po krahasoni shumë kolona, ​​funksioni COLUMNS mund të marrë automatikisht numrin e qelizave (n) për ju:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

Dhe funksioni IF do t'ju ndihmojë të ktheni gjithçka që dëshironi si rezultat:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

Formulë e ndjeshme ndaj shkronjave të vogla për përputhje të shumta

Ashtu si me kontrollimin e dy qelizave, ne përdorni funksionin EXACT për të kryer krahasimin e saktë, duke përfshirë rastin e shkronjave. Për të trajtuar shumë qeliza, EXACT duhet të futet në funksionin AND si ky:

AND(EXACT( range , qeliza ))

Në Excel 365 dhe Excel 2021 , për shkak të mbështetjes për vargje dinamike, kjo funksionon si një formulë normale. Në Excel 2019 dhe më poshtë, mos harroni të shtypni Ctrl + Shift + Enter për ta bërë atë një formulë grupi .

Për shembull, për të kontrolluar nëse qelizat A2:C2 përmbajnë të njëjtat vlera, një rast -Formula e ndjeshme është:

=AND(EXACT(A2:C2, A2))

Në kombinim me IF, merr këtë formë:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Kontrollo nëse qeliza përputhet me ndonjë qelizë në intervalin

Për të parë nëse një qelizë përputhet me ndonjë qelizë në një diapazon të caktuar, përdorni një nga formulat e mëposhtme:

Funksioni OSE

Është më mirë të përdoret për kontrollimin e 2 - 3 qelizave.

OSE( qeliza A = qeliza B , qeliza A = qeliza C , qeliza A = qeliza D , …)

Excel 365 dhe Excel 2021 e kuptojnë gjithashtu këtë sintaksë:

OSE( qeliza = varg )

Në Excel 2019 dhe më poshtë, kjo duhet të futet si një formulë grupi duke shtypur shkurtoren Ctrl + Shift + Enter.

Funksioni COUNTIF

COUNTIF( range , qeliza )>0

Për shembull, për të kontrolluar nëse A2 është e barabartë me ndonjë qelizë në B2:D2, ndonjë nga këto formula do të bëjë:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Nëse jeni duke përdorur Excel 2019 ose version më të ri, mos harroni të shtypni Ctrl + Shift + Enter për të marrë formulën e dytë OSE për të dhënë rezultatet e sakta.

Për të kthyer Po/Jo ose çdo vlerë tjetër që dëshironi, ju e dini se çfarë të bëni - futni një nga formulat e mësipërme në testin logjik të funksionit IF. Për shembull:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

Për më shumë informacion, ju lutemi shikoni Kontrolloni nëse vlera ekziston në një interval.

Kontrollo nëse dy vargje janë të barabarta

Për të krahasuar dy vargje qelizë për qelizë dhe ktheni vlerën logjike TRUE nëse të gjitha qelizat në pozicionet përkatëse përputhen, jepni vargjet me madhësi të barabartë në testin logjik të funksionit AND:

AND( vargu A = varg B )

Për shembull, për të krahasuar Matricën A në B3:F6 dhe Matricën B në B11:F14, formula është:

=AND(B3:F6= B11:F14)

Për merrni Po / Jo si rezultat, përdorni kombinimin e mëposhtëm IF AND:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

Kjo është mënyra se si të përdorni formulën Nëse përputhetnë Excel. Ju falënderoj që lexoni dhe shpresoj t'ju shohim në blogun tonë javën e ardhshme!

Praktikoni librin e punës

Nëse qelizat përputhen në Excel - shembuj formulash (skedari .xlsx)