Сравнение столбцов в Excel - это то, что мы все делаем время от времени. Microsoft Excel предлагает ряд возможностей для сравнения и сопоставления данных, но большинство из них сосредоточены на поиске в одном столбце. В этом учебнике мы рассмотрим несколько методов, чтобы сравнить два столбца в Excel и найти совпадения и различия между ними.

Как сравнить 2 столбца в Excel строка за строкой

При анализе данных в Excel одной из наиболее частых задач является сравнение данных в каждой отдельной строке. Эту задачу можно решить с помощью функции IF, как показано в следующих примерах.

Пример 1. Сравните два столбца на предмет совпадений или различий в одной строке

Чтобы сравнить два столбца в Excel строка за строкой, напишите обычную формулу IF, которая сравнивает первые две ячейки. Введите формулу в другой столбец той же строки, а затем скопируйте ее в другие ячейки, перетащив ручку заполнения (маленький квадратик в правом нижнем углу выделенной ячейки). При этом курсор меняется на знак плюс:

Формула для спичек

Чтобы найти ячейки в одном ряду с одинаковым содержимым, A2 и B2 в данном примере, формула выглядит следующим образом:

=IF(A2=B2,"Match","")

Формула различий

Чтобы найти ячейки в одной строке с разными значениями, просто замените знак равенства на знак неравенства ():

=IF(A2B2, "Нет совпадений","")

Совпадения и различия

И, конечно, ничто не мешает вам найти и совпадения, и различия с помощью одной формулы:

=IF(A2=B2, "Совпадает", "Не совпадает")

Или

=IF(A2B2, "Не совпадает", "Совпадает")

Результат может выглядеть примерно так:

Как вы видите, формула обрабатывает номера , даты , раз и текстовые строки одинаково хорошо.

Совет. Вы также можете сравнивать два столбца ряд за рядом с помощью расширенного фильтра Excel. Вот пример, показывающий, как отфильтровать совпадения и различия между двумя столбцами.

Пример 2. Сравнение двух списков для совпадений с учетом регистра в одной строке

Как вы, вероятно, заметили, формулы из предыдущего примера игнорируют регистр при сравнении текстовых значений, как в строке 10 на скриншоте выше. Если вы хотите найти соответствия с учетом регистра между двумя столбцами в каждой строке, то используйте функцию EXACT:

=IF(EXACT(A2, B2), "Match", "")

Чтобы найти различия с учетом регистра в той же строке введите соответствующий текст ("Unique" в данном примере) в 3-й аргумент функции IF, например:

=IF(EXACT(A2, B2), "Совпадает", "Уникальный")

Сравните несколько столбцов на предмет совпадений в одной строке

В рабочих листах Excel можно сравнивать несколько столбцов на основе следующих критериев:

• Найдите строки с одинаковыми значениями в все колонки (Пример 1)
• Найдите строки с одинаковыми значениями в любые 2 колонки (Пример 2)

Пример 1. Найти совпадения во всех ячейках одной строки

Если в вашей таблице три или более столбцов, и вы хотите найти строки, которые имеют одинаковые значения во всех ячейках, формула IF с оператором AND будет работать на ура:

=IF(AND(A2=B2, A2=C2), "Полное совпадение", "")

Если в вашей таблице много столбцов, более элегантным решением будет использование функции COUNTIF:

=IF(COUNTIF($A2:$E2, $A2)=5, "Полное совпадение", "")

Где 5 - количество столбцов, которые вы сравниваете.

Пример 2. Найдите совпадения в любых двух ячейках одного ряда

Если вы ищете способ сравнить столбцы для любые две или более ячеек с одинаковыми значениями в одной строке, используйте формулу IF с оператором OR:

=IF(OR(A2=B2, B2=C2, A2=C2), "Match", "")

В случае, если нужно сравнить много столбцов, оператор OR может вырасти слишком большим. В этом случае лучшим решением будет сложение нескольких функций COUNTIF. Первый COUNTIF подсчитывает, сколько столбцов имеют то же значение, что и в 1-м столбце, второй COUNTIF подсчитывает, сколько оставшихся столбцов равны 2-му столбцу, и т.д. Если счет равен 0, формула возвращает "Уникально","Соответствие" в противном случае. Например:

=IF(COUNTIF(B2:D2,A2)+COUNTIF(C2:D2,B2)+(C2=D2)=0, "Уникальный", "Соответствие")

Как сравнить два столбца в Excel на предмет совпадений и различий

Предположим, у вас есть 2 списка данных в Excel, и вы хотите найти все значения (числа, даты или текстовые строки), которые находятся в столбце A, но не находятся в столбце B.

Для этого можно встроить функцию COUNTIF($B:$B, $A2)=0 в логический тест IF и проверить, возвращает ли она ноль (совпадение не найдено) или любое другое число (найдено хотя бы 1 совпадение).

Например, следующая формула IF/COUNTIF ищет по всему столбцу B значение в ячейке A2. Если совпадение не найдено, формула возвращает "No match in B", в противном случае - пустую строку:

=IF(COUNTIF($B:$B, $A2)=0, "Нет совпадения в B", "")

Совет. Если ваша таблица имеет фиксированное количество строк, вы можете указать определенный диапазон (например, $B2:$B10), а не весь столбец ($B:$B), чтобы формула работала быстрее на больших наборах данных.

Того же результата можно добиться, используя формулу IF со встроенными функциями ISERROR и MATCH:

=IF(ISERROR(MATCH($A2,$B$2:$B$10,0)), "Нет совпадения в B","")

Или с помощью следующей формулы массива (не забудьте нажать Ctrl + Shift + Enter, чтобы ввести ее правильно):

=IF(SUM(--($B$2:$B$10=$A2))=0, " Нет совпадений в B", "")

Если вы хотите, чтобы одна формула определяла как совпадения (дубликаты), так и различия (уникальные значения), поместите текст для совпадений в пустые двойные кавычки ("") в любой из приведенных выше формул. Например:

=IF(COUNTIF($B:$B, $A2)=0, "Нет совпадения в B", "Совпадение в B")

Как сравнить два списка в Excel и получить совпадения

Иногда вам может понадобиться не только сопоставить два столбца в двух разных таблицах, но и извлечь совпадающие записи из таблицы поиска. Microsoft Excel предоставляет для этого специальную функцию - функцию VLOOKUP. В качестве альтернативы вы можете использовать более мощную и универсальную формулу INDEX MATCH. Пользователи Excel 2021 и Excel 365, могут решить эту задачу с помощью функции XLOOKUP.

Например, следующие формулы сравнивают названия продуктов в столбце D с названиями в столбце A и извлекают соответствующий показатель продаж из столбца B, если найдено совпадение, в противном случае возвращается ошибка #N/A.

=VLOOKUP(D2, $A$2:$B$6, 2, FALSE)

=INDEX($B$2:$B$6, MATCH($D2, $A$2:$A$6, 0))

=XLOOKUP(D2, $A$2:$A$6, $B$2:$B$6)

Для получения дополнительной информации см. раздел Как сравнить два столбца с помощью VLOOKUP.

Если вам не очень удобно работать с формулами, вы можете выполнить эту работу с помощью быстрого и интуитивно понятного решения - Мастера слияния таблиц.

Сравните два списка и выделите совпадения и различия

Когда вы сравниваете столбцы в Excel, вы можете захотеть "визуализировать" элементы, которые присутствуют в одном столбце, но отсутствуют в другом. Вы можете заштриховать такие ячейки любым цветом по вашему выбору, используя функцию Excel Conditional Formatting, и следующие примеры демонстрируют подробные шаги.

Пример 1. Выделите совпадения и различия в каждой строке

Чтобы сравнить два столбца и Excel и выделить ячейки в столбце A, которые имеют одинаковые записи в столбце B в той же строке, выполните следующие действия:

• Выберите ячейки, которые нужно выделить (можно выделить ячейки в одном столбце или в нескольких столбцах, если нужно выделить цветом целые строки).
• Нажмите Условное форматирование> Новое правило.> Используйте формулу, чтобы определить, какие ячейки форматировать .
• Создайте правило с простой формулой, например =$B2=$A2 (предполагается, что строка 2 - это первая строка с данными, не включая заголовок столбца). Пожалуйста, дважды проверьте, что вы используете относительную ссылку на строку (без знака $), как в формуле выше.

Чтобы выделить различия между столбцами A и B, создайте правило с такой формулой:

=$B2$A2

Если вы новичок в условном форматировании Excel, ознакомьтесь с пошаговыми инструкциями в разделе Как создать правило условного форматирования на основе формулы.

Пример 2. Выделение уникальных записей в каждом списке

Когда вы сравниваете два списка в Excel, есть 3 типа элементов, которые вы можете выделить:

• Элементы, которые есть только в 1-м списке (уникальные)
• Элементы, которые есть только во 2-м списке (уникальные)
• Элементы, находящиеся в обоих списках (дубликаты) - продемонстрировано в следующем примере.

В этом примере показано, как выделить цветом элементы, которые находятся только в одном списке.

Предположим, что список 1 находится в столбце A (A2:A6), а список 2 - в столбце C (C2:C5). Вы создаете правила условного форматирования с помощью следующих формул:

Выделите уникальные значения в Списке 1 (столбец A):

=COUNTIF($C$2:$C$5, $A2)=0

Выделите уникальные значения в Списке 2 (столбец C):

=COUNTIF($A$2:$A$6, $C2)=0

И получите следующий результат:

Пример 3. Выделение совпадений (дубликатов) между 2 колонками

Если вы внимательно следили за предыдущим примером, вам не составит труда настроить формулы COUNTIF так, чтобы они находили совпадения, а не различия. Все, что вам нужно сделать, это установить счетчик больше нуля:

Выделите совпадения в Списке 1 (колонка А):

=COUNTIF($C$2:$C$5, $A2)>0

Выделите совпадения в Списке 2 (колонка С):

=COUNTIF($A$2:$A$6, $C2)>0

Выделите различия в строках и совпадения в нескольких столбцах

При сравнении значений в нескольких столбцах подряд, самый быстрый способ выделить совпадения - это создать правило условного форматирования, а самый быстрый способ оттенить различия - это использовать Перейти к специальному как показано в следующих примерах.

Пример 1. Сравнение нескольких столбцов и выделение совпадений строк

Чтобы выделить строки, в которых одинаковые значения во всех колонках создайте правило условного форматирования на основе одной из следующих формул:

=AND($A2=$B2, $A2=$C2)

или

=COUNTIF($A2:$C2, $A2)=3

Где A2, B2 и C2 - самые верхние ячейки, а 3 - количество столбцов для сравнения.

Конечно, ни формула AND, ни COUNTIF не ограничиваются сравнением только 3 столбцов, вы можете использовать аналогичные формулы для выделения строк с одинаковыми значениями в 4, 5, 6 и более столбцах.

Пример 2. Сравнение нескольких столбцов и выделение различий в строках

Чтобы быстро выделить ячейки с разными значениями в каждой отдельной строке, можно использовать функцию Excel Перейти к специальному особенность.

1. Выберите диапазон ячеек, которые вы хотите сравнить. В этом примере я выбрал ячейки с A2 по C8.

   По умолчанию самая верхняя ячейка выбранного диапазона является активной ячейкой, и ячейки из других выбранных столбцов в той же строке будут сравниваться с этой ячейкой. Как видно на скриншоте выше, активная ячейка имеет белый цвет, в то время как все остальные ячейки выбранного диапазона выделены. В данном примере активной ячейкой является A2, поэтому сравнительная колонка является столбец A.

   Смотрите также: Слияние 2 листов Google и обновление данных на основе общих записей

   На изменить колонку сравнения Используйте либо клавишу Tab для перемещения по выделенным ячейкам слева направо, либо клавишу Enter для перемещения сверху вниз.

   Совет. Чтобы выбрать несмежные колонки выберите первый столбец, нажмите и удерживайте Ctrl, а затем выберите остальные столбцы. Активная ячейка будет находиться в последнем столбце (или в последнем блоке соседних столбцов). Чтобы изменить столбец сравнения, используйте клавишу Tab или Enter, как описано выше.

2. На Главная перейдите на вкладку Редактирование группу, и нажмите кнопку Найти и выбрать > Перейти к специальному... Затем выберите Различия в рядах и нажмите кнопку OK кнопка.
3. Ячейки, значения которых отличаются от ячейки сравнения в каждом ряду, окрашиваются. Если вы хотите оттенить выделенные ячейки каким-либо цветом, просто нажмите на кнопку Цвет заливки значок на ленте и выберите нужный цвет.

Как сравнить две ячейки в Excel

Фактически, сравнение двух ячеек - это частный случай сравнения двух столбцов в Excel по строкам, за исключением того, что вам не нужно копировать формулы в другие ячейки столбца.

Например, для сравнения ячеек A1 и C1 можно использовать следующие формулы.

Для матчей:

=IF(A1=C1, "Match", "")

Для различий:

=IF(A1C1, "Разница", "")

Чтобы узнать несколько других способов сравнения ячеек в Excel, см:

• Как сравнить две строки в Excel
• Проверьте, совпадают ли две ячейки или равны ли несколько ячеек

Способ сравнения двух столбцов/списков в Excel без формул

Теперь, когда вы знаете, что Excel предлагает для сравнения и сопоставления столбцов, позвольте мне показать вам наше собственное решение для этой задачи. Этот инструмент называется Compare Two Tables и входит в наш Ultimate Suite.

Надстройка может сравнивать две таблицы или списки по любому количеству столбцов и как определять совпадения/различия (как мы это делали с помощью формул), так и выделять их (как мы это делали с помощью условного форматирования).

В рамках данной статьи мы будем сравнивать два следующих списка, чтобы найти общие значения, которые присутствуют в обоих.

Чтобы сравнить два списка, необходимо выполнить следующие действия:

1. Начните с нажатия кнопки Сравнить таблицы кнопка на Ablebits Data вкладка.
2. Выберите первый столбец/список и нажмите Следующий Что касается дополнения, то это ваша таблица 1.
3. Выберите второй колонка/список и нажмите Следующий Что касается надстройки, то это ваша Таблица 2, и она может находиться на том же или другом рабочем листе или даже в другой рабочей книге.
4. Выберите, какие данные искать:
   • Дубликат значения (совпадения) - элементы, которые есть в обоих списках.
   • Уникальный значения (различия) - элементы, которые присутствуют в списке 1, но отсутствуют в списке 2.

   Поскольку наша цель - найти совпадения, мы выбираем первый вариант и нажимаем кнопку Следующий .

5. Это ключевой шаг, на котором вы выбираете столбцы для сравнения В нашем случае выбор очевиден, поскольку мы сравниваем только 2 столбца: Победители 2000 года против Победители 2021 года В больших таблицах можно выбрать несколько пар столбцов для сравнения.
6. На последнем этапе вы выбираете, как поступить с найденными элементами, и нажимаете кнопку Отделка .

   Здесь доступно несколько различных вариантов. Для наших целей наиболее полезны эти два:

   • Выделите цветом - оттенки совпадений или различий в выбранном цвете (как это делает условное форматирование Excel).
   • Определите в колонке Статус - вставляет Статус столбец с метками "Дубликат" или "Уникальный" (как это делают формулы IF).

Для данного примера я решил выделить дубликаты следующим цветом:

И через мгновение получил следующий результат:

С Статус столбца, результат будет выглядеть следующим образом:

Совет. Если сравниваемые списки находятся в разных рабочих листах или рабочих книгах, может быть полезно просмотреть листы Excel рядом друг с другом.

Именно так вы сравниваете столбцы в Excel на предмет совпадений (дубликатов) и различий (уникальных значений). Если вам интересно попробовать этот инструмент, вы можете загрузить ознакомительную версию по ссылке ниже.

Я благодарю вас за прочтение и рекомендую ознакомиться с другими полезными руководствами, которые у нас есть :)

Доступные загрузки

Сравнение списков Excel - примеры (файл.xlsx)

Ultimate Suite - пробная версия (файл .exe)