एक्सेलमध्ये इफ मॅच फॉर्म्युला कसा तयार करायचा हे ट्युटोरियल तुम्हाला शिकवेल, त्यामुळे ते तार्किक मूल्ये, कस्टम मजकूर किंवा दुसर्‍या सेलमधील मूल्य मिळवते.

पहाण्यासाठी एक एक्सेल सूत्र जर दोन पेशी जुळतील तर A1=B1 इतके सोपे असेल. तथापि, अशी भिन्न परिस्थिती असू शकते जेव्हा हे स्पष्ट समाधान कार्य करणार नाही किंवा आपल्या अपेक्षेपेक्षा भिन्न परिणाम देईल. या ट्युटोरियलमध्ये, आम्ही एक्सेलमधील सेलची तुलना करण्याच्या विविध मार्गांवर चर्चा करू, जेणेकरून तुम्ही तुमच्या कार्यासाठी इष्टतम उपाय शोधू शकाल.

एक्सेलमध्ये दोन सेल जुळतात का ते कसे तपासायचे

एक्सेल इफ मॅच फॉर्म्युलामध्ये अनेक भिन्नता आहेत. फक्त खालील उदाहरणांचे पुनरावलोकन करा आणि तुमच्या परिस्थितीसाठी सर्वोत्तम कार्य करणारे एक निवडा.

दोन सेल समान असल्यास, TRUE परत करा

सर्वात सोपा " जर एक सेल दुसऱ्या सेलच्या बरोबरीचा असेल तर सत्य" एक्सेल फॉर्म्युला असा आहे:

सेल A= सेल B

उदाहरणार्थ, प्रत्येक ओळीतील कॉलम A आणि B मधील सेलची तुलना करण्यासाठी, तुम्ही हे सूत्र एंटर करा. C2, आणि नंतर कॉलम खाली कॉपी करा:

=A2=B2

परिणामी, दोन सेल समान असल्यास तुम्हाला TRUE मिळेल, अन्यथा FALSE:

नोट्स:

• हे सूत्र दोन बुलियन मूल्ये मिळवते: जर दोन सेल समान असतील - TRUE; समान नसल्यास - FALSE. फक्त सत्य मूल्ये परत करण्यासाठी, पुढील उदाहरणात दर्शविल्याप्रमाणे IF स्टेटमेंटमध्ये वापरा.
• हे सूत्र केस-असंवेदनशील आहे, त्यामुळे ते अपरकेस आणि लोअरकेस अक्षरे समान वर्ण मानते. जर मजकूरकेस महत्त्वाचे आहेत, नंतर हे केस-संवेदनशील सूत्र वापरा.

दोन सेल जुळत असल्यास, मूल्य परत करा

दोन सेल जुळल्यास तुमचे स्वतःचे मूल्य परत करण्यासाठी, हा नमुना वापरून IF विधान तयार करा :

IF( सेल A = सेल B , value_if_true, value_if_false)

उदाहरणार्थ, A2 आणि B2 ची तुलना करण्यासाठी आणि समान मूल्ये असल्यास "होय" परत करा , "नाही" अन्यथा, सूत्र आहे:

=IF(A2=B2, "yes", "no")

तुम्हाला केवळ सेल समान असल्यास मूल्य परत करायचे असल्यास, value_if_false साठी रिक्त स्ट्रिंग ("") द्या. .

जुळत असल्यास, होय :

=IF(A2=B2, "yes", "")

जुळल्यास, बरोबर:

=IF(A2=B2, TRUE, "") <18

टीप. तार्किक मूल्य TRUE परत करण्यासाठी, ते दुहेरी अवतरणांमध्ये संलग्न करू नका. दुहेरी अवतरण वापरल्याने तार्किक मूल्य नियमित मजकूर स्ट्रिंगमध्ये रूपांतरित होईल.

जर एक सेल दुसऱ्या सेलच्या बरोबरीचा असेल, तर दुसरा सेल परत करा

आणि येथे एक्सेल इफ मॅच सूत्राचा एक फरक आहे जो हे विशिष्ट कार्य सोडवतो: दोन सेलमधील मूल्यांची तुलना करा आणि जर डेटा जुळतो, नंतर दुसर्‍या सेलमधून मूल्य कॉपी करा.

एक्सेल भाषेत, हे असे तयार केले जाते:

IF( सेल A = सेल B , सेल C , "")

उदाहरणार्थ, स्तंभ A आणि B मधील आयटम तपासण्यासाठी आणि मजकूर जुळल्यास स्तंभ C मधून मूल्य परत करण्यासाठी, D2 मधील सूत्र, कॉपी डाउन, आहे:<3

=IF(A2=B2, C2, "")

दोन पेशी जुळतात की नाही हे पाहण्यासाठी केस-सेन्सिटिव्ह फॉर्म्युला

जेव्हा तुम्ही केस-सेन्सिटिव्ह मजकूर मूल्ये हाताळत असाल त्या परिस्थितीत, अचूक वापरालेटर केससह सेलची अचूक तुलना करण्यासाठी फंक्शन:

IF(EXACT( cell A , cell B ), value_if_true, value_if_false)

उदाहरणार्थ, तुलना करणे A2 आणि B2 मधील आयटम आणि मजकूर तंतोतंत जुळत असल्यास "होय" परत करा, काही फरक आढळल्यास "नाही", तुम्ही हे सूत्र वापरू शकता:

=IF(EXACT(A2, B2), "Yes", "No")

एकाधिक सेल आहेत हे कसे तपासायचे समान आहेत

दोन सेलची तुलना करण्याप्रमाणे, जुळण्यांसाठी अनेक सेल तपासणे देखील काही वेगळ्या प्रकारे केले जाऊ शकते.

आणि अनेक सेल जुळतात का हे पाहण्यासाठी सूत्र

एकाधिक मूल्ये जुळतात का ते तपासा, तुम्ही दोन किंवा अधिक तार्किक चाचण्यांसह AND फंक्शन वापरू शकता:

AND( सेल A = सेल B , सेल A = सेल C , …)

उदाहरणार्थ, सेल A2, B2 आणि C2 समान आहेत का हे पाहण्यासाठी, सूत्र आहे:

=AND(A2=B2, A2=C2)

डायनॅमिक अॅरेमध्ये Excel (365 आणि 2021) तुम्ही खालील वाक्यरचना देखील वापरू शकता. एक्सेल 2019 आणि त्याखालील मध्ये, हे फक्त पारंपारिक CSE अॅरे फॉर्म्युला म्हणून काम करेल, Ctrl + Shift + Enter की एकत्र दाबून पूर्ण केले जाईल.

=AND(A2=B2:C2)

दोन्ही आणि सूत्रांचा परिणाम आहे तार्किक मूल्ये TRUE आणि FALSE.

तुमची स्वतःची मूल्ये परत करण्यासाठी, AND ला IF फंक्शनमध्ये याप्रमाणे गुंडाळा:

=IF(AND(A2=B2:C2), "yes", "")

हे सूत्र तीनही सेल असल्यास "होय" मिळवते. समान आहेत, अन्यथा रिक्त सेल.

एकाधिक स्तंभ जुळतात का हे तपासण्यासाठी COUNTIF सूत्र

एकाधिक जुळण्या तपासण्याचा दुसरा मार्ग म्हणजे या फॉर्ममध्ये COUNTIF फंक्शन वापरणे:

COUNTIF( श्रेणी , सेल )= n

जेथे श्रेणी ही सेलची श्रेणी एकमेकांशी तुलना करायची आहे, सेल हा रेंजमधील कोणताही एकल सेल आहे आणि n ही श्रेणीतील सेलची संख्या आहे.

आमच्या नमुना डेटासेटसाठी, सूत्र या फॉर्ममध्ये लिहिले जाऊ शकते. :

=COUNTIF(A2:C2, A2)=3

तुम्ही अनेक स्तंभांची तुलना करत असल्यास, COLUMNS फंक्शन तुमच्यासाठी सेलची संख्या (n) आपोआप मिळवू शकते:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

आणि IF फंक्शन तुम्हाला परिणाम म्हणून हवी असलेली कोणतीही गोष्ट परत करण्यात मदत करेल:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

एकाधिक जुळण्यांसाठी केस-संवेदनशील सूत्र

दोन सेल तपासण्याप्रमाणे, आम्ही अक्षर केससह अचूक तुलना करण्यासाठी EXACT फंक्शन वापरा. एकाधिक सेल हाताळण्यासाठी, EXACT हे AND फंक्शनमध्ये याप्रमाणे नेस्ट केले पाहिजे:

AND(EXACT( range , cell ))

Excel 365 आणि Excel 2021 मध्ये , डायनॅमिक अॅरेच्या समर्थनामुळे, हे सामान्य सूत्र म्हणून कार्य करते. Excel 2019 आणि खालच्या मध्ये, Ctrl + Shift + Enter दाबून ते अॅरे फॉर्म्युला बनवायचे लक्षात ठेवा.

उदाहरणार्थ, सेल A2:C2 मध्ये समान मूल्ये आहेत की नाही हे तपासण्यासाठी, केस -संवेदनशील सूत्र आहे:

=AND(EXACT(A2:C2, A2))

IF च्या संयोजनात, तो हा आकार घेतो:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

सेल श्रेणीतील कोणत्याही सेलशी जुळतो का ते तपासा

एखादा सेल दिलेल्या श्रेणीतील कोणत्याही सेलशी जुळतो की नाही हे पाहण्यासाठी, खालीलपैकी एक सूत्र वापरा:

किंवा फंक्शन

वापरणे सर्वोत्तम आहे 2 - 3 सेल तपासण्यासाठी.

किंवा( सेल A = सेल B , सेल A = सेल C , सेल A = सेल D , …)

Excel 365 आणि Excel 2021 हे वाक्यरचना देखील समजतात:

OR( cell = श्रेणी )

Excel 2019 मध्ये आणि लोअर, हे Ctrl + Shift + Enter शॉर्टकट दाबून अॅरे फॉर्म्युला म्हणून प्रविष्ट केले जावे.

COUNTIF फंक्शन

COUNTIF( श्रेणी , सेल )>0

उदाहरणार्थ, A2 हे B2:D2 मधील कोणत्याही सेलच्या बरोबरीचे आहे की नाही हे तपासण्यासाठी, यापैकी कोणतेही सूत्र हे करेल:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

तुम्ही Excel 2019 किंवा त्यापेक्षा कमी वापरत असल्यास, योग्य परिणाम देण्यासाठी दुसरा किंवा फॉर्म्युला मिळविण्यासाठी Ctrl + Shift + Enter दाबण्याचे लक्षात ठेवा.

होय/नाही किंवा तुम्हाला हवी असलेली कोणतीही मूल्ये परत करण्यासाठी, तुम्हाला काय करावे हे माहित आहे - IF फंक्शनच्या तार्किक चाचणीमध्ये वरील सूत्रांपैकी एक नेस्ट करा. उदाहरणार्थ:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

अधिक माहितीसाठी, कृपया श्रेणीमध्ये मूल्य अस्तित्वात आहे का ते तपासा.

दोन श्रेणी समान आहेत का ते तपासा

तुलना करण्यासाठी सेल-दर-सेल दोन श्रेणी आणि तार्किक मूल्य परत करा TRUE जर संबंधित पोझिशन्समधील सर्व सेल जुळत असतील तर, AND फंक्शनच्या लॉजिकल चाचणीसाठी समान आकाराच्या श्रेणी पुरवा:

AND( श्रेणी A = श्रेणी B )

उदाहरणार्थ, B3:F6 मधील मॅट्रिक्स A आणि B11:F14 मधील मॅट्रिक्स B ची तुलना करण्यासाठी, सूत्र आहे:

=AND(B3:F6= B11:F14)

ते परिणाम म्हणून होय / नाही मिळवा, खालील IF आणि संयोजन वापरा:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

अशा प्रकारे If match फॉर्म्युला वापरायचाएक्सेल मध्ये. वाचल्याबद्दल मी तुमचा आभारी आहे आणि पुढच्या आठवड्यात तुम्हाला आमच्या ब्लॉगवर भेटण्याची आशा आहे!

सराव वर्कबुक

सेल्स एक्सेलमध्ये जुळत असल्यास - सूत्र उदाहरणे (.xlsx फाइल)