A bemutató megtanítja, hogyan kell felépíteni az If match képletet az Excelben, hogy logikai értékeket, egyéni szöveget vagy egy másik cellából származó értéket adjon vissza.

Egy Excel-képlet, amellyel megnézhetjük, hogy két cella egyezik-e, lehet olyan egyszerű, mint az A1=B1. Azonban különböző körülmények között előfordulhat, hogy ez a nyilvánvaló megoldás nem működik, vagy a várttól eltérő eredményt ad. Ebben a bemutatóban a cellák összehasonlításának különböző módjait tárgyaljuk az Excelben, hogy megtaláljuk a feladatunkhoz szükséges optimális megoldást.

Hogyan ellenőrizheti, hogy két cella egyezik-e az Excelben

Az Excel If match képletének számos változata létezik. Tekintse át az alábbi példákat, és válassza ki az Ön forgatókönyvének legmegfelelőbbet.

Ha két cella egyenlő, TRUE-t ad vissza

A legegyszerűbb " Ha az egyik cella egyenlő egy másikkal, akkor igaz" Az Excel képlet a következő:

Ha például az egyes sorok A és B oszlopában lévő cellákat szeretné összehasonlítani, adja be ezt a képletet a C2-be, majd másolja lefelé az oszlopba:

=A2=B2

Az eredmény TRUE lesz, ha két cella azonos, egyébként FALSE:

Megjegyzések:

• Ez a képlet két Boolean értéket ad vissza: ha két cella egyenlő - TRUE; ha nem egyenlő - FALSE. Ha csak a TRUE értékeket szeretné visszaadni, használjon IF utasítást a következő példában látható módon.
• Ez a képlet a következő case-insensitive , így a nagy- és kisbetűket azonos karaktereknek tekinti. Ha a szöveg nagy- és kisbetűi számítanak, akkor használja ezt a nagy- és kisbetű-érzékeny formulát.

Ha két cella egyezik, visszatérési érték

Ha saját értéket szeretne visszaadni, ha két cella egyezik, akkor egy IF utasítást kell létrehoznia ezzel a mintával:

Például, az A2 és B2 összehasonlításához, és "igen" választ ad, ha ugyanazokat az értékeket tartalmazzák, és "nem" választ, ha nem, a képlet a következő:

=IF(A2=B2, "igen", "nem")

Ha csak akkor akarsz értéket visszaadni, ha a cellák egyenlőek, akkor adj meg egy üres karakterláncot ("") a value_if_false .

Ha egyezik, akkor igen :

=IF(A2=B2, "igen", "")

Ha egyezik, akkor TRUE:

=IF(A2=B2, TRUE, "")

Megjegyzés: Ha a logikai értéket TRUE értékkel akarja visszaadni, ne zárja be idézőjelekbe, mert akkor a logikai értéket normál szöveges karakterlánccá alakítja.

Ha egy cella egyenlő egy másikkal, akkor egy másik cellát ad vissza.

És itt van egy variációja a Excel ha egyezés képlet, amely megoldja ezt a konkrét feladatot: összehasonlítja a két cellában lévő értékeket, és ha az adatok egyeznek, akkor másoljon egy értéket egy másik cellából.

Az Excel nyelvén ez így hangzik:

Például, ha az A és B oszlopban lévő elemeket szeretnénk ellenőrizni, és a C oszlopból visszaadni egy értéket, ha a szöveg egyezik, akkor a D2-ben lévő képlet a következő, lemásolva:

=IF(A2=B2, C2, "")

Nagy- és kisbetű-érzékeny képlet két cella egyezésének megnézéséhez

Olyan helyzetekben, amikor nagy- és kisbetű-érzékeny szöveges értékekkel van dolga, használja az EXACT funkciót a cellák pontos összehasonlításához, beleértve a betűk nagy- és kisbetűit is:

Ha például össze akarja hasonlítani az A2 és B2 elemeket, és "igen" választ ad, ha a szöveg pontosan megegyezik, "nem" választ, ha bármilyen eltérést talál, akkor ezt a képletet használhatja:

=IF(EXACT(A2, B2), "Igen", "Nem")

Hogyan ellenőrizhetjük, hogy több cella egyenlő-e

Két cella összehasonlításához hasonlóan a több cella egyezésének ellenőrzése is többféleképpen történhet.

ÉS formula, hogy megnézzük, több cella egyezik-e

Több érték egyezésének ellenőrzésére használhatja az ÉS függvényt két vagy több logikai teszt segítségével:

Például, ha azt szeretnénk megnézni, hogy az A2, B2 és C2 cellák egyenlőek-e, a képlet a következő:

=ÉS(A2=B2, A2=C2)

A dinamikus tömb Excelben (365 és 2021) az alábbi szintaxist is használhatja. Az Excel 2019-ben és annál alacsonyabb verzióban ez csak hagyományos CSE tömbképletként működik, amelyet a Ctrl + Shift + Enter billentyűk együttes lenyomásával fejezhet be.

=AND(A2=B2:C2)

Mindkét AND formula eredménye a TRUE és a FALSE logikai értékek.

A saját értékek visszaadása érdekében az ÉS-t az IF függvénybe csomagoljuk be a következőképpen:

=IF(AND(A2=B2:C2), "igen", "")

Ez a képlet "igen"-t ad vissza, ha mindhárom cella egyenlő, egyébként egy üres cellát.

COUNTIF formula több oszlop egyezőségének ellenőrzésére

A többszörös egyezések ellenőrzésének másik módja a COUNTIF függvény használata ebben az űrlapban:

Hol tartomány az egymással összehasonlítandó cellák tartománya, sejt a tartomány bármelyik cellája, és n a tartományban lévő cellák száma.

A mintaadatkészletünk esetében a képlet a következő formában írható fel:

=COUNTIF(A2:C2, A2)=3

Ha sok oszlopot hasonlít össze, a COLUMNS függvény automatikusan megkaphatja a cellák számát (n):

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

Az IF függvény pedig segít visszaadni bármit, amit csak akarsz eredményként:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

Nagy- és kisbetű-érzékeny formula többszörös egyezésekhez

A két cella ellenőrzéséhez hasonlóan az EXACT függvényt használjuk a pontos összehasonlítás elvégzésére, beleértve a betűhasonlítást is. Több cella kezeléséhez az EXACT függvényt az AND függvénybe kell beágyazni a következőképpen:

Az Excel 365 és az Excel 2021 programban a dinamikus tömbök támogatása miatt ez normál képletként működik. Az Excel 2019 és alacsonyabb verzióban ne feledje, hogy a Ctrl + Shift + Enter billentyűkombinációt kell megnyomnia, hogy a tömb képlet .

Ha például azt szeretné ellenőrizni, hogy az A2:C2 cellák ugyanazokat az értékeket tartalmazzák-e, akkor a nagy- és kisbetűket figyelembe vevő képlet a következő:

=AND(EXACT(A2:C2, A2))

Az IF-fel kombinálva a következő formát ölti:

=IF(AND(EXACT(A2:C2, A2)), "Igen", "Nem")

Ellenőrizze, hogy a cella egyezik-e a tartomány bármely cellájával

Ha meg szeretné nézni, hogy egy adott tartomány bármelyik cellájával egyezik-e egy cella, használja a következő képletek egyikét:

VAGY funkció

A legjobb, ha 2-3 cella ellenőrzésére használják.

Az Excel 365 és az Excel 2021 is érti ezt a szintaxist:

Az Excel 2019 és újabb programokban ezt tömbképletként kell megadni a Ctrl + Shift + Enter billentyűkombináció megnyomásával.

COUNTIF funkció

Ha például azt szeretnénk ellenőrizni, hogy A2 egyenlő-e a B2:D2 bármelyik cellájával, akkor az alábbi képletek bármelyike megfelel:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

Ha az Excel 2019 vagy alacsonyabb verzióját használja, ne feledje, hogy a Ctrl + Shift + Enter billentyűkombinációt kell megnyomnia, hogy a második VAGY képlet a megfelelő eredményt adja.

Visszatérni Igen/Nem vagy bármilyen más értéket, akkor tudja, mit kell tennie - a fenti formulák egyikét beilleszti az IF függvény logikai tesztjébe. Például:

=IF(COUNTIF(B2:D2, A2)>0, "Igen", "Nem")

További információért lásd: Érték létezésének ellenőrzése egy tartományban.

Két tartomány egyenlőségének ellenőrzése

Két tartomány cellánkénti összehasonlításához és a TRUE logikai érték visszaadásához, ha a megfelelő pozíciókban lévő összes cella egyezik, adjuk meg az azonos méretű tartományokat az ÉS függvény logikai tesztjéhez:

Például a B3:F6 mátrixban található A mátrix és a B11:F14 mátrixban található B mátrix összehasonlításához a képlet a következő:

=ÉS(B3:F6= B11:F14)

Ahhoz, hogy Igen / Nem eredményként a következő IF AND kombinációt használja:

=IF(AND(B3:F6=B11:F14), "Igen", "Nem")

Így kell használni az If match képletet az Excelben. Köszönöm, hogy elolvastad, és remélem, jövő héten találkozunk a blogon!

Gyakorló munkafüzet

Ha a cellák egyeznek az Excelben - képletpéldák (.xlsx fájl)