Tutorial bakal ngajarkeun anjeun kumaha carana ngawangun rumus If match dina Excel, ku kituna mulangkeun nilai logis, téks khusus atanapi nilai tina sél sanés.

Rumus Excel kanggo ningali lamun dua sél cocog bisa jadi sasederhana A1 = B1. Nanging, tiasa waé aya kaayaan anu béda nalika solusi anu jelas ieu moal jalan atanapi ngahasilkeun hasil anu béda ti anu anjeun ngarepkeun. Dina tutorial ieu, urang bakal ngabahas sagala rupa cara pikeun ngabandingkeun sél dina Excel, sangkan anjeun bisa manggihan solusi optimal pikeun tugas anjeun.

Kumaha mariksa lamun dua sél cocog dina Excel

Aya seueur variasi rumus Excel If match. Tinjau ngan conto di handap tur pilih salah sahiji anu pangalusna cocog pikeun skenario anjeun.

Mun dua sél sarua, balikkeun BENER

Paling basajan " Lamun hiji sél sarua jeung nu sejen, bener" Rumus Excel kieu:

sél A= sél B

Contona, pikeun ngabandingkeun sél dina kolom A jeung B dina unggal baris, anjeun ngasupkeun rumus ieu dina C2, teras salin ka handap kolom:

=A2=B2

Hasilna, anjeun bakal nampi BENER upami dua sél sami, SALAH upami henteu:

Catetan:

• Rumus ieu ngabalikeun dua nilai Boolean: lamun dua sél sarua - BENER; lamun teu sarua - PALSU. Pikeun ngan ukur mulangkeun nilai TRUE, paké dina pernyataan IF sapertos anu dipidangkeun dina conto salajengna.
• Rumus ieu henteu sensitip hurup , janten nganggap hurup ageung sareng hurup leutik salaku karakter anu sami. Lamun tékshal hal, teras nganggo rumus case-sénsitip ieu.

Mun dua sél cocog, balikkeun nilai

Pikeun mulangkeun nilai sorangan lamun dua sél cocog, jieun pernyataan IF ngagunakeun pola ieu :

IF( sél A = sél B , value_if_true, value_if_false)

Contona, pikeun ngabandingkeun A2 jeung B2 sarta balikkeun "enya" lamun ngandung nilai anu sarua. , "henteu", rumusna nyaéta:

=IF(A2=B2, "yes", "no")

Upami anjeun ngan ukur hoyong ngabalikeun nilai upami sél sami, teras pasang string kosong ("") kanggo value_if_false .

Lamun cocog, mangka enya :

=IF(A2=B2, "yes", "")

Mun cocok, mangka BENER:

=IF(A2=B2, TRUE, "")

Catetan. Pikeun mulangkeun nilai logis BENER, ulah ngalampirkeun dina tanda petik ganda. Ngagunakeun tanda petik ganda bakal ngarobah nilai logis kana string téks biasa.

Lamun hiji sél sarua jeung sél séjén, balikkeun sél séjén

Jeung ieu variasi rumus Excel lamun cocok nu ngajawab tugas husus ieu: ngabandingkeun nilai dina dua sél jeung lamun data cocog, teras salin nilai ti sél séjén.

Dina basa Excel, éta dirumuskeun saperti kieu:

IF( sél A = sél B , sél C , "")

Contona, pikeun mariksa item dina kolom A jeung B sarta mulangkeun nilai tina kolom C lamun téks cocog, rumus dina D2, disalin ka handap, nyaéta:

=IF(A2=B2, C2, "")

Rumus sénsitip hurup pikeun ningali naha dua sél cocog

Dina kaayaan nalika anjeun nyanghareupan niléy téks sénsitip leutik, paké EXACTfungsina pikeun ngabandingkeun sél persis, kaasup kasus hurup:

IF(EXACT( sél A , sél B ), value_if_true, value_if_false)

Contona, pikeun ngabandingkeun item dina A2 jeung B2 sarta balikkeun "enya" lamun téks cocog persis, "henteu" lamun aya bédana kapanggih, Anjeun bisa make rumus ieu:

=IF(EXACT(A2, B2), "Yes", "No")

Kumaha mariksa lamun sababaraha sél sarua

Sapertos ngabandingkeun dua sél, mariksa sababaraha sél pikeun patandingan ogé tiasa dilakukeun ku sababaraha cara.

Jeung rumus pikeun ningali naha sababaraha sél cocog

Ka pariksa naha sababaraha nilai cocog, anjeun tiasa nganggo fungsi AND sareng dua atanapi langkung tes logis:

AND( sél A = sél B , sél A = sél C ,…)

Contona, pikeun ningali naha sél A2, B2 sareng C2 sami, rumusna nyaéta:

=AND(A2=B2, A2=C2)

Dina array dinamis Excel (365 sareng 2021) anjeun ogé tiasa nganggo sintaksis di handap ieu. Dina Excel 2019 sareng anu langkung handap, ieu ngan ukur tiasa dianggo salaku rumus susunan CSE tradisional, réngsé ku mencét Ctrl + Shift + Enter babarengan.

=AND(A2=B2:C2)

Hasil tina duanana rumus AND nyaéta nilai logis BENER jeung SALAH.

Pikeun mulangkeun nilai sorangan, bungkus AND dina fungsi IF saperti kieu:

=IF(AND(A2=B2:C2), "yes", "")

Rumus ieu ngabalikeun "enya" lamun tilu sél sarua, sél kosong disebutkeun.

Rumus COUNTIF pikeun mariksa naha sababaraha kolom cocog

Cara séjén pikeun mariksa sababaraha patandingan nyaéta ngagunakeun fungsi COUNTIF dina formulir ieu:

COUNTIF( rentang , sél )= n

Dimana rentang mangrupa rentang sél nu kudu dibandingkeun, sél nyaéta sél tunggal dina rentang, sarta n nyaéta jumlah sél dina rentang.

Pikeun set data sampel urang, rumus bisa ditulis dina formulir ieu. :

=COUNTIF(A2:C2, A2)=3

Upami anjeun ngabandingkeun seueur kolom, fungsi COLUMNS tiasa nampi jumlah sél (n) pikeun anjeun sacara otomatis:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

Jeung pungsi IF bakal mantuan Anjeun mulangkeun naon wae nu Anjeun hoyongkeun salaku hasilna:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

Rumus case-sensitive pikeun sababaraha patandingan

Salaku mariksa dua sél, urang ngagunakeun fungsi EXACT pikeun ngalakukeun perbandingan pasti, kalebet kasus hurup. Pikeun nanganan sababaraha sél, EXACT kedah disarangkeun kana fungsi AND sapertos kieu:

AND(EXACT( rentang , cell ))

Dina Excel 365 sareng Excel 2021 , alatan rojongan pikeun arrays dinamis, ieu jalan salaku rumus normal. Dina Excel 2019 sareng handap, émut pencét Ctrl + Shift + Enter supados janten rumus array .

Contona, pikeun mariksa naha sél A2:C2 ngandung nilai anu sami, hiji kasus. -rumus sénsitip nyaéta:

=AND(EXACT(A2:C2, A2))

Dina kombinasi sareng IF, bentukna kieu:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Parios upami sél cocog sareng sél mana waé dina rentang

Pikeun ningali naha sél cocog sareng sél mana waé dina rentang anu ditangtukeun, paké salah sahiji rumus ieu:

OR fungsi

Hadé pisan upami dianggo pikeun mariksa 2 - 3 sél.

ATAWA( sél A = sél B , sél A = sél C , sél A = sél D ,…)

Excel 365 sareng Excel 2021 ogé ngartos sintaksis ieu:

ATAWA( sel = rentang )

Dina Excel 2019 sareng handap, ieu kudu diasupkeun salaku rumus Asép Sunandar Sunarya ku mencét potong kompas Ctrl + Shift + Enter.

fungsi COUNTIF

COUNTIF( rentang , cell )>0

Misalna, pikeun mariksa naha A2 sarua jeung sél mana wae dina B2:D2, salah sahiji rumus ieu bakal ngalakukeun:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Upami anjeun nganggo Excel 2019 atanapi langkung handap, émut pencét Ctrl + Shift + Enter pikeun kéngingkeun rumus ATAWA kadua pikeun nganteurkeun hasil anu leres.

Pikeun mulangkeun Leres/Henteu atanapi nilai-nilai sanés anu anjeun pikahoyong, anjeun terang naon anu kedah dilakukeun - pasangkeun salah sahiji rumus di luhur dina uji logis tina fungsi IF. Contona:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

Pikeun inpormasi salengkepna, mangga tingali Parios upami aya nilai dina rentang.

Parios upami dua rentang sami

Pikeun ngabandingkeun dua rentang sél-demi-sél jeung mulangkeun nilai logis BENER lamun sakabeh sél dina posisi pakait cocog, nyadiakeun rentang ukuran sarua keur test logis fungsi AND:

AND( rentang A = rentang B )

Contona, pikeun ngabandingkeun Matrix A dina B3:F6 sareng Matrix B dina B11:F14, rumusna nyaéta:

=AND(B3:F6= B11:F14)

Ka Kéngingkeun Leres / Henteu salaku hasilna, paké kombinasi IF AND di handap ieu:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

Éta cara ngagunakeun rumus pertandingan Upamidina Excel. Hatur nuhun pikeun maca sareng ngarepkeun anjeun tiasa ningali anjeun dina blog urang minggu payun!

Buku kerja latihan

Upami sél cocog dina Excel - conto rumus (file .xlsx)