ټیوټوریل به تاسو ته درس درکړي چې څنګه په Excel کې If match فورمول جوړ کړئ، نو دا منطقي ارزښتونه، دودیز متن یا د بل حجرې څخه ارزښت بیرته راولي.

د لیدلو لپاره د Excel فورمول که دوه حجرې سره سمون ولري د A1=B1 په څیر ساده وي. په هرصورت، ممکن مختلف شرایط شتون ولري کله چې دا روښانه حل به کار ونکړي یا پایلې د هغه څه څخه توپیر ولري چې تاسو یې تمه درلوده. په دې ټیوټوریل کې، موږ به په Excel کې د حجرو پرتله کولو په مختلفو لارو بحث وکړو، نو تاسو کولی شئ د خپلې دندې لپاره غوره حل ومومئ.

څنګه وګورئ چې آیا دوه حجرې په Excel کې سره سمون لري

د Excel که د میچ فارمول ډیر توپیرونه شتون لري. یوازې لاندې مثالونه بیاکتنه وکړئ او هغه غوره کړئ چې ستاسو د سناریو لپاره غوره کار کوي.

که دوه حجرې مساوي وي، ریښتیا راشئ

تر ټولو ساده " که یو حجره د بل سره مساوي وي نو ریښتیا" د ایکسل فورمول دا دی:

حجره A= حجره B

د مثال په توګه، په هر قطار کې د A او B په کالمونو کې د حجرو پرتله کولو لپاره، تاسو دا فورمول دننه کړئ. C2، او بیا یې د کالم لاندې کاپي کړئ:

=A2=B2

د پایلې په توګه، تاسو به ریښتیا ترلاسه کړئ که دوه حجرې ورته وي، که غلط وي، که نه نو غلط:

یادونه:

• دا فورمول دوه بولین ارزښتونه راګرځوي: که دوه حجرې مساوي وي - ریښتیا؛ که مساوي نه وي - FALSE. یوازې د ریښتیني ارزښتونو بیرته راستنیدو لپاره، د IF بیان کې کار واخلئ لکه څنګه چې په راتلونکې مثال کې ښودل شوي.
• دا فورمول کیس غیر حساس دی، نو دا د ورته حروفونو په توګه لوی او کوچني توري چلند کوي. که متند قضیې مسله ده، نو بیا دا د قضیې حساس فورمول وکاروئ.

که دوه حجرې سره سمون ولري، د بیرته ستنیدو ارزښت

د خپل ارزښت بیرته راستنیدو لپاره که دوه حجرې سره سمون ولري، د دې نمونې په کارولو سره د IF بیان جوړ کړئ :

IF( cell A = cell B , value_if_true, value_if_false)

د مثال په توګه، د A2 او B2 پرتله کول او "هو" بیرته راګرځول که دوی ورته ارزښتونه ولري , "نه" بل ډول، فورمول دا دی:

=IF(A2=B2, "yes", "no")

که تاسو غواړئ یو ارزښت بیرته ورکړئ که چیرې حجرې مساوي وي، نو د value_if_false لپاره یو خالي تار ("") وړاندې کړئ .

که میچ وي نو هو :

=IF(A2=B2, "yes", "")

که میچ وي نو ریښتیا:

=IF(A2=B2, TRUE, "")

یادونه. د سم منطقي ارزښت د بیرته راګرځولو لپاره، دا په دوه اړخیزو نرخونو کې مه تړلئ. د دوه ګوني نرخونو کارول به منطقي ارزښت په منظم متن تار کې بدل کړي.

که یو حجره له بل سره مساوي وي، نو بیا بل حجره بیرته راوباسئ

او دلته د Excel if match فورمول یو تغیر دی چې دا ځانګړی دنده حل کوي: په دوه حجرو کې ارزښتونه پرتله کړئ او که ډیټا میچ کړئ، بیا د بل حجرې څخه یو ارزښت کاپي کړئ.

په Excel ژبه کې، دا په دې ډول جوړ شوی دی:

IF( cell A = cell B , حجره C ، "")

د مثال په توګه، د A او B په کالمونو کې د توکو د کتلو لپاره او د C کالم څخه ارزښت بیرته راستانه کړئ که متن سره سمون ولري، په D2 کې فورمول، کاپي شوی، دا دی: <3

=IF(A2=B2, C2, "")

د قضیې حساس فورمول د دې لپاره چې وګورئ چې دوه حجرې سره سمون لري

په هغه حالت کې چې تاسو د قضیې حساس متن ارزښتونو سره معامله کوئ، EXACT وکاروئد حجرو په دقیق ډول پرتله کولو لپاره فعالیت، په شمول د لیک قضیه:

IF(EXACT( cell A , cell B ), value_if_true, value_if_false)

د مثال په توګه پرتله کول توکي په A2 او B2 کې وګرځئ او "هو" بیرته راګرځئ که متن په سمه توګه سره سمون ولري، "نه" که کوم توپیر وموندل شي، تاسو کولی شئ دا فورمول وکاروئ:

=IF(EXACT(A2, B2), "Yes", "No")

څنګه وګورئ چې څو حجرې مساوي دي

لکه څنګه چې د دوو حجرو پرتله کول، د میچونو لپاره د ډیری حجرو معاینه کول هم په یو څو مختلفو لارو ترسره کیدی شي.

او فورمول وګورئ چې ایا ډیری حجرې سره سمون لري

د وګورئ چې څو ارزښتونه سره سمون لري، تاسو کولی شئ د AND فنکشن د دوه یا ډیرو منطقي ازموینو سره وکاروئ:

AND( حجره A = حجره B ، حجره A = حجره C ، …)

د مثال په توګه، د دې لپاره چې وګورئ حجرې A2، B2 او C2 مساوي دي، فورمول دا دی:

=AND(A2=B2, A2=C2)

په متحرک صف کې Excel (365 او 2021) تاسو کولی شئ لاندې ترکیب هم وکاروئ. په Excel 2019 او ښکته کې، دا به یوازې د دودیز CSE سرې فورمول په توګه کار وکړي، د Ctrl + Shift + Enter کیلي په یوځای کولو سره بشپړ شي.

=AND(A2=B2:C2)

د دواړو او فارمولونو پایله ده. منطقي ارزښتونه ریښتیا او غلط دي.

د خپلو ارزښتونو د بیرته راستنیدو لپاره، AND په IF فنکشن کې داسې وپلټئ:

=IF(AND(A2=B2:C2), "yes", "")

دا فورمول "هو" بیرته راګرځي که چیرې ټولې درې حجرې مساوي دي، یو خالي حجره بل ډول.

د COUNTIF فارمول د چک کولو لپاره چې څو کالمونه سره سمون خوري

د څو میچونو د چک کولو بله لاره په دې فورمه کې د COUNTIF فنکشن کارول دي:

COUNTIF( رینج , حجره )= n

چیرته چې رینج د حجرو سلسله ده چې د یو بل سره پرتله کیږي، حجره په سلسله کې هر یو واحد حجره ده، او n په سلسله کې د حجرو شمیر دی.

زموږ د نمونې ډیټاسیټ لپاره، فورمول په دې بڼه لیکل کیدی شي. :

=COUNTIF(A2:C2, A2)=3

که تاسو ډیری کالمونه پرتله کوئ، د COLUMNS فنکشن کولی شي ستاسو لپاره په اتوماتيک ډول د حجرو شمیر (n) ترلاسه کړي:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

او د IF فنکشن به تاسو سره مرسته وکړي هر هغه څه چې تاسو یې د پایلې په توګه غواړئ بیرته راستانه کړئ:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

د څو میچونو لپاره د قضیې حساس فورمول

لکه څنګه چې د دوه حجرو چک کولو سره، موږ د دقیق پرتله کولو لپاره د EXACT فعالیت وکاروئ، په شمول د لیک قضیه. د ډیری حجرو اداره کولو لپاره، EXACT باید په AND فنکشن کې داسې وي:

AND(EXACT( range , cell ))

په Excel 365 او Excel 2021 کې د متحرک صفونو د ملاتړ له امله، دا د یو نورمال فورمول په توګه کار کوي. په Excel 2019 او ښکته کې، په یاد ولرئ چې Ctrl + Shift + Enter فشار ورکړئ ترڅو دا د ارې فورمول جوړ کړي.

د مثال په توګه، د دې لپاره چې وګورئ A2:C2 ورته ارزښتونه لري، یوه قضیه حساس فورمول دا دی:

=AND(EXACT(A2:C2, A2))

د IF سره په ترکیب کې، دا شکل اخلي:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

وګورئ چې ایا حجره په رینج کې د کومې حجرې سره سمون لري

د دې لپاره چې وګورئ چې حجره په یوه ټاکل شوي سلسله کې د کومې حجرې سره سمون لري، د لاندې فورمولونو څخه یو کار واخلئ:

0> 15> یا فعالیت 3

دا غوره ده چې وکارول شي د 2 - 3 حجرو چک کولو لپاره.

یا ( حجره A = حجره B ، حجره A = حجره C ، حجره A = سیل D ، …)

Excel 365 او Excel 2021 په دې ترکیب هم پوهیږي:

OR( cell = range )

په Excel 2019 او ښکته، دا باید د Ctrl + Shift + Enter شارټ کټ په فشارولو سره د صف فارمول په توګه داخل شي.

COUNTIF فعالیت

COUNTIF( رینج , حجره )>0

د مثال په توګه، د دې لپاره چې وګوري چې ایا A2 په B2:D2 کې د کومې حجرې سره مساوي دی، د دې فورمولونو څخه کوم یو به دا کار وکړي:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

که تاسو د Excel 2019 یا ټیټ کاروئ، په یاد ولرئ چې Ctrl + Shift + Enter فشار ورکړئ ترڅو د سمې پایلې وړاندې کولو لپاره دوهم یا فارمول ترلاسه کړئ.

د بیرته راستنیدو لپاره هو/نه یا کوم بل ارزښت چې تاسو یې غواړئ، تاسو پوهیږئ چې څه وکړئ - د IF فنکشن منطقي ازموینې کې د پورتنیو فورمولونو څخه یو یې نیست کړئ. د مثال په توګه:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

د نورو معلوماتو لپاره، مهرباني وکړئ وګورئ وګورئ چې ایا ارزښت په یوه حد کې شتون لري.

چک کړئ که دوه رینجونه مساوي وي

د پرتله کولو لپاره دوه رینجونه د حجرو په واسطه او د منطقي ارزښت بیرته راګرځي TRUE که چیرې په اړونده پوستونو کې ټولې حجرې سره سمون ولري، د مساوي اندازې سلسلې د AND فنکشن منطقي ازموینې ته وړاندې کړئ:

AND( range A = رینج B )

د مثال په توګه، په B3:F6 کې Matrix A او B11:F14 کې Matrix B پرتله کولو لپاره، فورمول دا دی:

=AND(B3:F6= B11:F14)

ته ترلاسه کړئ هو / نه د پایلې په توګه، لاندې IF او ترکیب وکاروئ:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

دا څنګه د If میچ فارمول وکاروئپه Excel کې. زه ستاسو د لوستلو لپاره مننه کوم او هیله لرم چې تاسو راتلونکې اونۍ زموږ په بلاګ کې وګورم!

د تمرین کاري کتاب

که حجرې په Excel کې سره سمون خوري - د فورمول مثالونه (.xlsx فایل)