Opplæringen forklarer hvordan du gjør Excel VLOOKUP sensitiv for store og små bokstaver, demonstrerer noen få andre formler som skiller mellom store og små bokstaver, og påpeker styrker og begrensninger for hver funksjon.

Jeg antar at hver funksjon Excel-bruker vet hvilken funksjon som utfører et vertikalt oppslag i Excel. Greit, det er VLOOKUP. Svært få mennesker er imidlertid klar over at Excels VLOOKUP ikke skiller mellom store og små bokstaver, noe som betyr at den behandler små og STORE bokstaver som de samme tegnene.

Her er et raskt eksempel som viser VLOOKUPs manglende evne til å skille mellom store og små bokstaver. Anta at hvis du har "bill" i celle A2 og "Bill" i A4. Formelen nedenfor vil fange "regning" fordi den kommer først i oppslagsmatrisen og returnerer en samsvarende verdi fra B2.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

Videre i denne artikkel, vil jeg vise deg en måte å gjøre VLOOKUP skiller mellom store og små bokstaver. Vi vil også utforske noen få andre funksjoner som kan gjøre et samsvar med store og små bokstaver i Excel.

Stillingssensitiv VLOOKUP-formel

Som nevnt ovenfor, en vanlig VLOOKUP-formel kjenner ikke igjen bokstaven. Det er imidlertid en måte å gjøre Excel VLOOKUP skiller mellom store og små bokstaver, som vist i eksemplet nedenfor.

Anta at du har vare-ID-er i kolonne A og ønsker å hente varens pris og kommentar fra kolonne B og C. Problemet er at ID-er inkluderer både små og store tegn. For eksempel er verdiene i A4 (001Tvci3u) og A5 (001Tvci3U) bare forskjellige idet siste tegnet, henholdsvis "u" og "U".

Når du slår opp "001Tvci3 U ", gir en standard VLOOKUP-formel $90 som er assosiert med "001Tvci3 u " fordi den kommer før "001Tvci3 U " i oppslagsmatrisen. Men dette er ikke det du vil ha, ikke sant?

=VLOOKUP(F2, A2:C7, 2, FALSE)

For å utføre et oppslag som skiller mellom store og små bokstaver i Excel, kombinerer vi SØK OPP, VELG og EKSAKT funksjoner:

Denne generiske formelen fungerer perfekt i alle situasjoner. Du kan til og med slå opp fra høyre til venstre , noe en vanlig VLOOKUP-formel ikke klarer. Kudos til Pouriya for å foreslå denne enkle og elegante løsningen!

I vårt tilfelle går de virkelige formlene som følger.

For å trekke prisen i F3:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

For å hente kommentaren F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Merk. I alle andre Excel-versjoner enn Excel 365 fungerer dette kun som en matriseformel, så husk å trykke Ctrl + Shift + Enter for å fullføre den riktig. I Excel 365, på grunn av støtte for dynamiske matriser, fungerer den også som en vanlig formel.

Hvordan denne formelen fungerer:

Kjernen som gjør susen er VELG-formelen med nestet EXACT:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

Her, EKSAKT-funksjonen sammenligner verdien i F2 mot hver verdi i A2:A7 og returnerer TRUE hvis de er nøyaktig like inkludert store og små bokstaver,FALSE ellers:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

For index_num -argumentet til CHOOSE, bruker vi matrisekonstanten {1,2}. Som et resultat kombinerer funksjonen de logiske verdiene fra arrayen ovenfor og verdiene fra C2:C7 til en todimensjonal array slik:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP-funksjonen tar den derfra og søker etter oppslagsverdien (som er TRUE) i den første kolonnen i den 2-dimensjonale matrisen (representert av de logiske verdiene) og returnerer et samsvar fra den andre kolonnen, som er prisen vi ser etter:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Stillingssensitiv XLOOKUP-formel

Microsoft 365-abonnenter kan gjøre et versalsensitivt oppslag i Excel med enda en enklere formel. Som du kan gjette, snakker jeg om en kraftigere etterfølger av VLOOKUP - XLOOKUP-funksjonen.

Fordi XLOOKUP opererer på oppslags- og returmatriser separat, trenger vi ikke det todimensjonale matrisetrikset fra forrige eksempel. Bare bruk EXACT for oppslagsmatrise -argumentet:

Det siste argumentet ("Ikke funnet") er valgfritt. Den definerer bare hvilken verdi som skal returneres hvis ingen samsvar blir funnet. Hvis du utelater det, vil en standard #N/A-feil returneres i tilfelle formelen ikke finner noe.

For eksempeltabellen vår er dette de store og små bokstavsensitive XLOOKUP-formlene som skal brukes.

For å få prisen i F3:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

For å trekke utkommentar F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

Hvordan denne formelen fungerer:

Som i forrige eksempel, returnerer EXACT en rekke TRUE- og FALSE-verdier, der TRUE representerer treff som skiller mellom store og små bokstaver. XLOOKUP søker i arrayen ovenfor etter TRUE-verdien og returnerer et samsvar fra return_array . Vær oppmerksom på at hvis det er to eller flere nøyaktig samme verdier i oppslagskolonnen (inkludert store og små bokstaver), vil formelen returnere det første funnet samsvaret.

XLOOKUP-begrensning : kun tilgjengelig i Excel 365 og Excel 2021.

SUMPRODUKT – store og små bokstaver for å returnere samsvarende tall

Som du forstår fra overskriften, er SUMPRODUCT nok en Excel-funksjon som kan gjøre et oppslag som skiller mellom store og små bokstaver , men den kan bare returnere numeriske verdier . Hvis dette ikke er ditt tilfelle, så hopp til INDEX MATCH-eksemplet som gir en løsning for alle datatyper.

Som du sikkert vet, multipliserer Excels SUMPRODUCT komponenter i de spesifiserte matrisene og returnerer summen av produktene. Siden vi ønsker et oppslag som skiller mellom store og små bokstaver, bruker vi EXACT-funksjonen for å få den første matrisen:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

Dessverre kan SUMPRODUCT-funksjonen ikke returnere teksttreff siden tekstverdier ikke kan multipliseres. I dette tilfellet vil du få en #VALUE! feil som i celle F4 i skjermbildet nedenfor:

Hvordan denne formelen fungerer:

Som i VLOOKUP-eksemplet, EXACT funksjonskontrollerverdien i F2 mot alle verdiene i A2:A7 og returnerer TRUE for treff som skiller mellom store og små bokstaver, FALSE ellers:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

I de fleste formler evaluerer Excel SANN til 1 og FALSE til 0 Så, når SUMPRODUCT multipliserer elementene i de to matrisene i samme posisjoner, blir alle ikke-treff (FALSE) nuller:

SUMPRODUCT({0;0;0;54;0;0})

Som resultat returnerer formelen et tall fra kolonne B som tilsvarer det nøyaktige samsvaret med store og små bokstaver i kolonne A.

SUMPRODUKT-begrensning : kan bare returnere numeriske verdier.

INDEX MATCH – store og små bokstaver-sensitive oppslag for alle datatyper

Endelig er vi i ferd med å få en begrensningsfri hovedsaksensitiv oppslagsformel som fungerer i alle Excel-versjoner og på alle datasett.

Dette eksemplet kommer sist, ikke bare fordi det beste lagres til sist, men også fordi kunnskapen du har fått i de foregående eksemplene kan hjelpe deg å forstå den store og små bokstavsensitive MATCH INDEX-formelen bedre.

Kombinasjonen av INDEX- og MATCH-funksjoner brukes ofte i eks cel som et mer fleksibelt og allsidig alternativ til VLOOKUP. Følgende artikkel gjør en god jobb (forhåpentligvis :) og forklarer hvordan disse to funksjonene fungerer sammen - Bruk av INDEX MATCH i stedet for VLOOKUP.

Her vil jeg bare minne deg på nøkkelpunktene:

• MATCH-funksjonen søker etter oppslagsverdien i den angitte oppslagsmatrisen og returnerer dens relative posisjon.
• Den relativeposisjonen til oppslagsverdien går direkte til radnummer -argumentet til INDEX-funksjonen og instruerer den om å returnere en verdi fra den raden.

For at formelen skal gjenkjenne store og små bokstaver i tekst, må du bare må legge til en funksjon til i den klassiske INDEX MATCH-kombinasjonen. Selvfølgelig trenger du EXACT-funksjonen igjen:

Den virkelige formelen i F3 er:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

I F4 bruker vi denne:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Husk at den bare fungerer som en matriseformel i alle andre versjoner enn Excel 365, så sørg for å angi den ved å trykke Ctrl + Shift + Enter-tastene samtidig. Hvis det gjøres riktig, vil formelen bli omsluttet av krøllete klammeparenteser som vist i skjermbildet nedenfor:

Hvordan denne formelen fungerer:

Som i alle tidligere eksempler, returnerer EXACT TRUE for hver verdi i A2:A7 som nøyaktig samsvarer med verdien i F2. Siden vi bruker TRUE for oppslagsverdien til MATCH, returnerer den en relativ plassering av det eksakte tilfellet-sensitive samsvaret, som er nøyaktig det INDEX trenger for å returnere et samsvar fra B2:B7.

Avansert hovedsaksensitiv oppslagsformel

Den ovennevnte INDEX MATCH-formelen ser perfekt ut, ikke sant? Men det er det faktisk ikke. La meg vise deg hvorfor.

Anta at en celle i returkolonnen som tilsvarer oppslagsverdien er tom. Hva skal formelen returnere? Ingenting.Og nå, la oss se hva den faktisk returnerer:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Beklager, formelen returnerer en null! Kanskje er det egentlig ikke så viktig når man bare arbeider med tekstverdier. Men hvis regnearket ditt inneholder tall og noen av dem er reelle nuller, er dette et problem.

I sannhet oppfører alle andre oppslagsformler diskutert tidligere seg på samme måte. Men nå vil du ha en upåklagelig formel, gjør du ikke?

For å gjøre den store og små bokstavsensitive INDEX MATCH-formelen helt perfekt, pakker du den inn i HVIS-funksjonen som sjekker om en returcelle er tom og ikke returnerer noe i dette tilfellet:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

I formelen ovenfor:

• "C" er returkolonnen.
• "1" er tallet som gjør en relativ posisjon av cellen returnert av MATCH-funksjonen til en reell celleadresse .

For eksempel oppslagsmatrisen i MATCH-funksjonen vår er A2:A7, noe som betyr at den relative posisjonen til celle A2 er "1", fordi dette er den første cellen i matrisen. Men i virkeligheten begynner oppslagsmatrisen i rad 2. For å kompensere forskjellen legger vi til 1, slik at INDIREKTE-funksjonen vil returnere en verdi fra høyre celle.

Skjermbildene nedenfor viser den forbedrede INDEX som skiller mellom store og små bokstaver. MATCH formel i aksjon.

Hvis returcellen er tom, gir formelen ingenting ut (en tom streng):

Hvis returcellen inneholder en null , returnerer formelen 0:

Hvis du heller vil detvis en melding når en returcelle er tom, erstatt en tom streng ("") i det siste argumentet til IF med litt tekst:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

Gjør VLOOKUP med store og små bokstaver på en enkel måte

Brukerne av Ultimate Suite for Excel har et spesialverktøy som gjør det enklere og stressfritt å slå opp i store og komplekse tabeller. Det beste er at Merge Two Tables har et alternativ som skiller mellom store og små bokstaver, og eksemplet nedenfor viser det i aksjon.

Anta at du vil trekke antall. fra Oppslag -tabellen til Hoved -tabellen basert på unike vare-ID-er:

Det du gjør er å kjøre sammenslåingstabellene veiviseren og utfør disse trinnene:

1. Velg hovedtabellen du vil trekke nye data inn i.
2. Velg oppslagstabellen der du vil se etter de nye dataene.
3. Velg en eller flere nøkkelkolonner (Vare-ID i vårt tilfelle). Og sørg for å merke av for Stilling for store og små bokstaver .

Et øyeblikk senere får du ønsket resultat :)

Det er hvordan du slår opp i Excel med tanke på teksten. Jeg takker for at du leste og håper å se deg på bloggen vår neste uke!

Øvningsarbeidsbok for nedlasting

Stillingssensitive VLOOKUP-eksempler (.xlsx-fil)