این آموزش به شما یاد می دهد که چگونه فرمول If match را در اکسل بسازید، بنابراین مقادیر منطقی، متن سفارشی یا مقداری را از سلول دیگر برمی گرداند.

یک فرمول اکسل برای دیدن اگر دو سلول مطابقت داشته باشند می تواند به سادگی A1=B1 باشد. با این حال، ممکن است شرایط متفاوتی وجود داشته باشد که این راه حل بدیهی کار نکند یا نتایجی متفاوت از آنچه انتظار داشتید ایجاد کند. در این آموزش، روش‌های مختلفی را برای مقایسه سلول‌ها در اکسل مورد بحث قرار می‌دهیم تا بتوانید راه‌حلی بهینه برای کار خود بیابید.

چگونه بررسی کنیم که آیا دو سلول در اکسل مطابقت دارند

تغییرهای زیادی از فرمول Excel If match وجود دارد. فقط نمونه‌های زیر را مرور کنید و بهترین را برای سناریوی خود انتخاب کنید.

اگر دو سلول برابر هستند، TRUE را برگردانید

ساده‌ترین " اگر یک سلول برابر با سلول دیگر باشد، درست است" فرمول اکسل این است:

سلول A= سلول B

به عنوان مثال، برای مقایسه سلول های ستون های A و B در هر سطر، این فرمول را وارد کنید C2، و سپس آن را در ستون کپی کنید:

=A2=B2

در نتیجه، اگر دو خانه یکسان باشند، TRUE دریافت خواهید کرد، در غیر این صورت FALSE:

نکات:

• این فرمول دو مقدار بولی را برمی گرداند: اگر دو سلول برابر باشند - TRUE; اگر مساوی نیست - FALSE. برای اینکه فقط مقادیر TRUE را برگردانید، همانطور که در مثال بعدی نشان داده شده است، از عبارت IF استفاده کنید.
• این فرمول به حروف بزرگ حساس نیست ، بنابراین حروف بزرگ و کوچک را به عنوان کاراکترهای یکسان در نظر می گیرد. اگر متنحروف بزرگ اهمیت دارد، سپس از این فرمول حساس به حروف کوچک و بزرگ استفاده کنید.

اگر دو سلول مطابقت دارند، مقدار را برگردانید

برای برگرداندن مقدار خود اگر دو سلول مطابقت دارند، با استفاده از این الگو یک دستور IF بسازید. :

IF( سلول A = سلول B ، value_if_true، value_if_false)

به عنوان مثال، برای مقایسه A2 و B2 و برگرداندن "بله" اگر حاوی مقادیر مشابهی باشند ، "نه" در غیر این صورت، فرمول این است:

=IF(A2=B2, "yes", "no")

اگر فقط می خواهید مقداری را در صورت مساوی بودن سلول ها برگردانید، سپس یک رشته خالی ("") برای value_if_false وارد کنید. .

اگر مطابقت دارد، پس بله :

=IF(A2=B2, "yes", "")

اگر مطابقت دارد، سپس TRUE:

=IF(A2=B2, TRUE, "")

توجه داشته باشید. برای برگرداندن مقدار منطقی TRUE، آن را در دو گیومه قرار ندهید. استفاده از دو نقل قول مقدار منطقی را به یک رشته متنی معمولی تبدیل می کند.

اگر یک سلول برابر با سلول دیگر است، سپس سلول دیگری را برگردانید

و در اینجا یک تغییر از فرمول Excel if match وجود دارد که این کار خاص را حل می کند: مقادیر را در دو سلول مقایسه کنید و اگر داده ها مطابقت دارند، سپس یک مقدار را از یک سلول دیگر کپی کنید.

در زبان اکسل، این فرمول بندی شده است:

IF( سلول A = سلول B ، سلول C ، "")

به عنوان مثال، برای بررسی موارد در ستون‌های A و B و برگرداندن مقداری از ستون C در صورت مطابقت متن، فرمول موجود در D2 که به پایین کپی می‌شود، این است:

=IF(A2=B2, C2, "")

فرمول حساس به حروف بزرگ و کوچک برای دیدن اینکه آیا دو سلول مطابقت دارند یا نه

در شرایطی که با مقادیر متن حساس به حروف بزرگ و کوچک سر و کار دارید، از EXACT استفاده کنید.عملکردی برای مقایسه دقیق سلول ها، از جمله حروف کوچک:

IF(EXACT( سلول A ، سلول B )، value_if_true، value_if_false)

به عنوان مثال، برای مقایسه موارد موجود در A2 و B2 و اگر متن دقیقاً مطابقت دارد "بله" را بازگردانید، اگر تفاوتی پیدا شد "نه"، می توانید از این فرمول استفاده کنید:

=IF(EXACT(A2, B2), "Yes", "No")

چگونه بررسی کنیم که آیا چندین سلول وجود دارد یا خیر برابر هستند

همانطور که با مقایسه دو سلول، بررسی سلول های متعدد برای مطابقت نیز می تواند به روش های مختلف انجام شود.

و فرمول برای مشاهده اینکه آیا چندین سلول مطابقت دارند

به بررسی کنید که آیا چندین مقدار مطابقت دارند، می توانید از تابع AND با دو یا چند تست منطقی استفاده کنید:

AND( سلول A = سلول B ، سلول A = سلول C ، …)

به عنوان مثال، برای اینکه ببینید آیا سلول های A2، B2 و C2 برابر هستند یا خیر، فرمول این است:

=AND(A2=B2, A2=C2)

در آرایه پویا اکسل (365 و 2021) همچنین می توانید از نحو زیر استفاده کنید. در Excel 2019 و نسخه های پایین تر، این فقط به عنوان یک فرمول سنتی آرایه CSE کار می کند که با فشار دادن کلیدهای Ctrl + Shift + Enter با هم کامل می شود.

=AND(A2=B2:C2)

نتیجه هر دو فرمول AND این است مقادیر منطقی TRUE و FALSE.

برای برگرداندن مقادیر خود، AND را در تابع IF به این شکل بپیچید:

=IF(AND(A2=B2:C2), "yes", "")

این فرمول اگر هر سه سلول "بله" را برمی‌گرداند برابر هستند، در غیر این صورت یک سلول خالی هستند.

فرمول COUNTIF برای بررسی مطابقت چند ستون

روش دیگری برای بررسی تطابق چندگانه استفاده از تابع COUNTIF در این فرم است:

COUNTIF( محدوده ، سلول )= n

که در آن محدوده محدوده ای از سلول ها است که باید با یکدیگر مقایسه شوند، cell هر سلول منفرد در محدوده است و n تعداد سلول‌های محدوده است.

برای مجموعه داده نمونه ما، فرمول را می‌توان به این شکل نوشت. :

=COUNTIF(A2:C2, A2)=3

اگر ستون های زیادی را با هم مقایسه می کنید، تابع COLUMNS می تواند تعداد سلول ها (n) را به طور خودکار برای شما دریافت کند:

=COUNTIF(A2:C2, A2)=COLUMNS(A2:C2)

و تابع IF به شما کمک می کند هر چیزی را که می خواهید به عنوان نتیجه برگردانید:

=IF(COUNTIF(A2:C2, A2)=3, "All match", "")

فرمول حساس به حروف بزرگ برای چندین تطابق

همانطور که با بررسی دو سلول، ما از تابع EXACT برای انجام مقایسه دقیق، از جمله حروف کوچک، استفاده کنید. برای مدیریت چندین سلول، EXACT باید در تابع AND به این صورت تودرتو شود:

AND(EXACT( محدوده ، سلول ))

در Excel 365 و Excel 2021 ، به دلیل پشتیبانی از آرایه های پویا، این به عنوان یک فرمول عادی عمل می کند. در اکسل 2019 و نسخه‌های پایین‌تر، به یاد داشته باشید که Ctrl + Shift + Enter را فشار دهید تا به فرمول آرایه تبدیل شود.

به عنوان مثال، برای بررسی اینکه آیا سلول‌های A2:C2 حاوی مقادیر یکسان هستند یا خیر، یک مورد -فرمول حساس این است:

=AND(EXACT(A2:C2, A2))

در ترکیب با IF، این شکل را به خود می گیرد:

=IF(AND(EXACT(A2:C2, A2)), "Yes", "No")

بررسی کنید آیا سلول با هر سلولی در محدوده مطابقت دارد یا خیر

برای مشاهده اینکه آیا یک سلول با سلولی در یک محدوده مشخص مطابقت دارد یا خیر، از یکی از فرمول های زیر استفاده کنید:

عملکرد OR

بهتر است استفاده شود برای بررسی 2 - 3 سلول.

OR( سلول A = سلول B ، سلول A = سلول C ، سلول A = سلول D ، …)

Excel 365 و Excel 2021 این نحو را نیز درک می کنند:

OR( cell = range )

در Excel 2019 و پایین تر، باید با فشار دادن کلیدهای میانبر Ctrl + Shift + Enter، آن را به عنوان یک فرمول آرایه وارد کنید. cell )>0

به عنوان مثال، برای بررسی اینکه آیا A2 برابر با هر سلولی در B2:D2 است، هر یک از این فرمول ها این کار را انجام می دهد:

=OR(A2=B2, A2=C2, A2=D2)

=OR(A2=B2:D2)

=COUNTIF(B2:D2, A2)>0

اگر از اکسل 2019 یا پایین تر استفاده می کنید، به خاطر داشته باشید که Ctrl + Shift + Enter را فشار دهید تا فرمول OR دوم را برای ارائه نتایج صحیح به دست آورید.

برای برگرداندن Yes/No یا هر مقدار دیگری که می خواهید، می دانید چه کاری باید انجام دهید - یکی از فرمول های بالا را در تست منطقی تابع IF قرار دهید. به عنوان مثال:

=IF(COUNTIF(B2:D2, A2)>0, "Yes", "No")

برای اطلاعات بیشتر، لطفاً بررسی کنید آیا مقدار در یک محدوده وجود دارد یا خیر.

بررسی کنید که آیا دو محدوده برابر هستند

برای مقایسه دو محدوده سلول به سلول و اگر همه سلول‌ها در موقعیت‌های مربوطه مطابقت داشته باشند، مقدار منطقی TRUE را برمی‌گردانید، محدوده‌های هم اندازه را به آزمون منطقی تابع AND ارائه کنید:

AND( محدوده A = محدوده B )

به عنوان مثال، برای مقایسه ماتریس A در B3:F6 و ماتریس B در B11:F14، فرمول این است:

=AND(B3:F6= B11:F14)

به در نتیجه بله / خیر را دریافت کنید، از ترکیب IF و زیر استفاده کنید:

=IF(AND(B3:F6=B11:F14), "Yes", "No")

به این ترتیب می توان از فرمول If match استفاده کرددر اکسل از خواندن شما سپاسگزارم و امیدوارم هفته آینده شما را در وبلاگ خود ببینیم!

کتاب کار تمرینی

اگر سلول ها در اکسل مطابقت دارند - نمونه های فرمول (فایل xlsx.)

<3 <3 <3

3 3> 3>