W tutorialu dowiesz się, jak skonstruować formułę If match w Excelu, dzięki czemu zwraca ona wartości logiczne, tekst własny lub wartość z innej komórki.

Formuła w Excelu sprawdzająca, czy dwie komórki pasują do siebie, może być tak prosta jak A1=B1. Mogą jednak wystąpić różne okoliczności, w których to oczywiste rozwiązanie nie zadziała lub da wyniki inne niż oczekiwane. W tym samouczku omówimy różne sposoby porównywania komórek w Excelu, dzięki czemu będziesz mógł znaleźć optymalne rozwiązanie dla swojego zadania.

Jak sprawdzić, czy dwie komórki pasują do siebie w programie Excel

Istnieje wiele odmian formuły Excel Jeśli dopasowanie. Wystarczy przejrzeć poniższe przykłady i wybrać ten, który najlepiej sprawdzi się w Twoim scenariuszu.

Jeśli dwie komórki są równe, zwróć TRUE

Najprostsze " Jeśli jedna komórka jest równa drugiej to prawda" Formuła Excela jest taka:

Na przykład, aby porównać komórki w kolumnach A i B w każdym wierszu, wprowadzasz tę formułę w C2, a następnie kopiujesz ją w dół kolumny:

=A2=B2

W rezultacie otrzymasz TRUE, jeśli dwie komórki są takie same, FALSE w przeciwnym razie:

Uwagi:

• Formuła ta zwraca dwie wartości logiczne: jeśli dwie komórki są równe - TRUE; jeśli nie są równe - FALSE. Aby zwrócić tylko wartości TRUE, należy użyć instrukcji IF, jak pokazano w następnym przykładzie.
• Wzór ten to. bez rozróżniania wielkości liter Jeśli wielkość liter w tekście ma znaczenie, to należy użyć tej formuły z uwzględnieniem wielkości liter.

Jeśli dwie komórki pasują do siebie, zwróć wartość

Aby zwrócić własną wartość, jeśli dwie komórki pasują do siebie, skonstruuj instrukcję JEŻELI używając tego wzoru:

Na przykład, aby porównać A2 i B2 i zwrócić "tak", jeśli zawierają te same wartości, "nie" w przeciwnym razie, formuła jest:

=IF(A2=B2, "tak", "nie")

Jeśli chcesz zwrócić wartość tylko wtedy, gdy komórki są równe, podaj pusty łańcuch ("") dla wartość_jeśli_false .

Jeśli pasują, to tak :

=IF(A2=B2, "tak", "")

Jeśli pasuje, to TRUE:

=IF(A2=B2, TRUE, "")

Uwaga. Aby zwrócić wartość logiczną TRUE, nie należy jej ujmować w podwójne cudzysłowy. Użycie podwójnych cudzysłowów spowoduje przekształcenie wartości logicznej w zwykły łańcuch tekstowy.

Jeśli jedna komórka jest równa innej, to zwróć inną komórkę

A oto wariacja na temat Excel jeśli pasuje formuła, która rozwiązuje to konkretne zadanie: porównać wartości w dwóch komórkach i jeśli dane się zgadzają, to skopiować wartość z innej komórki.

W języku Excela formułuje się to tak:

Na przykład, aby sprawdzić elementy w kolumnach A i B i zwrócić wartość z kolumny C, jeśli tekst pasuje, formuła w D2, skopiowana w dół, to:

=IF(A2=B2, C2, "")

Formuła rozróżniająca wielkość liter, aby sprawdzić czy dwie komórki pasują do siebie

W sytuacji, gdy mamy do czynienia z wartościami tekstowymi uwzględniającymi wielkość liter, należy użyć funkcji EXACT, aby porównać komórki dokładnie, z uwzględnieniem wielkości liter:

Na przykład, aby porównać elementy w A2 i B2 i zwrócić "tak", jeśli tekst pasuje dokładnie, "nie", jeśli zostanie znaleziona jakakolwiek różnica, możesz użyć tej formuły:

=IF(EXACT(A2, B2), "Yes", "No")

Jak sprawdzić, czy wiele komórek jest równych

Podobnie jak w przypadku porównywania dwóch komórek, sprawdzanie wielu komórek pod kątem dopasowania również można przeprowadzić na kilka różnych sposobów.

Formuła AND sprawdzająca zgodność wielu komórek

Aby sprawdzić, czy wiele wartości pasuje, możesz użyć funkcji AND z dwoma lub więcej testami logicznymi:

Na przykład, aby sprawdzić, czy komórki A2, B2 i C2 są równe, formuła to:

=AND(A2=B2, A2=C2)

W dynamicznych tablicach Excel (365 i 2021) możesz również użyć poniższej składni. W Excelu 2019 i niższych będzie to działać tylko jako tradycyjna formuła tablicowa CSE, uzupełniona przez naciśnięcie klawiszy Ctrl + Shift + Enter razem.

=AND(A2=B2:C2)

Wynikiem obu formuł AND są wartości logiczne TRUE i FALSE.

Aby zwrócić własne wartości, zawiń AND w funkcję IF w taki sposób:

=IF(AND(A2=B2:C2), "tak", "")

Ta formuła zwraca "tak", jeśli wszystkie trzy komórki są równe, pusta komórka w przeciwnym razie.

Formuła COUNTIF sprawdzająca zgodność wielu kolumn

Innym sposobem na sprawdzenie wielokrotnych dopasowań jest użycie funkcji COUNTIF w tej postaci:

Gdzie zakres to zakres komórek, które mają być ze sobą porównywane, komórka jest dowolną pojedynczą komórką w zakresie, a n jest liczbą komórek w zakresie.

Dla naszego przykładowego zbioru danych wzór ten można zapisać w takiej postaci:

=COUNTIF(A2:C2, A2)=3

Jeśli porównujesz wiele kolumn, funkcja KOLUMNY może uzyskać dla ciebie liczbę komórek (n) automatycznie:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

A funkcja IF pomoże ci zwrócić cokolwiek chcesz jako wynik:

=IF(COUNTIF(A2:C2, A2)=3, "Wszystko pasuje", "")

Formuła rozróżniająca wielkość liter dla wielokrotnych dopasowań

Podobnie jak w przypadku sprawdzania dwóch komórek, stosujemy funkcję EXACT, aby wykonać dokładne porównanie, z uwzględnieniem wielkości liter. Aby obsłużyć wiele komórek, EXACT należy zagnieździć w funkcji AND w następujący sposób:

W Excelu 365 i Excelu 2021, ze względu na obsługę tablic dynamicznych, działa to jak zwykła formuła. W Excelu 2019 i niższych pamiętaj, aby nacisnąć Ctrl + Shift + Enter, aby była to formuła formuła macierzowa .

Na przykład, aby sprawdzić, czy komórki A2:C2 zawierają te same wartości, formuła rozróżniająca wielkość liter to:

=AND(EXACT(A2:C2, A2))

W połączeniu z IF przyjmuje taki kształt:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

Sprawdź, czy komórka pasuje do dowolnej komórki z zakresu

Aby sprawdzić, czy dana komórka pasuje do dowolnej komórki z danego zakresu, należy użyć jednej z poniższych formuł:

Funkcja OR

Najlepiej używać go do sprawdzania 2 - 3 komórek.

Excel 365 i Excel 2021 rozumieją również tę składnię:

W Excelu 2019 i niższych należy to wprowadzić jako formułę tablicową, naciskając skrót Ctrl + Shift + Enter.

Funkcja COUNTIF

Na przykład, aby sprawdzić, czy A2 jest równe dowolnej komórce w B2:D2, każda z tych formuł zrobi:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Jeśli używasz programu Excel 2019 lub niższego, pamiętaj, aby nacisnąć Ctrl + Shift + Enter, aby druga formuła OR dostarczyła prawidłowych wyników.

Aby powrócić Tak/Nie lub dowolne inne wartości, które chcesz, wiesz co zrobić - zagnieździć jedną z powyższych formuł w teście logicznym funkcji JEŻELI. Na przykład:

=IF(COUNTIF(B2:D2, A2)>0, "Tak", "Nie")

Więcej informacji można znaleźć w części Sprawdź, czy wartość istnieje w zakresie.

Sprawdź, czy dwa zakresy są równe

Aby porównać dwa zakresy komórka po komórce i zwrócić wartość logiczną TRUE, jeśli wszystkie komórki w odpowiednich pozycjach pasują do siebie, należy dostarczyć jednakowej wielkości zakresy do testu logicznego funkcji AND:

Na przykład, aby porównać macierz A w B3:F6 i macierz B w B11:F14, wzór to:

=AND(B3:F6= B11:F14)

Aby uzyskać Tak / Nie jako wynik, użyj następującej kombinacji IF AND:

=IF(AND(B3:F6=B11:F14), "Tak", "Nie")

Oto jak używać formuły If match w Excelu. Dziękuję za przeczytanie i mam nadzieję, że zobaczymy się na naszym blogu za tydzień!

Zeszyt ćwiczeń

Jeśli komórki pasują do siebie w Excelu - przykłady formuł (plik .xlsx)