La lernilo instruos vin kiel konstrui la formulon Se kongruas en Excel, do ĝi resendas logikajn valorojn, kutiman tekston aŭ valoron el alia ĉelo.

Excel-formulo por vidi se du ĉeloj kongruas povus esti tiel simpla kiel A1=B1. Tamen, povas esti malsamaj cirkonstancoj kiam ĉi tiu evidenta solvo ne funkcios aŭ produktos rezultojn malsamajn ol kion vi atendis. En ĉi tiu lernilo, ni diskutos diversajn manierojn kompari ĉelojn en Excel, por ke vi povu trovi optimuman solvon por via tasko.

Kiel kontroli ĉu du ĉeloj kongruas en Excel

Ekzistas multaj variaĵoj de la Excel Se kongrua formulo. Nur reviziu la ekzemplojn sube kaj elektu tiun, kiu plej bone funkcias por via scenaro.

Se du ĉeloj egalas, redonu VERA

La plej simpla " Se unu ĉelo egalas alian tiam vera" Excel-formulo estas ĉi tiu:

ĉelo A= ĉelo B

Ekzemple, por kompari ĉelojn en kolumnoj A kaj B en ĉiu vico, vi enigu ĉi tiun formulon en C2, kaj tiam kopiu ĝin laŭ la kolumno:

=A2=B2

Kiel rezulto, vi ricevos VERA se du ĉeloj estas samaj, FALSA alie:

Notoj:

• Tiu formulo liveras du Buleajn valorojn: se du ĉeloj estas egalaj - VERA; se ne egala - FALSA. Por nur redoni la VERajn valorojn, uzu en IF deklaro kiel montrita en la sekva ekzemplo.
• Ĉi tiu formulo estas majuskle-malsentema , do ĝi traktas majusklojn kaj minusklojn kiel la samajn signojn. Se la tekstouskleco gravas, tiam uzu ĉi tiun uskle-distintan formulon.

Se du ĉeloj kongruas, redonu valoron

Por redoni vian propran valoron se du ĉeloj kongruas, konstruu IF-astrumon uzante ĉi tiun ŝablonon. :

IF( ĉelo A = ĉelo B , valoro_se_vera, valoro_se_malvera)

Ekzemple, por kompari A2 kaj B2 kaj redoni "jes" se ili enhavas la samajn valorojn , "ne" alie, la formulo estas:

=IF(A2=B2, "yes", "no")

Se vi nur volas redoni valoron se ĉeloj estas egalaj, do liveru malplenan ĉenon ("") por valoro_se_falsa .

Se kongruas, tiam jes :

=IF(A2=B2, "yes", "")

Se kongruas, tiam VERA:

=IF(A2=B2, TRUE, "")

Notu. Por redoni la logikan valoron VERA, ne enmetu ĝin inter citiloj. Uzado de duoblaj citiloj konvertiĝos la logikan valoron en regulan tekstan ĉenon.

Se unu ĉelo egalas alian, do redonu alian ĉelon

Kaj jen variaĵo de la formulo Excel se kongruas , kiu solvas ĉi tiun specifan taskon: komparu la valorojn en du ĉeloj kaj se la datumo kongruas, tiam kopiu valoron el alia ĉelo.

En la lingvo Excel, ĝi estas formulita jene:

IF( ĉelo A = ĉelo B , ĉelo C , "")

Ekzemple, por kontroli la erojn en kolumnoj A kaj B kaj redoni valoron de kolumno C se teksto kongruas, la formulo en D2, kopiita malsupren, estas:

=IF(A2=B2, C2, "")

Majuskkle-distinga formulo por vidi ĉu du ĉeloj kongruas

En situacio, kiam vi traktas majuskle-distintajn tekstajn valorojn, uzu la EKZAKT.funkcio por ĝuste kompari la ĉelojn, inkluzive de la litera majuskla:

IF(EXACT( ĉelo A , ĉelo B ), valoro_se_vera, valoro_se_malvera)

Ekzemple, por kompari la erojn en A2 kaj B2 kaj resendas "jes" se teksto ĝuste kongruas, "ne" se iu diferenco estas trovita, vi povas uzi ĉi tiun formulon:

=IF(EXACT(A2, B2), "Yes", "No")

Kiel kontroli ĉu pluraj ĉeloj estas egalaj

Kiel kun komparo de du ĉeloj, kontroli plurajn ĉelojn por kongruoj ankaŭ povas esti farita en kelkaj malsamaj manieroj.

KAJ formulo por vidi ĉu pluraj ĉeloj kongruas

Al kontrolu ĉu pluraj valoroj kongruas, vi povas uzi la funkcion AND kun du aŭ pli da logikaj testoj:

AND( ĉelo A = ĉelo B , ĉelo A = ĉelo C , …)

Ekzemple, por vidi ĉu ĉeloj A2, B2 kaj C2 estas egalaj, la formulo estas:

=AND(A2=B2, A2=C2)

En dinamika tabelo Excel (365 kaj 2021) vi ankaŭ povas uzi la suban sintakson. En Excel 2019 kaj pli malaltaj, ĉi tio funkcios nur kiel tradicia CSE-tabelformulo, kompletigita per premado de la klavoj Ctrl + Shift + Enigu kune.

=AND(A2=B2:C2)

La rezulto de ambaŭ AND-formuloj estas la logikaj valoroj VERA kaj FALSA.

Por redoni viajn proprajn valorojn, envolvu AND en la funkcio SE tiel:

=IF(AND(A2=B2:C2), "yes", "")

Tiu formulo liveras "jes" se ĉiuj tri ĉeloj. estas egalaj, malplena ĉelo alie.

NOMBRUSE-formulo por kontroli ĉu pluraj kolumnoj kongruas

Alia maniero por kontroli plurajn kongruojn estas uzi la funkcion COUNTIF en ĉi tiu formo:

COUNTIF( intervalo , ĉelo )= n

Kie intervalo estas gamo da ĉeloj komparendaj unu kontraŭ la alia, ĉelo estas ajna ununura ĉelo en la intervalo, kaj n estas la nombro da ĉeloj en la intervalo.

Por nia ekzempla datumaro, la formulo povas esti skribita en ĉi tiu formo. :

=COUNTIF(A2:C2, A2)=3

Se vi komparas multajn kolumnojn, la funkcio KOLUMnoj povas aŭtomate akiri la nombron de la ĉeloj (n) por vi:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

Kaj la IF-funkcio helpos vin redoni ĉion, kion vi volas kiel rezulto:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

Majuskkle-distinga formulo por multoblaj kongruoj

Kiel ĉe kontrolado de du ĉeloj, ni uzu la EKZAKTAN funkcion por plenumi la precizan komparon, inkluzive de la litermajskulo. Por manipuli plurajn ĉelojn, EXACT estas nestota en la AND-funkcion jene:

KAJ (EXACT ( gamo , ĉelo ))

En Excel 365 kaj Excel 2021 , pro subteno por dinamikaj tabeloj, ĉi tio funkcias kiel normala formulo. En Excel 2019 kaj pli malaltaj, memoru premi Ctrl + Shift + Enter por fari ĝin tabelformulo .

Ekzemple, por kontroli ĉu ĉeloj A2:C2 enhavas la samajn valorojn, kazo. -sentema formulo estas:

=AND(EXACT(A2:C2, A2))

En kombinaĵo kun IF, ĝi prenas ĉi tiun formon:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Kontrolu ĉu ĉelo kongruas kun iu ĉelo en intervalo

Por vidi ĉu ĉelo kongruas kun iu ajn ĉelo en difinita intervalo, uzu unu el la jenaj formuloj:

OR-funkcio

Estas plej bone esti uzata. por kontroli 2 - 3 ĉelojn.

AŬ( ĉelo A = ĉelo B , ĉelo A = ĉelo C , ĉelo A = ĉelo D , …)

Excel 365 kaj Excel 2021 ankaŭ komprenas ĉi tiun sintakson:

AŬ ( ĉelo = gamo )

En Excel 2019 kaj malsupre, ĉi tio estu enigita kiel tabelformulo premante la klavkombinon Ctrl + Shift + Enigu.

NOMBRUSE-funkcio

COUNTIF( gamo , ĉelo )>0

Ekzemple, por kontroli ĉu A2 egalas al iu ajn ĉelo en B2:D2, iu el ĉi tiuj formuloj faros:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Se vi uzas Excel 2019 aŭ pli malaltan, memoru premi Ctrl + Shift + Enter por ricevi la duan AŬ formulon por liveri la ĝustajn rezultojn.

Por redoni Jes/Ne aŭ ajnajn aliajn valorojn, kiujn vi volas, vi scias kion fari - nestu unu el la supraj formuloj en la logika testo de la funkcio IF. Ekzemple:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

Por pliaj informoj, bonvolu vidi Kontroli ĉu valoro ekzistas en intervalo.

Kontrolu ĉu du intervaloj estas egalaj

Por kompari du gamoj ĉelo post ĉelo kaj redonu la logikan valoron VERA se ĉiuj ĉeloj en la respondaj pozicioj kongruas, liveru la samgrandajn intervalojn al la logika testo de la AND-funkcio:

AND( gamo A = gamo B )

Ekzemple, por kompari Matrico A en B3:F6 kaj Matrico B en B11:F14, la formulo estas:

=AND(B3:F6= B11:F14)

Al ricevu Jes / Ne kiel rezulton, uzu la jenan SE KAJ kombinaĵon:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

Tiel uzi la If-kongruan formulonen Excel. Mi dankas vin pro legado kaj esperas vidi vin en nia blogo venontsemajne!

Praktiku laborlibron

Se ĉeloj kongruas en Excel - formulekzemploj (.xlsx-dosiero)