Урок навчить вас, як побудувати формулу "Если совпадает" в Excel так, щоб вона повертала логічні значення, користувацький текст або значення з іншої комірки.

Формула Excel для перевірки відповідності двох клітинок може бути такою ж простою, як A1=B1. Однак можуть бути різні обставини, коли це очевидне рішення не спрацює або дасть результат, відмінний від очікуваного. У цьому уроці ми розглянемо різні способи порівняння клітинок в Excel, щоб ви могли знайти оптимальне рішення для вашої задачі.

Як перевірити, чи співпадають дві комірки в Excel

Існує багато варіацій формули "Якщо" в Excel. Просто перегляньте наведені нижче приклади та виберіть той, який найкраще підходить для вашого сценарію.

Якщо дві комірки рівні, повернути TRUE

Найпростіший " Якщо одна комірка дорівнює іншій, то true" Формула Excel така:

Наприклад, щоб порівняти клітинки в стовпчиках А і В в кожному рядку, ви вводите цю формулу в комірку С2, а потім копіюєте її вниз по стовпчику:

=A2=B2

В результаті Ви отримаєте TRUE, якщо дві клітинки збігаються, і FALSE в іншому випадку:

Нотатки:

• Ця формула повертає два логічних значення: якщо дві комірки рівні - TRUE; якщо не рівні - FALSE. Щоб повернути тільки значення TRUE, використовуйте в операторі IF, як показано в наступному прикладі.
• Ця формула має вигляд нечутливий до регістру Таким чином, вона розглядає великі та малі літери як однакові символи. Якщо регістр тексту має значення, то використовуйте цю формулу з урахуванням регістру.

Якщо дві комірки співпадають, повернути значення

Щоб повернути власне значення, якщо дві комірки збігаються, побудуйте оператор IF, використовуючи цей шаблон:

Наприклад, порівняти А2 і В2 і повернути "так", якщо вони містять однакові значення, "ні" в іншому випадку, формула така:

=IF(A2=B2, "так", "ні")

Якщо потрібно повернути значення тільки якщо комірки рівні, то вкажіть порожній рядок ("") для value_if_false .

Якщо збігаються, то так :

=IF(A2=B2, "yes", "")

Якщо збігається, то TRUE:

=IF(A2=B2, TRUE, "")

Примітка: Щоб повернути логічне значення TRUE, не беріть його в подвійні лапки. Використання подвійних лапок перетворить логічне значення в звичайний текстовий рядок.

Якщо одна комірка дорівнює іншій, то повернути іншу комірку

А ось варіація на тему Excel, якщо збіг формула, яка вирішує цю конкретну задачу: порівняти значення в двох комірках і якщо дані збігаються, то скопіювати значення з іншої комірки.

Мовою Excel це формулюється так:

Наприклад, для перевірки елементів у стовпчиках A і B і повернення значення зі стовпчика C, якщо текст збігається, використовується формула в D2, скопійована вниз:

=IF(A2=B2, C2, "")

Формула з урахуванням регістру для перевірки збігу двох комірок

У ситуації, коли ви маєте справу з текстовими значеннями, чутливими до регістру, використовуйте функцію ТОЧНО для точного порівняння комірок, включаючи регістр літер:

Наприклад, щоб порівняти елементи в А2 і В2 і повернути "так", якщо текст повністю збігається, і "ні", якщо знайдена будь-яка різниця, можна використовувати цю формулу:

=IF(EXACT(A2, B2), "Так", "Ні")

Як перевірити рівність декількох комірок

Як і при порівнянні двох клітинок, перевірка декількох клітинок на наявність збігів також може бути виконана кількома різними способами.

І формула, щоб побачити, чи збігаються кілька клітинок

Для перевірки збігу декількох значень можна використовувати функцію AND з двома або більше логічними перевірками:

Наприклад, щоб перевірити, чи рівні комірки A2, B2 і C2, використовується формула:

=AND(A2=B2, A2=C2)

У динамічних масивах Excel (365 і 2021) ви також можете використовувати наведений нижче синтаксис. В Excel 2019 і нижче це буде працювати тільки як традиційна формула масиву CSE, що заповнюється натисканням клавіш Ctrl + Shift + Enter разом.

=AND(A2=B2:C2)

Результатом обох формул І є логічні значення ІСТИНА та ХИБНІСТЬ.

Щоб повернути власні значення, оберніть AND у функції IF таким чином:

=IF(AND(A2=B2:C2), "yes", "")

Ця формула повертає "так", якщо всі три клітинки рівні, інакше - порожня клітинка.

Формула COUNTIF для перевірки збігу декількох стовпців

Інший спосіб перевірки на множинні збіги - використання функції COUNTIF у цій формі:

Де діапазон діапазон комірок, які потрібно порівняти між собою, клітина є будь-яка окрема комірка в діапазоні, і n кількість комірок у діапазоні.

Для нашого прикладу формулу можна записати у такому вигляді:

=COUNTIF(A2:C2, A2)=3

Якщо ви порівнюєте багато стовпців, функція COLUMNS може автоматично підрахувати кількість комірок (n):

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

А функція IF допоможе вам повернути в якості результату все, що ви захочете:

=IF(COUNTIF(A2:C2, A2)=3, "Всі збігаються", "")

Формула з урахуванням регістру для декількох збігів

Як і при перевірці двох клітинок, ми використовуємо функцію ТОЧНО, щоб виконати точне порівняння, включаючи регістр літер. Для обробки декількох клітинок функція ТОЧНО повинна бути вкладена у функцію І, як показано нижче:

В Excel 365 і Excel 2021 завдяки підтримці динамічних масивів це працює як звичайна формула. В Excel 2019 і нижче не забудьте натиснути Ctrl + Shift + Enter, щоб зробити її формула масиву .

Наприклад, для перевірки того, чи містять комірки A2:C2 однакові значення, використовується формула, чутлива до регістру:

=AND(EXACT(A2:C2, A2))

У поєднанні з ПЧ вона набуває такої форми:

=IF(AND(EXACT(A2:C2, A2)), "Так", "Ні")

Перевірити, чи співпадає комірка з будь-якою коміркою в діапазоні

Щоб перевірити, чи збігається комірка з будь-якою коміркою в заданому діапазоні, скористайтеся однією з наведених нижче формул:

Функція АБО

Найкраще використовувати для перевірки 2 - 3 осередків.

Excel 365 та Excel 2021 також розуміють цей синтаксис:

В Excel 2019 і нижче це слід вводити як формулу масиву, натиснувши комбінацію клавіш Ctrl + Shift + Enter.

Функція COUNTIF

Наприклад, щоб перевірити, чи дорівнює A2 будь-якій комірці в B2:D2, підійде будь-яка з цих формул:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Якщо ви використовуєте Excel 2019 або новішу версію, не забудьте натиснути Ctrl + Shift + Enter, щоб отримати другу формулу АБО для отримання правильних результатів.

Повернутися Так/Ні або будь-яких інших потрібних вам значень, ви знаєте, що робити - вкласти одну з наведених вище формул в логічний тест функції ЕСЛИ. Наприклад:

=IF(COUNTIF(B2:D2, A2)>0, "Так", "Ні")

Для отримання додаткової інформації, будь ласка, зверніться до розділу Перевірка наявності значення в діапазоні.

Перевірка рівності двох діапазонів

Щоб порівняти два діапазони по комірках і повернути логічне значення ІСТИНА, якщо всі комірки у відповідних позиціях збігаються, подайте однакові за розміром діапазони на логічний тест функції І:

Наприклад, для порівняння Матриці А у B3:F6 та Матриці В у B11:F14 використовується формула:

=AND(B3:F6= B11:F14)

Щоб отримати Так / Ні в якості результату використовуйте наступну комбінацію IF AND:

=IF(AND(B3:F6=B11:F14), "Так", "Ні")

Ось так можна використовувати формулу "Если совпадает" в Excel. Дякую за увагу і сподіваюся побачити вас на нашому блозі наступного тижня!

Практичний посібник

Якщо комірки збігаються в Excel - приклади формул (файл .xlsx)