Kennsluforritið útskýrir hvernig á að gera Excel VLOOKUP hástafanæmt, sýnir nokkrar aðrar formúlur sem aðgreina stóra og stóra texta og bendir á styrkleika og takmarkanir hverrar aðgerðar.

Ég býst við að allir Excel notandi veit hvaða aðgerð framkvæmir lóðrétta uppflettingu í Excel. Rétt, það er VLOOKUP. Hins vegar eru mjög fáir meðvitaðir um að VLOOKUP í Excel er hástafa-ónæmir, sem þýðir að það meðhöndlar lágstafi og hástafi sem sömu stafi.

Hér er stutt dæmi sem sýnir vanhæfni VLOOKUP til að greina á milli hástafa og hástafa. Segjum að þú hafir "reikning" í reit A2 og "Bill" í A4. Formúlan hér að neðan mun grípa "reikning" vegna þess að hún kemur fyrst í uppflettifylki og skilar samsvarandi gildi frá B2.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

Nánar í þessu grein, mun ég sýna þér leið til að gera VLOOKUP hástafanæmu. Við munum einnig kanna nokkrar aðrar aðgerðir sem geta gert hástafanæmu samsvörun í Excel.

Höfuð- og hástafanæm VLOOKUP formúla

Eins og getið er hér að ofan, venjuleg VLOOKUP formúla kannast ekki við bréfafallið. Hins vegar er leið til að gera Excel VLOOKUP hástafanæm, eins og sýnt er í dæminu hér að neðan.

Segjum að þú sért með vöruauðkenni í dálki A og viljir draga verð vörunnar og athugasemdir úr dálkum B og C. Vandamálið er að auðkenni innihalda bæði lágstafi og hástafi. Til dæmis eru gildin í A4 (001Tvci3u) og A5 (001Tvci3U) aðeins mismunandi ísíðasta stafurinn, "u" og "U", í sömu röð.

Þegar þú flettir upp "001Tvci3 U ", gefur venjuleg VLOOKUP formúla $90 sem tengist "001Tvci3 u " vegna þess að það kemur á undan "001Tvci3 U " í uppflettifylkingunni. En þetta er ekki það sem þú vilt, ekki satt?

=VLOOKUP(F2, A2:C7, 2, FALSE)

Til að framkvæma uppflettingu sem er há- og lágstöfum í Excel sameinum við ÚTLIT, VELJA og EXACT aðgerðir:

Þessi almenna formúla virkar fullkomlega við allar aðstæður. Þú getur jafnvel flett upp frá hægri til vinstri , eitthvað sem venjuleg VLOOKUP formúla getur ekki gert. Hrós til Pouriya fyrir að stinga upp á þessari einföldu og glæsilegu lausn!

Í okkar tilviki eru raunverulegu formúlurnar sem hér segir.

Til að draga verðið í F3:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

Til að sækja athugasemdina F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Athugið. Í öllum Excel útgáfum öðrum en Excel 365 virkar þetta aðeins sem fylkisformúla, svo mundu að ýta á Ctrl + Shift + Enter til að klára það rétt. Í Excel 365, vegna stuðnings við kraftmikla fylki, virkar það einnig sem venjuleg formúla.

Hvernig þessi formúla virkar:

Kjarnihlutinn sem gerir bragðið er VELJA formúlan með hreiðri EXACT:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

Hér, EXACT fallið ber saman gildið í F2 við hvert gildi í A2:A7 og skilar TRUE ef þau eru nákvæmlega eins, þ.mt hástafir,FALSE annars:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

Fyrir index_num röksemdin fyrir CHOOSE notum við fylkisfastann {1,2}. Fyrir vikið sameinar aðgerðin rökfræðilegu gildin úr fylkinu hér að ofan og gildin frá C2:C7 í tvívíddar fylki eins og þetta:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP fallið tekur það þaðan og leitar að uppflettigildinu (sem er TRUE) í 1. dálki tvívíddar fylkisins (táknað með rökréttum gildum) og skilar samsvörun úr 2. dálki, sem er verðið sem við erum að leita að:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Höfuð- og hástöfumnæm XLOOKUP formúla

Microsoft 365 áskrifendur geta leitað í Excel með jafnvel einfaldari formúlu. Eins og þú getur giskað á þá er ég að tala um öflugri arftaka VLOOKUP - XLOOKUP fallið.

Þar sem XLOOKUP starfar á uppfletti og skila fylkjum sérstaklega, þurfum við ekki tvívíddar fylkisbrellur frá fyrri dæmi. Einfaldlega, notaðu EXACT fyrir uppflettisfylki rökin:

Síðasta rökin ("Finn ekki") er valfrjáls. Það skilgreinir bara hvaða gildi á að skila ef engin samsvörun finnst. Ef þú sleppir því, þá mun staðlað #N/A villa skila sér ef formúlan finnur ekkert.

Fyrir sýnishornstöfluna okkar eru þetta XLOOKUP formúlurnar sem eru há- og hástafanæmar til að nota.

Til að fá verðið í F3:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

Til að draga útathugasemd F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

Hvernig þessi formúla virkar:

Eins og í fyrra dæmi, EXACT skilar fylki af TRUE og FALSE gildi, þar sem TRUE táknar samsvörun sem er há og hástöfum. XLOOKUP leitar í fylkinu hér að ofan að TRUE gildinu og skilar samsvörun frá return_array . Vinsamlegast athugið að ef það eru tvö eða fleiri nákvæmlega sömu gildi í uppflettisdálknum (þar á meðal stafsetningu), mun formúlan skila fyrstu samsvöruninni sem fannst.

XLOOKUP takmörkun : aðeins í boði. í Excel 365 og Excel 2021.

SUMPRODUCT - hástafanæm uppfletting til að skila samsvarandi tölum

Eins og þú skilur af fyrirsögninni er SUMPRODUCT enn ein Excel aðgerðin sem getur gert stóra og hástafaviðkvæma uppflettingu , en það getur aðeins skilað tölugildum . Ef þetta er ekki þitt tilfelli skaltu hoppa í INDEX MATCH dæmið sem gefur lausn fyrir allar gagnategundir.

Eins og þú veist líklega margfaldar SUMPRODUCT Excel íhluti í tilgreindum fylkjum og skilar summan af afurðunum. Þar sem við viljum hafa stóra og stóra uppflettingu notum við EXACT fallið til að fá fyrsta fylkið:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

Því miður getur SUMPRODUCT fallið ekki skilað textasamsvörun þar sem ekki er hægt að margfalda textagildi. Í þessu tilfelli færðu #VALUE! villa eins og í reit F4 á skjámyndinni hér að neðan:

Hvernig þessi formúla virkar:

Eins og í VLOOKUP dæminu, EXACT virkni athuganirgildið í F2 á móti öllum gildunum í A2:A7 og skilar TRUE fyrir samsvörun sem eru há og hástafir, FALSE annars:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

Í flestum formúlum metur Excel TRUE í 1 og FALSE í 0 Svo, þegar SUMPRODUCT margfaldar þætti fylkianna tveggja í sömu stöðu, verða allar ósamsvörun (FALSE) núll:

SUMPRODUCT({0;0;0;54;0;0})

Svo sem afleiðingin skilar formúlan tölu frá dálkur B sem samsvarar nákvæmri samsvörun í dálki A.

SUMPRODUCT takmörkun : getur aðeins skilað tölugildum.

INDEX MATCH - hástafanæm uppflettingu fyrir allar gagnategundir

Loksins erum við nálægt því að fá takmörkunarlausa uppflettingarformúlu sem virkar í öllum Excel útgáfum og öllum gagnasettum.

Þetta dæmi kemur síðast ekki aðeins vegna þess að það besta er vistað í það síðasta, en einnig vegna þess að þekkingin sem þú hefur aflað þér í fyrri dæmum getur hjálpað þér að skilja betur hástafanæmu MATCH INDEX formúlu.

Samsetning INDEX og MATCH falla er oft notuð. í Ex cel sem sveigjanlegri og fjölhæfari valkostur við VLOOKUP. Eftirfarandi grein gerir gott starf (vonandi :) og útskýrir hvernig þessar tvær aðgerðir vinna saman - Notkun INDEX MATCH í stað VLOOKUP.

Hér mun ég bara minna þig á lykilatriðin:

• MATCH aðgerðin leitar að uppflettigildinu í tilgreindu uppflettifylki og skilar hlutfallslegri stöðu þess.
• Hið hlutfallslegastaðsetning uppflettigildisins fer beint í row_num röksemdin í INDEX fallinu sem gefur fyrirmæli um að skila gildi úr þeirri línu.

Til þess að formúlan þekki stóra og stóra texta þarftu bara þarf að bæta einni aðgerð í viðbót við hina klassísku INDEX MATCH samsetningu. Augljóslega þarftu EXACT aðgerðina aftur:

Raunverulega formúlan í F3 er:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Í F4 erum við að nota þessa:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Vinsamlegast mundu að það virkar bara sem fylkisformúla í öllum öðrum útgáfum en Excel 365, svo vertu viss um að slá hana inn með því að ýta á Ctrl + Shift + Enter takkana saman. Ef það er gert á réttan hátt mun formúlan verða umlukin krulluðum axlaböndum eins og sýnt er á skjámyndinni hér að neðan:

Hvernig þessi formúla virkar:

Eins og í öllum fyrri dæmum, EXACT skilar TRUE fyrir hvert gildi í A2:A7 sem passar nákvæmlega við gildið í F2. Þar sem við notum TRUE fyrir uppflettingargildið í MATCH, þá skilar það hlutfallslegri stöðu hinnar nákvæmu samsvörunar sem er há- og hástöfum, sem er nákvæmlega það sem INDEX þarf til að skila samsvörun frá B2:B7.

Háþróuð upplitsformúla með hástöfum og hástöfum

Ofnefnd INDEX MATCH formúla lítur fullkomlega út, ekki satt? En í raun er það ekki. Leyfðu mér að sýna þér hvers vegna.

Segjum að reit í skiladálknum sem samsvarar uppflettigildinu sé auður. Hverju á formúlan að skila? Ekkert.Og nú skulum við sjá hverju það skilar í raun og veru:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Úbbs, formúlan skilar núlli! Kannski er það ekki mjög mikilvægt þegar eingöngu er fjallað um textagildi. Hins vegar, ef vinnublaðið þitt inniheldur tölur og sumar þeirra eru raunveruleg núll, þá er þetta vandamál.

Í sannleika sagt, hegða sér allar aðrar uppflettingarformúlur sem ræddar voru áðan á sama hátt. En núna langar þig í óaðfinnanlega formúlu, er það ekki?

Til að gera INDEX MATCH formúluna algjörlega fullkomna, pakkar þú henni inn í IF fallið sem athugar hvort skilareitur sé auður og skilar engu í þetta tilvik:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

Í formúlunni hér að ofan:

• "C" er skiladálkur.
• "1" er talan sem breytir hlutfallslegri staðsetningu reitsins sem MATCH-fallið skilar í raunverulegt frumveffang .

Til dæmis uppflettifylki í MATCH-fallinu okkar er A2:A7, sem þýðir að hlutfallsleg staða reits A2 er "1", því þetta er fyrsta reitinn í fylkinu. En í raun og veru byrjar uppflettifylkingin í röð 2. Til að jafna upp mismuninn bætum við 1 við, þannig að INDIRECT aðgerðin mun skila gildi úr hægri hólfinu.

Skjámyndirnar hér að neðan sýna endurbættan INDEX sem er há- og hástafanæm. MATCH formúla í aðgerð.

Ef skilareiturinn er tómur gefur formúlan ekkert út (tómur strengur):

Ef skilahólfið inniheldur núll , formúlan skilar 0:

Ef þú vilt frekarbirta einhver skilaboð þegar skilareitur er auður, skiptu út tómum streng ("") í síðustu breytu IF með einhverjum texta:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

Gerðu hástafanæmu VLOOKUP á auðveldan hátt

Notendur Ultimate Suite fyrir Excel okkar eru með sérstakt tól sem gerir það auðveldara og streitulaust að fletta upp í stórum og flóknum töflum. Það besta er að Sameina tvær töflur hefur valmöguleika sem næmur fyrir hástöfum og dæmið hér að neðan sýnir það í aðgerð.

Segjum að þú viljir draga Magn. frá Upplit töflunni í Aðal töfluna sem byggist á einstökum vöruauðkennum:

Það sem þú gerir er að keyra sameinatöflurnar töframaður og framkvæma þessi skref:

1. Veldu aðaltöfluna sem á að draga ný gögn í.
2. Veldu uppflettingartöfluna þar sem þú vilt leita að nýju gögnunum.
3. Veldu einn eða fleiri lykildálka (Auðkenni vöru í okkar tilviki). Og vertu viss um að haka í reitinn hástafahámarkssamsvörun .

Að augnabliki síðar færðu þá niðurstöðu sem þú vilt :)

Svona á að fletta í Excel að teknu tilliti til textafalls. Ég þakka þér fyrir lesturinn og vonast til að sjá þig á blogginu okkar í næstu viku!

Æfingabók til að hlaða niður

Látstafsnæm VLOOKUP dæmi (.xlsx skrá)