ਟਿਊਟੋਰਿਅਲ ਦੱਸਦਾ ਹੈ ਕਿ ਐਕਸਲ VLOOKUP ਨੂੰ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਕਿਵੇਂ ਬਣਾਇਆ ਜਾਵੇ, ਕੁਝ ਹੋਰ ਫਾਰਮੂਲੇ ਦਿਖਾਉਂਦਾ ਹੈ ਜੋ ਟੈਕਸਟ ਕੇਸ ਨੂੰ ਵੱਖਰਾ ਕਰਦੇ ਹਨ, ਅਤੇ ਹਰੇਕ ਫੰਕਸ਼ਨ ਦੀਆਂ ਸ਼ਕਤੀਆਂ ਅਤੇ ਸੀਮਾਵਾਂ ਨੂੰ ਦਰਸਾਉਂਦੇ ਹਨ।

ਮੇਰਾ ਅਨੁਮਾਨ ਹੈ ਕਿ ਹਰ ਐਕਸਲ ਉਪਭੋਗਤਾ ਜਾਣਦਾ ਹੈ ਕਿ ਐਕਸਲ ਵਿੱਚ ਕਿਹੜਾ ਫੰਕਸ਼ਨ ਵਰਟੀਕਲ ਲੁੱਕਅਪ ਕਰਦਾ ਹੈ। ਠੀਕ ਹੈ, ਇਹ VLOOKUP ਹੈ। ਹਾਲਾਂਕਿ, ਬਹੁਤ ਘੱਟ ਲੋਕ ਜਾਣਦੇ ਹਨ ਕਿ ਐਕਸਲ ਦਾ VLOOKUP ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਹੈ, ਭਾਵ ਇਹ ਛੋਟੇ ਅੱਖਰਾਂ ਅਤੇ ਵੱਡੇ ਅੱਖਰਾਂ ਨੂੰ ਇੱਕੋ ਜਿਹੇ ਅੱਖਰ ਸਮਝਦਾ ਹੈ।

ਇੱਥੇ ਇੱਕ ਤੇਜ਼ ਉਦਾਹਰਨ ਹੈ ਜੋ ਟੈਕਸਟ ਕੇਸ ਨੂੰ ਵੱਖ ਕਰਨ ਵਿੱਚ VLOOKUP ਦੀ ਅਯੋਗਤਾ ਨੂੰ ਦਰਸਾਉਂਦੀ ਹੈ। ਮੰਨ ਲਓ ਜੇਕਰ ਤੁਹਾਡੇ ਕੋਲ ਸੈੱਲ A2 ਵਿੱਚ "ਬਿੱਲ" ਅਤੇ A4 ਵਿੱਚ "ਬਿੱਲ" ਹੈ। ਹੇਠਾਂ ਦਿੱਤਾ ਫਾਰਮੂਲਾ "ਬਿੱਲ" ਨੂੰ ਫੜੇਗਾ ਕਿਉਂਕਿ ਇਹ ਲੁੱਕਅੱਪ ਐਰੇ ਵਿੱਚ ਸਭ ਤੋਂ ਪਹਿਲਾਂ ਆਉਂਦਾ ਹੈ ਅਤੇ B2 ਤੋਂ ਇੱਕ ਮੇਲ ਖਾਂਦਾ ਮੁੱਲ ਵਾਪਸ ਕਰਦਾ ਹੈ।

=VLOOKUP("Bill", A2:B4, 2, FALSE)

ਇਸ ਵਿੱਚ ਅੱਗੇ ਲੇਖ, ਮੈਂ ਤੁਹਾਨੂੰ VLOOKUP ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਬਣਾਉਣ ਦਾ ਤਰੀਕਾ ਦਿਖਾਵਾਂਗਾ। ਅਸੀਂ ਕੁਝ ਹੋਰ ਫੰਕਸ਼ਨਾਂ ਦੀ ਵੀ ਪੜਚੋਲ ਕਰਾਂਗੇ ਜੋ Excel ਵਿੱਚ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਮੈਚ ਕਰ ਸਕਦੇ ਹਨ।

ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ VLOOKUP ਫਾਰਮੂਲਾ

ਜਿਵੇਂ ਉੱਪਰ ਦੱਸਿਆ ਗਿਆ ਹੈ, ਇੱਕ ਆਮ VLOOKUP ਫਾਰਮੂਲਾ ਅੱਖਰ ਕੇਸ ਦੀ ਪਛਾਣ ਨਹੀਂ ਕਰਦਾ। ਹਾਲਾਂਕਿ, Excel VLOOKUP ਨੂੰ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਬਣਾਉਣ ਦਾ ਇੱਕ ਤਰੀਕਾ ਹੈ, ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੀ ਉਦਾਹਰਨ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ।

ਮੰਨ ਲਓ ਕਿ ਤੁਹਾਡੇ ਕੋਲ ਕਾਲਮ A ਵਿੱਚ ਆਈਟਮ IDs ਹਨ ਅਤੇ ਤੁਸੀਂ ਆਈਟਮ ਦੀ ਕੀਮਤ ਅਤੇ ਟਿੱਪਣੀ ਨੂੰ ਖਿੱਚਣਾ ਚਾਹੁੰਦੇ ਹੋ। ਕਾਲਮ B ਅਤੇ C ਤੋਂ। ਸਮੱਸਿਆ ਇਹ ਹੈ ਕਿ ID ਵਿੱਚ ਛੋਟੇ ਅਤੇ ਵੱਡੇ ਅੱਖਰ ਸ਼ਾਮਲ ਹੁੰਦੇ ਹਨ। ਉਦਾਹਰਨ ਲਈ, A4 (001Tvci3u) ਅਤੇ A5 (001Tvci3U) ਦੇ ਮੁੱਲ ਸਿਰਫ਼ ਇਸ ਵਿੱਚ ਵੱਖਰੇ ਹਨਆਖਰੀ ਅੱਖਰ, "u" ਅਤੇ "U", ਕ੍ਰਮਵਾਰ।

ਜਦੋਂ "001Tvci3 U " ਨੂੰ ਦੇਖਦੇ ਹੋ, ਤਾਂ ਇੱਕ ਮਿਆਰੀ VLOOKUP ਫਾਰਮੂਲਾ $90 ਦਾ ਆਉਟਪੁੱਟ ਕਰਦਾ ਹੈ ਜੋ ਕਿ "001Tvci3 u ਨਾਲ ਸੰਬੰਧਿਤ ਹੈ। " ਕਿਉਂਕਿ ਇਹ ਲੁੱਕਅੱਪ ਐਰੇ ਵਿੱਚ "001Tvci3 U " ਤੋਂ ਪਹਿਲਾਂ ਆਉਂਦਾ ਹੈ। ਪਰ ਇਹ ਉਹ ਨਹੀਂ ਹੈ ਜੋ ਤੁਸੀਂ ਚਾਹੁੰਦੇ ਹੋ, ਠੀਕ?

=VLOOKUP(F2, A2:C7, 2, FALSE)

ਐਕਸਲ ਵਿੱਚ ਇੱਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ ਕਰਨ ਲਈ, ਅਸੀਂ VLOOKUP, CHOOSE ਅਤੇ EXACT ਨੂੰ ਜੋੜਦੇ ਹਾਂ ਫੰਕਸ਼ਨ:

ਇਹ ਆਮ ਫਾਰਮੂਲਾ ਸਾਰੀਆਂ ਸਥਿਤੀਆਂ ਵਿੱਚ ਪੂਰੀ ਤਰ੍ਹਾਂ ਕੰਮ ਕਰਦਾ ਹੈ। ਤੁਸੀਂ ਸੱਜੇ ਤੋਂ ਖੱਬੇ ਨੂੰ ਵੀ ਦੇਖ ਸਕਦੇ ਹੋ, ਜੋ ਕਿ ਇੱਕ ਨਿਯਮਤ VLOOKUP ਫਾਰਮੂਲਾ ਕਰਨ ਵਿੱਚ ਅਸਮਰੱਥ ਹੈ। ਇਸ ਸਰਲ ਅਤੇ ਸ਼ਾਨਦਾਰ ਹੱਲ ਦਾ ਸੁਝਾਅ ਦੇਣ ਲਈ ਪੂਰੀਆ ਦਾ ਧੰਨਵਾਦ!

ਸਾਡੇ ਕੇਸ ਵਿੱਚ, ਅਸਲ ਫਾਰਮੂਲੇ ਇਸ ਤਰ੍ਹਾਂ ਹਨ।

ਕੀਮਤ ਨੂੰ F3 ਵਿੱਚ ਖਿੱਚਣ ਲਈ:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

ਟਿੱਪਣੀ F4 ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

ਨੋਟ। ਐਕਸਲ 365 ਤੋਂ ਇਲਾਵਾ ਹੋਰ ਸਾਰੇ ਐਕਸਲ ਸੰਸਕਰਣਾਂ ਵਿੱਚ, ਇਹ ਸਿਰਫ ਇੱਕ ਐਰੇ ਫਾਰਮੂਲੇ ਦੇ ਤੌਰ 'ਤੇ ਕੰਮ ਕਰਦਾ ਹੈ, ਇਸਲਈ ਇਸਨੂੰ ਸਹੀ ਢੰਗ ਨਾਲ ਪੂਰਾ ਕਰਨ ਲਈ Ctrl + Shift + Enter ਦਬਾਓ। ਐਕਸਲ 365 ਵਿੱਚ, ਗਤੀਸ਼ੀਲ ਐਰੇ ਦੇ ਸਮਰਥਨ ਦੇ ਕਾਰਨ, ਇਹ ਇੱਕ ਨਿਯਮਤ ਫਾਰਮੂਲੇ ਵਜੋਂ ਵੀ ਕੰਮ ਕਰਦਾ ਹੈ।

ਇਹ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ:

ਮੁੱਖ ਹਿੱਸਾ ਜੋ ਟ੍ਰਿਕ ਕਰਦਾ ਹੈ ਉਹ ਹੈ ਨੇਸਟਡ EXACT ਦੇ ਨਾਲ ਫਾਰਮੂਲਾ ਚੁਣੋ:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

ਇੱਥੇ, EXACT ਫੰਕਸ਼ਨ F2 ਵਿੱਚ ਮੁੱਲ ਦੀ A2:A7 ਵਿੱਚ ਹਰੇਕ ਮੁੱਲ ਨਾਲ ਤੁਲਨਾ ਕਰਦਾ ਹੈ ਅਤੇ ਜੇਕਰ ਉਹ ਅੱਖਰ ਕੇਸ ਸਮੇਤ ਬਿਲਕੁਲ ਇੱਕੋ ਜਿਹੇ ਹਨ ਤਾਂ TRUE ਵਾਪਸ ਕਰਦਾ ਹੈ,FALSE ਨਹੀਂ ਤਾਂ:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

CHOOSE ਦੇ index_num ਆਰਗੂਮੈਂਟ ਲਈ, ਅਸੀਂ ਐਰੇ ਸਥਿਰ {1,2} ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ। ਨਤੀਜੇ ਵਜੋਂ, ਫੰਕਸ਼ਨ ਉਪਰੋਕਤ ਐਰੇ ਤੋਂ ਲਾਜ਼ੀਕਲ ਮੁੱਲਾਂ ਅਤੇ C2:C7 ਦੇ ਮੁੱਲਾਂ ਨੂੰ ਇਸ ਤਰ੍ਹਾਂ ਇੱਕ ਦੋ-ਅਯਾਮੀ ਐਰੇ ਵਿੱਚ ਜੋੜਦਾ ਹੈ:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP ਫੰਕਸ਼ਨ ਇਸ ਨੂੰ ਉੱਥੋਂ ਲੈਂਦਾ ਹੈ। ਅਤੇ 2-ਅਯਾਮੀ ਐਰੇ ਦੇ 1ਲੇ ਕਾਲਮ ਵਿੱਚ ਖੋਜ ਮੁੱਲ (ਜੋ ਕਿ ਸੱਚ ਹੈ) ਦੀ ਖੋਜ ਕਰਦਾ ਹੈ (ਲਾਜ਼ੀਕਲ ਮੁੱਲਾਂ ਦੁਆਰਾ ਪ੍ਰਸਤੁਤ ਕੀਤਾ ਜਾਂਦਾ ਹੈ) ਅਤੇ ਦੂਜੇ ਕਾਲਮ ਤੋਂ ਇੱਕ ਮੇਲ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਜਿਸ ਦੀ ਕੀਮਤ ਅਸੀਂ ਲੱਭ ਰਹੇ ਹਾਂ:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ XLOOKUP ਫਾਰਮੂਲਾ

Microsoft 365 ਗਾਹਕ ਐਕਸਲ ਵਿੱਚ ਇੱਕ ਸਧਾਰਨ ਫਾਰਮੂਲੇ ਦੇ ਨਾਲ ਇੱਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਲੁੱਕਅੱਪ ਕਰ ਸਕਦੇ ਹਨ। ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਅੰਦਾਜ਼ਾ ਲਗਾ ਸਕਦੇ ਹੋ, ਮੈਂ VLOOKUP ਦੇ ਵਧੇਰੇ ਸ਼ਕਤੀਸ਼ਾਲੀ ਉੱਤਰਾਧਿਕਾਰੀ - XLOOKUP ਫੰਕਸ਼ਨ ਬਾਰੇ ਗੱਲ ਕਰ ਰਿਹਾ ਹਾਂ।

ਕਿਉਂਕਿ XLOOKUP ਵੱਖਰੇ ਤੌਰ 'ਤੇ ਲੁੱਕਅਪ ਅਤੇ ਵਾਪਸੀ ਐਰੇ 'ਤੇ ਕੰਮ ਕਰਦਾ ਹੈ, ਸਾਨੂੰ ਪਿਛਲੇ ਤੋਂ ਦੋ-ਅਯਾਮੀ ਐਰੇ ਟ੍ਰਿਕ ਦੀ ਲੋੜ ਨਹੀਂ ਹੈ। ਉਦਾਹਰਨ. ਬਸ, lookup_array ਆਰਗੂਮੈਂਟ ਲਈ EXACT ਦੀ ਵਰਤੋਂ ਕਰੋ:

ਆਖਰੀ ਆਰਗੂਮੈਂਟ ("ਨਹੀਂ ਮਿਲਿਆ") ਵਿਕਲਪਿਕ ਹੈ। ਇਹ ਸਿਰਫ਼ ਪਰਿਭਾਸ਼ਿਤ ਕਰਦਾ ਹੈ ਕਿ ਜੇਕਰ ਕੋਈ ਮੇਲ ਨਹੀਂ ਮਿਲਦਾ ਤਾਂ ਕਿਹੜਾ ਮੁੱਲ ਵਾਪਸ ਕਰਨਾ ਹੈ। ਜੇਕਰ ਤੁਸੀਂ ਇਸਨੂੰ ਛੱਡ ਦਿੰਦੇ ਹੋ, ਤਾਂ ਇੱਕ ਮਿਆਰੀ #N/A ਗਲਤੀ ਵਾਪਸ ਕੀਤੀ ਜਾਵੇਗੀ ਜੇਕਰ ਫਾਰਮੂਲਾ ਕੁਝ ਨਹੀਂ ਲੱਭਦਾ।

ਸਾਡੀ ਨਮੂਨਾ ਸਾਰਣੀ ਲਈ, ਇਹ ਵਰਤਣ ਲਈ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ XLOOKUP ਫਾਰਮੂਲੇ ਹਨ।

F3 ਵਿੱਚ ਕੀਮਤ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

ਐਕਸਟਰੈਕਟ ਕਰਨ ਲਈਟਿੱਪਣੀ F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

ਇਹ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ:

ਪਿਛਲੀ ਉਦਾਹਰਨ ਦੀ ਤਰ੍ਹਾਂ, EXACT ਰਿਟਰਨ TRUE ਅਤੇ FALSE ਮੁੱਲਾਂ ਦੀ ਇੱਕ ਲੜੀ, ਜਿੱਥੇ TRUE ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਮੈਚਾਂ ਨੂੰ ਦਰਸਾਉਂਦਾ ਹੈ। XLOOKUP TRUE ਮੁੱਲ ਲਈ ਉਪਰੋਕਤ ਐਰੇ ਦੀ ਖੋਜ ਕਰਦਾ ਹੈ ਅਤੇ return_array ਤੋਂ ਮੈਚ ਵਾਪਸ ਕਰਦਾ ਹੈ। ਕਿਰਪਾ ਕਰਕੇ ਨੋਟ ਕਰੋ, ਜੇਕਰ ਲੁੱਕਅਪ ਕਾਲਮ (ਲੈਟਰ ਕੇਸ ਸਮੇਤ) ਵਿੱਚ ਦੋ ਜਾਂ ਦੋ ਤੋਂ ਵੱਧ ਇੱਕੋ ਜਿਹੇ ਮੁੱਲ ਹਨ, ਤਾਂ ਫਾਰਮੂਲਾ ਪਹਿਲਾ ਪਾਇਆ ਗਿਆ ਮੇਲ ਵਾਪਸ ਕਰੇਗਾ।

XLOOKUP ਸੀਮਾ : ਸਿਰਫ਼ ਉਪਲਬਧ Excel 365 ਅਤੇ Excel 2021 ਵਿੱਚ।

SUMPRODUCT - ਮੇਲ ਖਾਂਦੇ ਨੰਬਰਾਂ ਨੂੰ ਵਾਪਸ ਕਰਨ ਲਈ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਲੁੱਕਅੱਪ

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਸਿਰਲੇਖ ਤੋਂ ਸਮਝਦੇ ਹੋ, SUMPRODUCT ਇੱਕ ਹੋਰ ਐਕਸਲ ਫੰਕਸ਼ਨ ਹੈ ਜੋ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਲੁੱਕਅੱਪ ਕਰ ਸਕਦਾ ਹੈ। , ਪਰ ਇਹ ਸਿਰਫ਼ ਸੰਖਿਆਤਮਕ ਮੁੱਲ ਵਾਪਸ ਕਰ ਸਕਦਾ ਹੈ। ਜੇਕਰ ਇਹ ਤੁਹਾਡਾ ਮਾਮਲਾ ਨਹੀਂ ਹੈ, ਤਾਂ INDEX MATCH ਉਦਾਹਰਨ 'ਤੇ ਜਾਓ ਜੋ ਸਾਰੀਆਂ ਡਾਟਾ ਕਿਸਮਾਂ ਲਈ ਇੱਕ ਹੱਲ ਪ੍ਰਦਾਨ ਕਰਦਾ ਹੈ।

ਜਿਵੇਂ ਕਿ ਤੁਸੀਂ ਸ਼ਾਇਦ ਜਾਣਦੇ ਹੋ, Excel ਦਾ SUMPRODUCT ਨਿਰਧਾਰਤ ਐਰੇ ਵਿੱਚ ਭਾਗਾਂ ਨੂੰ ਗੁਣਾ ਕਰਦਾ ਹੈ ਅਤੇ ਉਤਪਾਦਾਂ ਦਾ ਜੋੜ ਵਾਪਸ ਕਰਦਾ ਹੈ। ਕਿਉਂਕਿ ਅਸੀਂ ਇੱਕ ਕੇਸ ਸੰਵੇਦੀ ਲੁੱਕਅੱਪ ਚਾਹੁੰਦੇ ਹਾਂ, ਅਸੀਂ ਪਹਿਲੀ ਐਰੇ ਪ੍ਰਾਪਤ ਕਰਨ ਲਈ EXACT ਫੰਕਸ਼ਨ ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

ਅਫ਼ਸੋਸ ਦੀ ਗੱਲ ਹੈ ਕਿ SUMPRODUCT ਫੰਕਸ਼ਨ ਟੈਕਸਟ ਮੈਚਾਂ ਨੂੰ ਵਾਪਸ ਨਹੀਂ ਕਰ ਸਕਦਾ ਕਿਉਂਕਿ ਟੈਕਸਟ ਮੁੱਲਾਂ ਨੂੰ ਗੁਣਾ ਨਹੀਂ ਕੀਤਾ ਜਾ ਸਕਦਾ ਹੈ। ਇਸ ਸਥਿਤੀ ਵਿੱਚ, ਤੁਹਾਨੂੰ ਇੱਕ #VALUE ਪ੍ਰਾਪਤ ਹੋਵੇਗਾ! ਹੇਠ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ੌਟ ਵਿੱਚ ਸੈੱਲ F4 ਵਿੱਚ ਗਲਤੀ:

ਇਹ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ:

VLOOKUP ਉਦਾਹਰਨ ਦੀ ਤਰ੍ਹਾਂ, ਬਿਲਕੁਲ ਫੰਕਸ਼ਨ ਜਾਂਚਾਂA2:A7 ਦੇ ਸਾਰੇ ਮੁੱਲਾਂ ਦੇ ਵਿਰੁੱਧ F2 ਵਿੱਚ ਮੁੱਲ ਅਤੇ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਮੈਚਾਂ ਲਈ TRUE ਦਿੰਦਾ ਹੈ, ਨਹੀਂ ਤਾਂ FALSE:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

ਜ਼ਿਆਦਾਤਰ ਫਾਰਮੂਲਿਆਂ ਵਿੱਚ, Excel TRUE ਨੂੰ 1 ਅਤੇ FALSE ਨੂੰ 0 ਦਾ ਮੁਲਾਂਕਣ ਕਰਦਾ ਹੈ। ਇਸ ਲਈ, ਜਦੋਂ SUMPRODUCT ਦੋ ਐਰੇ ਦੇ ਤੱਤਾਂ ਨੂੰ ਇੱਕੋ ਸਥਿਤੀ ਵਿੱਚ ਗੁਣਾ ਕਰਦਾ ਹੈ, ਤਾਂ ਸਾਰੇ ਗੈਰ-ਮੇਲ (FALSE) ਜ਼ੀਰੋ ਬਣ ਜਾਂਦੇ ਹਨ:

SUMPRODUCT({0;0;0;54;0;0})

ਨਤੀਜੇ ਵਜੋਂ, ਫਾਰਮੂਲਾ ਇਸ ਤੋਂ ਇੱਕ ਨੰਬਰ ਦਿੰਦਾ ਹੈ ਕਾਲਮ B ਜੋ ਕਾਲਮ A ਵਿੱਚ ਸਹੀ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਮੈਚ ਨਾਲ ਮੇਲ ਖਾਂਦਾ ਹੈ।

SUMPRODUCT ਸੀਮਾ : ਸਿਰਫ ਸੰਖਿਆਤਮਕ ਮੁੱਲ ਵਾਪਸ ਕਰ ਸਕਦਾ ਹੈ।

INDEX MATCH - ਲਈ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਖੋਜ ਸਾਰੀਆਂ ਡਾਟਾ ਕਿਸਮਾਂ

ਅੰਤ ਵਿੱਚ, ਅਸੀਂ ਇੱਕ ਸੀਮਾ-ਮੁਕਤ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਲੁੱਕਅਪ ਫਾਰਮੂਲਾ ਪ੍ਰਾਪਤ ਕਰਨ ਦੇ ਨੇੜੇ ਹਾਂ ਜੋ ਸਾਰੇ ਐਕਸਲ ਸੰਸਕਰਣਾਂ ਅਤੇ ਸਾਰੇ ਡੇਟਾ ਸੈੱਟਾਂ ਵਿੱਚ ਕੰਮ ਕਰਦਾ ਹੈ।

ਇਹ ਉਦਾਹਰਨ ਸਿਰਫ਼ ਇਸ ਲਈ ਨਹੀਂ ਕਿ ਆਖਰੀ ਹੈ। ਸਭ ਤੋਂ ਵਧੀਆ ਨੂੰ ਆਖਰੀ ਲਈ ਸੁਰੱਖਿਅਤ ਕੀਤਾ ਜਾਂਦਾ ਹੈ, ਪਰ ਇਹ ਵੀ ਕਿਉਂਕਿ ਪਿਛਲੀਆਂ ਉਦਾਹਰਣਾਂ ਵਿੱਚ ਤੁਸੀਂ ਜੋ ਗਿਆਨ ਪ੍ਰਾਪਤ ਕੀਤਾ ਹੈ, ਉਹ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਮੈਚ INDEX ਫਾਰਮੂਲੇ ਨੂੰ ਬਿਹਤਰ ਤਰੀਕੇ ਨਾਲ ਸਮਝਣ ਵਿੱਚ ਤੁਹਾਡੀ ਮਦਦ ਕਰ ਸਕਦਾ ਹੈ।

INDEX ਅਤੇ MATCH ਫੰਕਸ਼ਨਾਂ ਦਾ ਸੁਮੇਲ ਅਕਸਰ ਵਰਤਿਆ ਜਾਂਦਾ ਹੈ ਸਾਬਕਾ ਵਿੱਚ cel VLOOKUP ਦੇ ਇੱਕ ਵਧੇਰੇ ਲਚਕਦਾਰ ਅਤੇ ਬਹੁਮੁਖੀ ਵਿਕਲਪ ਵਜੋਂ। ਹੇਠਾਂ ਦਿੱਤਾ ਲੇਖ ਚੰਗਾ ਕੰਮ ਕਰਦਾ ਹੈ (ਉਮੀਦ ਹੈ :) ਇਹ ਦੱਸਦਾ ਹੈ ਕਿ ਇਹ ਦੋਵੇਂ ਫੰਕਸ਼ਨ ਇਕੱਠੇ ਕਿਵੇਂ ਕੰਮ ਕਰਦੇ ਹਨ - VLOOKUP ਦੀ ਬਜਾਏ INDEX MATCH ਦੀ ਵਰਤੋਂ ਕਰਨਾ।

ਇੱਥੇ, ਮੈਂ ਤੁਹਾਨੂੰ ਮੁੱਖ ਨੁਕਤੇ ਯਾਦ ਕਰਾਵਾਂਗਾ:

• MATCH ਫੰਕਸ਼ਨ ਨਿਸ਼ਚਿਤ ਲੁੱਕਅਪ ਐਰੇ ਵਿੱਚ ਲੁੱਕਅਪ ਵੈਲਯੂ ਦੀ ਖੋਜ ਕਰਦਾ ਹੈ ਅਤੇ ਇਸਦੀ ਸੰਬੰਧਿਤ ਸਥਿਤੀ ਨੂੰ ਵਾਪਸ ਕਰਦਾ ਹੈ।
• ਰਿਲੇਟਿਡਲੁੱਕਅਪ ਵੈਲਯੂ ਦੀ ਸਥਿਤੀ INDEX ਫੰਕਸ਼ਨ ਦੇ row_num ਆਰਗੂਮੈਂਟ 'ਤੇ ਜਾਂਦੀ ਹੈ ਜੋ ਇਸਨੂੰ ਉਸ ਕਤਾਰ ਤੋਂ ਇੱਕ ਮੁੱਲ ਵਾਪਸ ਕਰਨ ਲਈ ਨਿਰਦੇਸ਼ ਦਿੰਦੀ ਹੈ।

ਟੈਕਸਟ ਕੇਸ ਦੀ ਪਛਾਣ ਕਰਨ ਲਈ ਫਾਰਮੂਲੇ ਲਈ, ਤੁਸੀਂ ਸਿਰਫ਼ ਕਲਾਸਿਕ INDEX MATCH ਸੁਮੇਲ ਵਿੱਚ ਇੱਕ ਹੋਰ ਫੰਕਸ਼ਨ ਜੋੜਨ ਦੀ ਲੋੜ ਹੈ। ਸਪੱਸ਼ਟ ਤੌਰ 'ਤੇ, ਤੁਹਾਨੂੰ ਦੁਬਾਰਾ EXACT ਫੰਕਸ਼ਨ ਦੀ ਲੋੜ ਹੈ:

F3 ਵਿੱਚ ਅਸਲ ਫਾਰਮੂਲਾ ਹੈ:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

F4 ਵਿੱਚ, ਅਸੀਂ ਇਸ ਦੀ ਵਰਤੋਂ ਕਰ ਰਹੇ ਹਾਂ:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

ਕਿਰਪਾ ਕਰਕੇ ਯਾਦ ਰੱਖੋ ਕਿ ਇਹ ਸਿਰਫ ਇਸ ਤਰ੍ਹਾਂ ਕੰਮ ਕਰਦਾ ਹੈ ਐਕਸਲ 365 ਤੋਂ ਇਲਾਵਾ ਹੋਰ ਸਾਰੇ ਸੰਸਕਰਣਾਂ ਵਿੱਚ ਇੱਕ ਐਰੇ ਫਾਰਮੂਲਾ, ਇਸਲਈ Ctrl + Shift + Enter ਕੁੰਜੀਆਂ ਨੂੰ ਇਕੱਠੇ ਦਬਾ ਕੇ ਇਸਨੂੰ ਦਾਖਲ ਕਰਨਾ ਯਕੀਨੀ ਬਣਾਓ। ਜੇਕਰ ਸਹੀ ਢੰਗ ਨਾਲ ਕੀਤਾ ਜਾਵੇ, ਤਾਂ ਫਾਰਮੂਲਾ ਕਰਲੀ ਬਰੇਸ ਵਿੱਚ ਬੰਦ ਹੋ ਜਾਵੇਗਾ ਜਿਵੇਂ ਕਿ ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਵਿੱਚ ਦਿਖਾਇਆ ਗਿਆ ਹੈ:

ਇਹ ਫਾਰਮੂਲਾ ਕਿਵੇਂ ਕੰਮ ਕਰਦਾ ਹੈ:

ਪਿਛਲੀਆਂ ਸਾਰੀਆਂ ਉਦਾਹਰਣਾਂ ਵਾਂਗ, EXACT A2:A7 ਵਿੱਚ ਹਰੇਕ ਮੁੱਲ ਲਈ TRUE ਦਿੰਦਾ ਹੈ ਜੋ F2 ਵਿੱਚ ਮੁੱਲ ਨਾਲ ਬਿਲਕੁਲ ਮੇਲ ਖਾਂਦਾ ਹੈ। ਕਿਉਂਕਿ ਅਸੀਂ ਮੈਚ ਦੇ lookup_value ਲਈ TRUE ਦੀ ਵਰਤੋਂ ਕਰਦੇ ਹਾਂ, ਇਹ ਸਟੀਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਮੈਚ ਦੀ ਇੱਕ ਸੰਬੰਧਿਤ ਸਥਿਤੀ ਵਾਪਸ ਕਰਦਾ ਹੈ, ਜੋ ਕਿ INDEX ਨੂੰ B2:B7 ਤੋਂ ਮੈਚ ਵਾਪਸ ਕਰਨ ਲਈ ਲੋੜੀਂਦਾ ਹੈ।

ਐਡਵਾਂਸਡ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਲੁੱਕਅਪ ਫਾਰਮੂਲਾ

ਉਪਰੋਕਤ INDEX MATCH ਫਾਰਮੂਲਾ ਸੰਪੂਰਨ ਦਿਖਾਈ ਦਿੰਦਾ ਹੈ, ਠੀਕ ਹੈ? ਪਰ ਅਸਲ ਵਿੱਚ, ਇਹ ਨਹੀਂ ਹੈ. ਆਓ ਮੈਂ ਤੁਹਾਨੂੰ ਦਿਖਾਵਾਂ ਕਿ ਕਿਉਂ।

ਮੰਨ ਲਓ ਕਿ ਖੋਜ ਮੁੱਲ ਨਾਲ ਸੰਬੰਧਿਤ ਵਾਪਸੀ ਕਾਲਮ ਵਿੱਚ ਇੱਕ ਸੈੱਲ ਖਾਲੀ ਹੈ। ਫਾਰਮੂਲਾ ਕੀ ਵਾਪਸ ਕਰੇਗਾ? ਕੁਝ ਨਹੀਂ।ਅਤੇ ਹੁਣ, ਆਓ ਦੇਖੀਏ ਕਿ ਇਹ ਅਸਲ ਵਿੱਚ ਕੀ ਵਾਪਸ ਕਰਦਾ ਹੈ:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

ਓਹ, ਫਾਰਮੂਲਾ ਇੱਕ ਜ਼ੀਰੋ ਵਾਪਸ ਕਰਦਾ ਹੈ! ਹੋ ਸਕਦਾ ਹੈ, ਇਹ ਅਸਲ ਵਿੱਚ ਮਹੱਤਵਪੂਰਨ ਨਹੀਂ ਹੈ ਜਦੋਂ ਸਿਰਫ਼ ਟੈਕਸਟ ਮੁੱਲਾਂ ਨਾਲ ਨਜਿੱਠਣਾ ਹੋਵੇ. ਹਾਲਾਂਕਿ, ਜੇਕਰ ਤੁਹਾਡੀ ਵਰਕਸ਼ੀਟ ਵਿੱਚ ਸੰਖਿਆਵਾਂ ਹਨ ਅਤੇ ਉਹਨਾਂ ਵਿੱਚੋਂ ਕੁਝ ਅਸਲ ਜ਼ੀਰੋ ਹਨ, ਤਾਂ ਇਹ ਇੱਕ ਸਮੱਸਿਆ ਹੈ।

ਸੱਚ ਵਿੱਚ, ਪਹਿਲਾਂ ਵਿਚਾਰੇ ਗਏ ਹੋਰ ਸਾਰੇ ਲੁੱਕਅਪ ਫਾਰਮੂਲੇ ਉਸੇ ਤਰ੍ਹਾਂ ਵਿਵਹਾਰ ਕਰਦੇ ਹਨ। ਪਰ ਹੁਣ ਤੁਸੀਂ ਇੱਕ ਨਿਰਦੋਸ਼ ਫਾਰਮੂਲਾ ਚਾਹੁੰਦੇ ਹੋ, ਕੀ ਤੁਸੀਂ ਨਹੀਂ?

ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ INDEX MATCH ਫਾਰਮੂਲੇ ਨੂੰ ਬਿਲਕੁਲ ਸੰਪੂਰਨ ਬਣਾਉਣ ਲਈ, ਤੁਸੀਂ ਇਸਨੂੰ IF ਫੰਕਸ਼ਨ ਵਿੱਚ ਲਪੇਟਦੇ ਹੋ ਜੋ ਇਹ ਜਾਂਚਦਾ ਹੈ ਕਿ ਇੱਕ ਰਿਟਰਨ ਸੈੱਲ ਖਾਲੀ ਹੈ ਜਾਂ ਨਹੀਂ ਅਤੇ ਇਸ ਵਿੱਚ ਕੁਝ ਨਹੀਂ ਦਿੰਦਾ ਇਹ ਕੇਸ:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

ਉਪਰੋਕਤ ਫਾਰਮੂਲੇ ਵਿੱਚ:

• "C" ਵਾਪਸੀ ਕਾਲਮ ਹੈ।
• "1" ਸੰਖਿਆ ਹੈ। ਜੋ ਕਿ MATCH ਫੰਕਸ਼ਨ ਦੁਆਰਾ ਵਾਪਸ ਕੀਤੇ ਸੈੱਲ ਦੀ ਸਬੰਧਤ ਸਥਿਤੀ ਨੂੰ ਇੱਕ ਅਸਲ ਸੈੱਲ ਪਤੇ ਵਿੱਚ ਬਦਲਦਾ ਹੈ।

ਉਦਾਹਰਨ ਲਈ, ਸਾਡੇ ਮੈਚ ਫੰਕਸ਼ਨ ਵਿੱਚ ਲੁੱਕਅਪ ਐਰੇ A2:A7 ਹੈ, ਭਾਵ ਸੈੱਲ A2 ਦੀ ਰਿਸ਼ਤੇਦਾਰ ਸਥਿਤੀ "1" ਹੈ, ਕਿਉਂਕਿ ਇਹ ਐਰੇ ਵਿੱਚ ਪਹਿਲਾ ਸੈੱਲ ਹੈ। ਪਰ ਅਸਲ ਵਿੱਚ, ਲੁੱਕਅਪ ਐਰੇ ਕਤਾਰ 2 ਵਿੱਚ ਸ਼ੁਰੂ ਹੁੰਦਾ ਹੈ। ਅੰਤਰ ਦੀ ਪੂਰਤੀ ਕਰਨ ਲਈ, ਅਸੀਂ 1 ਜੋੜਦੇ ਹਾਂ, ਇਸਲਈ INDIRECT ਫੰਕਸ਼ਨ ਸਹੀ ਸੈੱਲ ਤੋਂ ਇੱਕ ਮੁੱਲ ਵਾਪਸ ਕਰੇਗਾ।

ਹੇਠਾਂ ਦਿੱਤੇ ਸਕ੍ਰੀਨਸ਼ਾਟ ਸੁਧਾਰੇ ਹੋਏ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ INDEX ਨੂੰ ਦਰਸਾਉਂਦੇ ਹਨ। ਮੇਲ ਖਾਂਦਾ ਫਾਰਮੂਲਾ ਐਕਸ਼ਨ ਵਿੱਚ ਹੈ।

ਜੇਕਰ ਰਿਟਰਨ ਸੈੱਲ ਖਾਲੀ ਹੈ, ਤਾਂ ਫਾਰਮੂਲਾ ਕੁਝ ਵੀ ਨਹੀਂ ਦਿੰਦਾ (ਇੱਕ ਖਾਲੀ ਸਤਰ):

ਜੇਕਰ ਵਾਪਸੀ ਸੈੱਲ ਵਿੱਚ ਇੱਕ ਜ਼ੀਰੋ ਹੈ , ਫਾਰਮੂਲਾ 0 ਵਾਪਸ ਕਰਦਾ ਹੈ:

ਜੇਕਰ ਤੁਸੀਂ ਚਾਹੁੰਦੇ ਹੋਜਦੋਂ ਇੱਕ ਰਿਟਰਨ ਸੈੱਲ ਖਾਲੀ ਹੋਵੇ ਤਾਂ ਕੁਝ ਸੁਨੇਹਾ ਪ੍ਰਦਰਸ਼ਿਤ ਕਰੋ, IF ਦੇ ਆਖਰੀ ਆਰਗੂਮੈਂਟ ਵਿੱਚ ਇੱਕ ਖਾਲੀ ਸਤਰ ("") ਨੂੰ ਕੁਝ ਟੈਕਸਟ ਨਾਲ ਬਦਲੋ:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ VLOOKUP ਨੂੰ ਆਸਾਨ ਤਰੀਕੇ ਨਾਲ ਕਰੋ

ਸਾਡੇ ਐਕਸਲ ਲਈ ਅਲਟੀਮੇਟ ਸੂਟ ਦੇ ਉਪਭੋਗਤਾਵਾਂ ਕੋਲ ਇੱਕ ਵਿਸ਼ੇਸ਼ ਟੂਲ ਹੈ ਜੋ ਵੱਡੇ ਅਤੇ ਗੁੰਝਲਦਾਰ ਟੇਬਲਾਂ ਵਿੱਚ ਦੇਖਣਾ ਆਸਾਨ ਅਤੇ ਤਣਾਅ-ਮੁਕਤ ਬਣਾਉਂਦਾ ਹੈ। ਸਭ ਤੋਂ ਵਧੀਆ ਗੱਲ ਇਹ ਹੈ ਕਿ ਮਰਜ ਟੂ ਟੇਬਲਸ ਵਿੱਚ ਇੱਕ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਵਿਕਲਪ ਹੈ, ਅਤੇ ਹੇਠਾਂ ਦਿੱਤੀ ਉਦਾਹਰਨ ਇਸ ਨੂੰ ਅਮਲ ਵਿੱਚ ਦਰਸਾਉਂਦੀ ਹੈ।

ਮੰਨ ਲਓ ਕਿ ਤੁਸੀਂ Qty ਨੂੰ ਖਿੱਚਣਾ ਚਾਹੁੰਦੇ ਹੋ। ਲੁਕਅੱਪ ਟੇਬਲ ਤੋਂ ਮੁੱਖ ਸਾਰਣੀ ਵਿੱਚ ਵਿਲੱਖਣ ਆਈਟਮ ਆਈਡੀ ਦੇ ਅਧਾਰ ਤੇ:

ਤੁਸੀਂ ਜੋ ਕਰਦੇ ਹੋ ਉਹ ਹੈ ਮਰਜ ਟੇਬਲ ਨੂੰ ਚਲਾਉਣਾ ਵਿਜ਼ਾਰਡ ਅਤੇ ਇਹਨਾਂ ਕਦਮਾਂ ਨੂੰ ਪੂਰਾ ਕਰੋ:

1. ਮੁੱਖ ਸਾਰਣੀ ਦੀ ਚੋਣ ਕਰੋ ਜਿਸ ਵਿੱਚ ਨਵਾਂ ਡੇਟਾ ਖਿੱਚਣਾ ਹੈ।
2. ਲੁੱਕਅਪ ਟੇਬਲ ਦੀ ਚੋਣ ਕਰੋ ਜਿੱਥੇ ਨਵਾਂ ਡੇਟਾ ਲੱਭਣਾ ਹੈ।
3. ਇੱਕ ਜਾਂ ਇੱਕ ਤੋਂ ਵੱਧ ਮੁੱਖ ਕਾਲਮ ਚੁਣੋ (ਸਾਡੇ ਕੇਸ ਵਿੱਚ ਆਈਟਮ ਆਈਡੀ)। ਅਤੇ ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ ਮੈਚਿੰਗ ਬਾਕਸ ਨੂੰ ਚੈੱਕ ਕਰਨਾ ਯਕੀਨੀ ਬਣਾਓ।

ਇੱਕ ਪਲ ਬਾਅਦ, ਤੁਹਾਨੂੰ ਲੋੜੀਂਦਾ ਨਤੀਜਾ ਮਿਲੇਗਾ :)

ਟੈਕਸਟ ਕੇਸ ਨੂੰ ਧਿਆਨ ਵਿੱਚ ਰੱਖਦੇ ਹੋਏ ਐਕਸਲ ਵਿੱਚ ਇਹ ਕਿਵੇਂ ਖੋਜਣਾ ਹੈ। ਮੈਂ ਪੜ੍ਹਨ ਲਈ ਤੁਹਾਡਾ ਧੰਨਵਾਦ ਕਰਦਾ ਹਾਂ ਅਤੇ ਅਗਲੇ ਹਫ਼ਤੇ ਤੁਹਾਨੂੰ ਸਾਡੇ ਬਲੌਗ 'ਤੇ ਮਿਲਣ ਦੀ ਉਮੀਦ ਕਰਦਾ ਹਾਂ!

ਡਾਊਨਲੋਡ ਲਈ ਅਭਿਆਸ ਵਰਕਬੁੱਕ

ਕੇਸ-ਸੰਵੇਦਨਸ਼ੀਲ VLOOKUP ਉਦਾਹਰਨਾਂ (.xlsx ਫਾਈਲ)