Bu eğitimde, mantıksal değerler, özel metin veya başka bir hücreden bir değer döndürmesi için Excel'de Eğer eşleşirse formülünü nasıl oluşturacağınız öğretilecektir.

İki hücrenin eşleşip eşleşmediğini görmek için bir Excel formülü A1=B1 kadar basit olabilir. Ancak, bu bariz çözümün işe yaramayacağı veya beklediğinizden farklı sonuçlar üreteceği farklı durumlar olabilir. Bu eğitimde, Excel'de hücreleri karşılaştırmanın çeşitli yollarını tartışacağız, böylece göreviniz için en uygun çözümü bulabilirsiniz.

Excel'de iki hücrenin eşleşip eşleşmediğini kontrol etme

Excel Eğer eşleşirse formülünün birçok çeşidi vardır. Aşağıdaki örnekleri inceleyin ve senaryonuz için en uygun olanı seçin.

İki hücre eşitse, TRUE döndürür

En basit " Bir hücre diğerine eşitse doğru" Excel formülü şudur:

Örneğin, her satırdaki A ve B sütunlarındaki hücreleri karşılaştırmak için, bu formülü C2'ye girip sütunun aşağısına kopyalarsınız:

=A2=B2

Sonuç olarak, iki hücre aynıysa DOĞRU, aksi takdirde YANLIŞ alırsınız:

Notlar:

• Bu formül iki Boolean değeri döndürür: iki hücre eşitse - DOĞRU; eşit değilse - YANLIŞ. Yalnızca DOĞRU değerlerini döndürmek için, sonraki örnekte gösterildiği gibi EĞER deyimini kullanın.
• Bu formül şöyledir büyük/küçük harf duyarsız bu nedenle büyük ve küçük harfleri aynı karakterler olarak ele alır. Metnin büyük/küçük harf durumu önemliyse, bu büyük/küçük harfe duyarlı formülü kullanın.

İki hücre eşleşirse, dönüş değeri

İki hücre eşleşirse kendi değerinizi döndürmek için, bu kalıbı kullanarak bir EĞER deyimi oluşturun:

Örneğin, A2 ve B2'yi karşılaştırmak ve aynı değerleri içeriyorlarsa "evet", aksi takdirde "hayır" döndürmek için formül şöyledir:

=IF(A2=B2, "evet", "hayır")

Yalnızca hücreler eşitse bir değer döndürmek istiyorsanız, boş bir dize ("") girin. value_if_false .

Eşleşirse, o zaman Evet. :

=IF(A2=B2, "evet", "")

Eşleşirse, DOĞRU olur:

=IF(A2=B2, TRUE, "")

Not: Mantıksal değeri TRUE olarak döndürmek için çift tırnak içine almayın. Çift tırnak kullanmak mantıksal değeri normal bir metin dizesine dönüştürecektir.

Bir hücre diğerine eşitse, başka bir hücre döndürür

Ve işte bir varyasyon Eşleşirse Excel Bu özel görevi çözen formül: iki hücredeki değerleri karşılaştırın ve veriler eşleşiyorsa, başka bir hücreden bir değer kopyalayın.

Excel dilinde şu şekilde formüle edilir:

Örneğin, A ve B sütunlarındaki öğeleri kontrol etmek ve metin eşleşirse C sütunundan bir değer döndürmek için D2'deki formül aşağı kopyalanır:

=IF(A2=B2, C2, "")

İki hücrenin eşleşip eşleşmediğini görmek için büyük/küçük harfe duyarlı formül

Büyük/küçük harfe duyarlı metin değerleriyle uğraştığınız durumlarda, harf büyük/küçük harfleri de dahil olmak üzere hücreleri tam olarak karşılaştırmak için EXACT işlevini kullanın:

Örneğin, A2 ve B2'deki öğeleri karşılaştırmak ve metin tam olarak eşleşirse "evet", herhangi bir fark bulunursa "hayır" döndürmek için bu formülü kullanabilirsiniz:

=IF(EXACT(A2, B2), "Evet", "Hayır")

Birden çok hücrenin eşit olup olmadığını kontrol etme

İki hücrenin karşılaştırılmasında olduğu gibi, eşleşmeler için birden fazla hücrenin kontrol edilmesi de birkaç farklı şekilde yapılabilir.

Birden çok hücrenin eşleşip eşleşmediğini görmek için AND formülü

Birden fazla değerin eşleşip eşleşmediğini kontrol etmek için AND işlevini iki veya daha fazla mantıksal testle birlikte kullanabilirsiniz:

Örneğin, A2, B2 ve C2 hücrelerinin eşit olup olmadığını görmek için formül şöyledir:

=VE(A2=B2, A2=C2)

Dinamik dizi Excel'de (365 ve 2021) aşağıdaki sözdizimini de kullanabilirsiniz. Excel 2019 ve daha düşük sürümlerde, bu yalnızca Ctrl + Shift + Enter tuşlarına birlikte basılarak tamamlanan geleneksel bir CSE dizi formülü olarak çalışacaktır.

=AND(A2=B2:C2)

Her iki AND formülünün sonucu TRUE ve FALSE mantıksal değerleridir.

Kendi değerlerinizi döndürmek için, AND öğesini IF işlevine şu şekilde sarın:

=IF(AND(A2=B2:C2), "yes", "")

Bu formül, üç hücre de eşitse "evet", aksi halde boş bir hücre döndürür.

Birden çok sütunun eşleşip eşleşmediğini kontrol etmek için COUNTIF formülü

Birden fazla eşleşme olup olmadığını kontrol etmenin bir başka yolu da bu formdaki COUNTIF fonksiyonunu kullanmaktır:

Nerede aralık birbiriyle karşılaştırılacak bir hücre aralığıdır, hücre aralıktaki herhangi bir tek hücre ve n aralıktaki hücre sayısıdır.

Örnek veri setimiz için formül şu şekilde yazılabilir:

=COUNTIF(A2:C2, A2)=3

Çok sayıda sütunu karşılaştırıyorsanız, COLUMNS işlevi sizin için hücrelerin sayısını (n) otomatik olarak alabilir:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

Ve IF fonksiyonu, sonuç olarak istediğiniz herhangi bir şeyi döndürmenize yardımcı olacaktır:

=IF(COUNTIF(A2:C2, A2)=3, "Tümü eşleşiyor", "")

Birden fazla eşleşme için büyük/küçük harfe duyarlı formül

İki hücreyi kontrol ederken olduğu gibi, harf durumu da dahil olmak üzere tam karşılaştırma yapmak için EXACT işlevini kullanırız. Birden fazla hücreyi işlemek için EXACT, AND işlevinin içine şu şekilde yerleştirilmelidir:

Excel 365 ve Excel 2021'de, dinamik diziler için destek nedeniyle, bu normal bir formül olarak çalışır. Excel 2019 ve daha düşük sürümlerde, bunu bir formül haline getirmek için Ctrl + Shift + Enter tuşlarına basmayı unutmayın dizi formülü .

Örneğin, A2:C2 hücrelerinin aynı değerleri içerip içermediğini denetlemek için büyük/küçük harfe duyarlı formül şudur:

=VE(EXACT(A2:C2, A2))

IF ile birlikte bu şekli alır:

=IF(AND(EXACT(A2:C2, A2)), "Evet", "Hayır")

Hücrenin aralıktaki herhangi bir hücreyle eşleşip eşleşmediğini kontrol edin

Bir hücrenin belirli bir aralıktaki herhangi bir hücreyle eşleşip eşleşmediğini görmek için aşağıdaki formüllerden birini kullanın:

VEYA işlevi

En iyisi 2 - 3 hücreyi kontrol etmek için kullanılmalıdır.

Excel 365 ve Excel 2021 bu sözdizimini de anlar:

Excel 2019 ve daha düşük sürümlerde bu, Ctrl + Shift + Enter kısayoluna basılarak bir dizi formülü olarak girilmelidir.

COUNTIF işlevi

Örneğin, A2'nin B2:D2'deki herhangi bir hücreye eşit olup olmadığını kontrol etmek için bu formüllerden herhangi biri kullanılabilir:

=VEYA(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Excel 2019 veya daha düşük bir sürümünü kullanıyorsanız, ikinci VEYA formülünün doğru sonuçları vermesini sağlamak için Ctrl + Shift + Enter tuşlarına basmayı unutmayın.

Geri dönmek için Evet/Hayır veya istediğiniz başka değerler varsa, ne yapacağınızı biliyorsunuz - yukarıdaki formüllerden birini IF fonksiyonunun mantıksal testine yerleştirin. Örneğin:

=IF(COUNTIF(B2:D2, A2)>0, "Evet", "Hayır")

Daha fazla bilgi için lütfen Değerin bir aralıkta olup olmadığını kontrol et bölümüne bakın.

İki aralığın eşit olup olmadığını kontrol edin

İki aralığı hücre hücre karşılaştırmak ve karşılık gelen konumlardaki tüm hücreler eşleşirse DOĞRU mantıksal değerini döndürmek için, AND işlevinin mantıksal sınamasına eşit büyüklükteki aralıkları sağlayın:

Örneğin, B3:F6'daki Matris A ile B11:F14'teki Matris B'yi karşılaştırmak için formül şöyledir:

=VE(B3:F6= B11:F14)

Almak için Evet / Hayır sonuç olarak, aşağıdaki EĞER VE kombinasyonunu kullanın:

=IF(AND(B3:F6=B11:F14), "Evet", "Hayır")

Excel'de If match formülü bu şekilde kullanılır. Okuduğunuz için teşekkür eder, gelecek hafta blogumuzda görüşmek dileğiyle!

Alıştırma çalışma kitabı

Excel'de hücreler eşleşirse - formül örnekleri (.xlsx dosyası)