Упатството ќе ве научи како да ја конструирате формулата If match во Excel, така што враќа логички вредности, приспособен текст или вредност од друга ќелија.

Формула на Excel за да ја видите ако две ќелии се совпаѓаат може да биде едноставно како A1=B1. Сепак, може да има различни околности кога ова очигледно решение нема да работи или да даде резултати различни од она што го очекувавте. Во ова упатство, ќе разговараме за различни начини за споредување ќелии во Excel, за да можете да најдете оптимално решение за вашата задача.

Како да проверите дали две ќелии се совпаѓаат во Excel

Постојат многу варијации на формулата Excel If match. Само прегледајте ги примерите подолу и изберете го оној кој најдобро функционира за вашето сценарио.

Ако две ќелии се еднакви, вратете TRUE

Наједноставниот „ Ако една ќелија е еднаква на друга, тогаш точно“ Формулата на Excel е ова:

ќелија А= клетка Б

На пример, за да ги споредите ќелиите во колоните А и Б во секој ред, ја внесувате оваа формула во C2, а потоа копирајте ја во колоната:

=A2=B2

Како резултат, ќе добиете ТОЧНО ако две ќелии се исти, НЕТОЧНО во спротивно:

Забелешки:

• Оваа формула враќа две Булови вредности: ако две ќелии се еднакви - ТОЧНО; ако не е еднакво - НЕТОЧНО. За да ги вратите само ВИСТИНСКИТЕ вредности, користете го во изјавата IF како што е прикажано во следниот пример.
• Оваа формула е неосетлива на букви , така што ги третира големите и малите букви како исти знаци. Доколку текстотслучајот е важен, тогаш користете ја оваа формула чувствителна на големи букви.

Ако две ќелии се совпаѓаат, вратете ја вредноста

За да ја вратите сопствената вредност ако две ќелии се совпаѓаат, конструирајте изјава IF користејќи ја оваа шема :

IF( ќелија A = ќелија B , value_if_true, value_if_false)

На пример, да се споредат A2 и B2 и да се врати „да“ ако ги содржат истите вредности , "не" во спротивно, формулата е:

=IF(A2=B2, "yes", "no")

Ако сакате да вратите вредност само ако ќелиите се еднакви, тогаш внесете празна низа ("") за value_if_false .

Ако се совпаѓаат, тогаш да :

=IF(A2=B2, "yes", "")

Ако се совпаѓаат, тогаш ТОЧНО:

=IF(A2=B2, TRUE, "")

Забелешка. За да ја вратите логичката вредност ВИСТИНА, не ставајте ја во двојни наводници. Користењето двојни наводници ќе ја претвори логичката вредност во обична текстуална низа.

Ако една ќелија е еднаква на друга, тогаш вратете друга ќелија

И еве варијација на формулата Excel if match што ја решава оваа специфична задача: споредете ги вредностите во две ќелии и ако податоците се совпаѓаат, а потоа копирајте вредност од друга ќелија.

Во јазикот на Excel, таа е формулирана вака:

IF( ќелија A = ќелија B , ќелија C , "")

На пример, за проверка на ставките во колоните A и B и враќање на вредност од колоната C ако текстот се совпаѓа, формулата во D2, копирана надолу, е:

=IF(A2=B2, C2, "")

Формула чувствителна на големи букви за да видите дали две ќелии се совпаѓаат

Во ситуација кога имате работа со вредности на текст чувствителни на големи букви, користете ја EXACTфункција за точно споредување на ќелиите, вклучувајќи ја и буквата буква:

IF(EXACT( клетка A , ќелија B ), value_if_true, value_if_false)

На пример, за споредба ставките во A2 и B2 и вратете „да“ ако текстот точно се совпаѓа, „не“ ако се најде некоја разлика, можете да ја користите оваа формула:

=IF(EXACT(A2, B2), "Yes", "No")

Како да проверите дали повеќе ќелии се еднакви

Како и со споредувањето на две ќелии, проверката на повеќе ќелии за совпаѓање може да се направи и на неколку различни начини.

И формула за да се види дали повеќе ќелии се совпаѓаат

Да проверете дали се совпаѓаат повеќе вредности, можете да ја користите функцијата И со два или повеќе логички тестови:

AND( ќелија A = ќелија B , ќелија А = ќелија C , …)

На пример, за да се види дали ќелиите A2, B2 и C2 се еднакви, формулата е:

=AND(A2=B2, A2=C2)

Во динамичка низа Excel (365 и 2021) можете да ја користите и синтаксата подолу. Во Excel 2019 и пониски, ова ќе работи само како традиционална формула за низа CSE, завршена со притискање на копчињата Ctrl + Shift + Enter заедно.

=AND(A2=B2:C2)

Резултатот од двете формули И е логички вредности TRUE и FALSE.

За да ги вратите вашите сопствени вредности, завиткајте AND во функцијата IF вака:

=IF(AND(A2=B2:C2), "yes", "")

Оваа формула враќа „да“ ако сите три ќелии се еднакви, инаку празна ќелија.

COUNTIF формула за проверка дали повеќе колони се совпаѓаат

Друг начин за проверка за повеќе совпаѓања е користење на функцијата COUNTIF во оваа форма:

COUNTIF( опсег , ќелија )= n

Каде што опсег е опсег на ќелии што треба да се споредат една со друга, ќелија е која било единечна ќелија во опсегот, а n е бројот на ќелии во опсегот.

За нашата база на податоци за примерок, формулата може да биде напишана во оваа форма :

=COUNTIF(A2:C2, A2)=3

Ако споредувате многу колони, функцијата COLUMNS може автоматски да го добие бројот на ќелиите (n):

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

И функцијата IF ќе ви помогне да вратите сè што сакате како резултат:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

Формула чувствителна на големи букви за повеќекратни совпаѓања

Како и при проверка на две ќелии, ние употребете ја функцијата EXACT за да ја извршите точната споредба, вклучително и буквите. За ракување со повеќе ќелии, EXACT треба да се вгнезди во функцијата AND вака:

AND(EXACT( опсег , ќелија ))

Во Excel 365 и Excel 2021 , поради поддршката за динамички низи, ова функционира како нормална формула. Во Excel 2019 и пониски, не заборавајте да притиснете Ctrl + Shift + Enter за да ја направите формула за низа .

На пример, за да проверите дали ќелиите A2:C2 ги содржат истите вредности, букви -чувствителна формула е:

=AND(EXACT(A2:C2, A2))

Во комбинација со IF, ја добива оваа форма:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Проверете дали ќелијата се совпаѓа со која било ќелија во опсегот

За да видите дали ќелијата се совпаѓа со која било ќелија во даден опсег, користете една од следните формули:

ИЛИ функција

Најдобро е да се користи за проверка на 2 - 3 ќелии.

ИЛИ( клетка А = клетка Б , клетка А = клетка C , клетка А = ќелија D , …)

Excel 365 и Excel 2021 ја разбираат и оваа синтакса:

OR( ќелија = опсег )

Во Excel 2019 и пониско, ова треба да се внесе како формула за низа со притискање на кратенката Ctrl + Shift + Enter.

COUNTIF функција

COUNTIF( опсег , cell )>0

На пример, за да проверите дали A2 е еднаква на која било ќелија во B2:D2, која било од овие формули ќе направи:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Ако користите Excel 2019 или понова верзија, не заборавајте да притиснете Ctrl + Shift + Enter за да ја добиете втората формула ИЛИ за да ги дадете точните резултати.

За да вратите Да/Не или кои било други вредности што ги сакате, знаете што да направите - вгнездувајте една од горенаведените формули во логичкиот тест на функцијата IF. На пример:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

За повеќе информации, погледнете Проверете дали вредноста постои во опсегот.

Проверете дали два опсези се еднакви

За споредба два опсези ќелија по ќелија и вратете ја логичката вредност TRUE ако сите ќелии во соодветните позиции се совпаѓаат, доставете ги опсезите со еднаква големина на логичкиот тест на функцијата AND:

AND( опсег A = опсег B )

На пример, за споредба на матрицата А во B3:F6 и матрицата Б во B11:F14, формулата е:

=AND(B3:F6= B11:F14)

Да добие Да / Не како резултат, користете ја следнава комбинација АКО И:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

Така да ја користите формулата Ако одговараво Excel. Ви благодарам што прочитавте и се надевам дека ќе се видиме на нашиот блог следната недела!

Вежбајте работна книга

Ако ќелиите се совпаѓаат во Excel - примери на формула (датотека .xlsx)