Tha an oideachadh a’ mìneachadh mar a nì thu Excel VLOOKUP mothachail air cùis, a’ nochdadh beagan fhoirmlean eile a nì eadar-dhealachadh air cùis teacsa, agus a’ comharrachadh neartan agus crìochan gach gnìomh.

Tha mi creidsinn a h-uile Tha fios aig neach-cleachdaidh Excel dè an gnìomh a nì sgrùdadh dìreach ann an Excel. Ceart, is e VLOOKUP a th’ ann. Ach, is e glè bheag de dhaoine a tha mothachail gu bheil VLOOKUP Excel neo-mhothachail air cùisean, a’ ciallachadh gu bheil e a’ làimhseachadh litrichean beaga agus UPPERCASE mar na h-aon charactaran.

Seo eisimpleir sgiobalta a sheallas nach eil VLOOKUP comasach air cùis teacsa aithneachadh. Can ma tha “bile” agad ann an cealla A2 agus “Bill” ann an A4. Glacaidh an fhoirmle gu h-ìosal "bile" a chionn 's gu bheil e a' tighinn an toiseach san raon lorg agus tillidh e luach co-ionnan o B2.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

Nas fhaide air adhart ann an seo artaigil, seallaidh mi dhut dòigh air VLOOKUP a dhèanamh mothachail air cùis. Nì sinn sgrùdadh cuideachd air grunn ghnìomhan eile as urrainn maids a tha mothachail air cùis a dhèanamh ann an Excel.

Foirmle VLOOKUP a tha mothachail air cùis

Mar a chaidh ainmeachadh gu h-àrd, foirmle àbhaisteach VLOOKUP chan eil e ag aithneachadh cùis na litreach. Ach, tha dòigh ann air Excel VLOOKUP a dhèanamh mothachail air cùis, mar a chithear san eisimpleir gu h-ìosal.

Abair gu bheil IDan nì agad ann an colbh A agus gu bheil thu airson prìs an nì agus beachd a tharraing. bho cholbhan B agus C. 'S e an duilgheadas a th' ann gu bheil IDan a' gabhail a-steach an dà chuid caraichean beaga agus litrichean mòra. Mar eisimpleir, tha na luachan ann an A4 (001Tvci3u) agus A5 (001Tvci3U) eadar-dhealaichte a-mhàin ann anan caractar mu dheireadh, "u" agus "U", fa leth.

Nuair a sheallas tu suas "001Tvci3 U ", bidh foirmle àbhaisteach VLOOKUP a' toirt a-mach $90 a tha co-cheangailte ri "001Tvci3 u " a chionn 's gu bheil e a' tighinn ro "001Tvci3 U " san raon sgrùdaidh. Ach chan e seo a tha thu ag iarraidh, ceart?

=VLOOKUP(F2, A2:C7, 2, FALSE)

Gus sgrùdadh a tha mothachail air cùis a dhèanamh ann an Excel, bidh sinn a’ cothlamadh an VLOOKUP, CHOOSE agus EXACT gnìomhan:

Bidh am foirmle coitcheann seo ag obair gu foirfe anns a h-uile suidheachadh. Faodaidh tu fiù 's coimhead suas bho dheas gu clì , rud nach urrainn do fhoirmle àbhaisteach VLOOKUP a dhèanamh. Kudos gu Pouriya airson am fuasgladh sìmplidh eireachdail seo a mholadh!

Anns a’ chùis againn, tha na fìor fhoirmlean a’ dol mar a leanas.

Gus a’ phrìs a tharraing ann am F3:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

Gus am beachd fhaighinn F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Nòta. Anns a h-uile dreach Excel a bharrachd air Excel 365, chan obraich seo ach mar fhoirmle rèite, mar sin cuimhnich gun brùth thu Ctrl + Shift + Enter gus a chrìochnachadh gu ceart. Ann an Excel 365, mar thoradh air taic airson arrays fiùghantach, bidh e cuideachd ag obair mar fhoirmle cunbhalach.

Mar a dh’obraicheas am foirmle seo:

Is e am prìomh phàirt a nì an cleas am foirmle CHOOSE le neadachadh EXACT:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

An seo, bidh an gnìomh EXACT a’ dèanamh coimeas eadar an luach ann am F2 an aghaidh gach luach ann an A2: A7 agus a’ tilleadh TRUE ma tha iad dìreach mar an ceudna a’ toirt a-steach cùis na litreach,FALSE air dhòigh eile:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

Airson argamaid index_num CHOOSE, bidh sinn a’ cleachdadh an seasmhach rèite {1,2}. Mar thoradh air an sin, bidh an gnìomh a’ cothlamadh nan luachan loidsigeach bhon raon gu h-àrd agus na luachan bho C2: C7 ann an sreath dà-thaobhach mar seo:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

Bheir an gnìomh VLOOKUP às an sin e agus a’ lorg an luach lorg (a tha TRUE) anns a’ 1d colbh den raon 2-mheudach (air a riochdachadh leis na luachan loidsigeach) agus a’ tilleadh maids bhon 2na colbh, is e sin a’ phrìs a tha sinn a’ sireadh:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Foirmle XLOOKUP a tha mothachail air cùis

Faodaidh luchd-aontachaidh Microsoft 365 sgrùdadh a tha mothachail air cùis a dhèanamh ann an Excel le eadhon foirmle nas sìmplidhe. Mar a shaoileadh tu, tha mi a’ bruidhinn mu dheidhinn neach-leantainn nas cumhachdaiche de VLOOKUP - an gnìomh XLOOKUP.

Leis gu bheil XLOOKUP ag obrachadh air arrays lorg is tilleadh air leth, chan eil feum againn air an t-sreath dà-mheudach bhon fhear roimhe. eisimpleir. Gu sìmplidh, cleachd EXACT airson an argamaid lookup_array :

Tha an argamaid mu dheireadh ("Cha deach a lorg") roghainneil. Tha e dìreach a’ mìneachadh dè an luach a th’ air a thilleadh mura lorgar maids. Ma dh'fhàgas tu e air falbh, thèid mearachd àbhaisteach #N/A a thilleadh air eagal 's nach lorg an fhoirmle dad.

Airson a' chlàr sampall againn, is iad seo na foirmlean XLOOKUP a tha mothachail air cùis a chleachdas iad.

Gus a’ phrìs fhaighinn ann am F3:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

Gus am faidhlebeachd F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

Mar a tha am foirmle seo ag obair:

Mar a bha san eisimpleir roimhe, tha EXACT a’ tilleadh sreath de luachan TRUE agus FALSE, far a bheil TRUE a’ riochdachadh maidsean a tha mothachail air cùis. Rannsaichidh XLOOKUP an t-sreath gu h-àrd airson an luach TRUE agus tillidh e maids bhon return_array . Thoir an aire, ma tha dhà no barrachd dìreach na h-aon luachan sa cholbh seallaidh (a’ gabhail a-steach a’ chùis litreach), tillidh am foirmle a’ chiad mhaidse a chaidh a lorg.

Crìochan XLOOKUP : ri fhaighinn a-mhàin ann an Excel 365 agus Excel 2021.

SUMPRODUCT - sgrùdadh cùis-mhothachail gus àireamhan maidsidh a thilleadh

Mar a thuigeas tu bhon cheann, tha SUMPRODUCT na ghnìomh Excel eile a nì sgrùdadh a tha mothachail air cùis. , ach chan urrainn dha luachan àireamhach a thilleadh a-mhàin. Mura h-e seo a’ chùis agad, leum chun eisimpleir INDEX MATCH a bheir seachad fuasgladh airson a h-uile seòrsa dàta.

Mar is dòcha gu bheil fios agad, bidh Excel's SUMPRODUCT ag iomadachadh co-phàirtean anns na rèitichean ainmichte agus a’ tilleadh suim nam bathar. Leis gu bheil sinn ag iarraidh sgrùdadh a tha mothachail air cùis, bidh sinn a’ cleachdadh an gnìomh EXACT gus a’ chiad raon fhaighinn:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

Gu mì-fhortanach, chan urrainn dhan ghnìomh SUMPRODUCT maidsean teacsa a thilleadh leis nach urrainn luachan teacsa iomadachadh. Anns a’ chùis seo, gheibh thu #VALUE! mearachd mar ann an ceal F4 san dealbh gu h-ìosal:

Mar a tha am foirmle seo ag obair:

Mar eisimpleir VLOOKUP, an EXACT sgrùdaidhean gnìomhan luach ann am F2 mu choinneamh nan luachan uile ann an A2: A7 agus a’ tilleadh TRUE airson maidsean a tha mothachail air cùis, FALSE air dhòigh eile:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

Anns a’ mhòr-chuid de fhoirmlean, bidh Excel a’ measadh TRUE gu 1 agus FALSE gu 0 Mar sin, nuair a dh'iomadaicheas SUMPRODUCT na h-eileamaidean den dà shreath anns na h-aon shuidheachaidhean, bidh a h-uile neo-gheam (FALSE) gu bhith nan neamhan:

SUMPRODUCT({0;0;0;54;0;0})

Mar thoradh air an sin, tillidh am foirmle àireamh bho colbh B a fhreagras ris an dearbh mhaidseadh a tha mothachail air cùis ann an colbh A.

Crìochan SUMPRODUCT : chan urrainn dha luachan àireamhach a-mhàin a thilleadh.

INDEX MATCH - lorg cùis-mhothachail airson a h-uile seòrsa dàta

Mu dheireadh, tha sinn faisg air a bhith a’ faighinn foirmle sgrùdaidh a tha mothachail air cùis gun chrìochan a bhios ag obair anns a h-uile dreach Excel agus air a h-uile seata dàta.

Tha an eisimpleir seo a’ tighinn mu dheireadh chan ann a-mhàin air sgàth tha an tè as fheàrr air a shàbhaladh airson an fhear mu dheireadh, ach cuideachd a chionn 's dòcha gun cuidich an t-eòlas a fhuair thu anns na h-eisimpleirean roimhe thu gus am foirmle MATCH INDEX a tha mothachail air cùis a thuigsinn nas fheàrr.

Tha am measgachadh de ghnìomhan INDEX agus MATCH air a chleachdadh gu tric ann an Ex cel mar roghainn eile nas sùbailte agus nas ioma-chruthach an àite VLOOKUP. Nì an artaigil a leanas obair mhath (an dòchas :) a’ mìneachadh mar a tha an dà ghnìomh seo ag obair còmhla - A’ cleachdadh INDEX MATCH an àite VLOOKUP.

An seo, cuiridh mi dìreach na prìomh phuingean nad chuimhne:

• Bidh an gnìomh MATCH a’ lorg luach an t-seallaidh san raon sgrùdaidh ainmichte agus a’ tilleadh a shuidheachadh càirdeach.
• An dàimheachtha suidheachadh luach an t-seallaidh a' dol dìreach gu argamaid row_num a' ghnìomh INDEX ag iarraidh air luach a thilleadh bhon t-sreath sin.

Airson na foirmle gus cùis teacsa aithneachadh, chan eil agad ach feumar aon ghnìomh eile a chur ris a’ mheasgachadh clasaigeach INDEX MATCH. Gu follaiseach, feumaidh tu an gnìomh EXACT a-rithist:

Is e an fhìor fhoirmle ann am F3:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Ann am F4, tha sinn a’ cleachdadh an tè seo:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Cuimhnich nach obraich e ach mar foirmle rèite anns a h-uile dreach a bharrachd air Excel 365, mar sin bi cinnteach gun cuir thu a-steach e le bhith a’ putadh na h-iuchraichean Ctrl + Shift + Enter còmhla. Ma thèid a dhèanamh ceart, thèid am foirmle a chuartachadh ann an sèbhirean lùbach mar a chithear san dealbh gu h-ìosal:

Mar a dh’obraicheas am foirmle seo:

Mar a h-uile eisimpleir roimhe, tha EXACT a’ tilleadh TRUE airson gach luach ann an A2: A7 a tha dìreach a rèir an luach ann am F2. Leis gu bheil sinn a’ cleachdadh TRUE airson an lookup_value de MATCH, bidh e a’ tilleadh suidheachadh co-cheangailte ris a’ gheama a tha mothachail air cùis, agus sin dìreach a dh’ fheumas INDEX gus maids a thilleadh o B2:B7.

Foirmle sgrùdaidh adhartach a tha mothachail air cùis

Tha am foirmle INDEX MATCH gu h-àrd a’ coimhead foirfe, ceart? Ach gu dearbh, chan eil. Leig dhomh sealltainn dhut carson.

Abair gu bheil cill sa cholbh tilleadh a tha co-chosmhail ris an luach lorg bàn. Dè a bheir am foirmle air ais? Chan eil dad.Agus a-nis, chì sinn dè dha-rìribh a thilleas e:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Oops, tha am foirmle a’ tilleadh neoni! Is dòcha, chan eil e gu math cudromach nuair a thathar a’ dèiligeadh ri luachan teacsa a-mhàin. Ge-tà, ma tha àireamhan air an duilleag-obrach agad agus cuid dhiubh nan neoni fìor, 's e duilgheadas a tha seo.

Gu fìrinneach, bidh a h-uile foirmle sgrùdaidh eile a chaidh a dheasbad nas tràithe gan giùlan fhèin san aon dòigh. Ach a-nis gu bheil thu ag iarraidh foirmle do-chreidsinneach, nach eil?

Gus am foirmle INDEX MATCH a tha mothachail air cùis a dhèanamh gu tur foirfe, bidh thu ga phasgadh a-steach don ghnìomh IF a nì sgrùdadh a bheil cealla tilleadh falamh agus nach till dad a-steach. a' chùis seo:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

San fhoirmle gu h-àrd:

• 'S e "C" an colbh tilleadh.
• 'S e "1" an àireamh a thionndaidheas suidheachadh càirdeach den chill air a thilleadh leis a’ ghnìomh MATCH gu seòladh fìor chealla .

Mar eisimpleir, an t-sreath lorg anns a’ ghnìomh MATCH againn is e A2:A7, a’ ciallachadh gur e suidheachadh càirdeach cill A2 “1”, oir is e seo a’ chiad chill san raon. Ach ann an da-rìribh, tha an t-sreath sgrùdaidh a’ tòiseachadh ann an sreath 2. Gus an diofar a dhìoladh, cuiridh sinn 1 ris, agus mar sin tillidh an gnìomh INDIRECT luach bhon chill cheart. MATCH foirmle ann an gnìomh.

Ma tha an cealla tilleadh falamh, chan eil an fhoirmle a’ toirt a-mach dad (sreang fhalamh):

Ma tha neoni sa chill tilleadh , tillidh am foirmle 0:

Nam b’ fheàrr leatseall teachdaireachd nuair a tha cealla tilleadh bàn, cuir teacsa an àite sreang fhalamh ("") san argamaid mu dheireadh aig IF:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

Dèan VLOOKUP a tha mothachail air cùis ann an dòigh fhurasta

Tha inneal sònraichte aig luchd-cleachdaidh an Ultimate Suite for Excel againn a tha a’ dèanamh coimhead suas ann an clàran mòra iom-fhillte nas fhasa agus gun cuideam. Is e an rud as fheàrr gu bheil roghainn cùis-mhothachail aig Merge Two Tables, agus tha an eisimpleir gu h-ìosal ga shealltainn ann an gnìomh.

Abair gu bheil thu airson Qty a tharraing. bhon chlàr Lookup chun chlàr Prìomh stèidhichte air IDan Nì sònraichte:

'S e na nì thu gus na Clàran Co-aonaidh a ruith draoidh agus dèan na ceumannan seo:

1. Tagh am prìomh chlàr airson dàta ùr a tharraing a-steach.
2. Tagh an clàr lorg far an lorg thu an dàta ùr.
3. Tagh aon phrìomh cholbh no barrachd (ID nì sa chùis againn). Agus dèan cinnteach gun cuir thu sùil air a’ bhogsa Co-fhreagras a tha mothachail air cùis .

Mionaid às deidh sin, gheibh thu an toradh a tha thu ag iarraidh :)

Sin mar a nì thu sgrùdadh ann an Excel a’ toirt aire don chùis teacsa. Tha mi a' toirt taing dhut airson an leughadh agus an dòchas ur faicinn air a' bhlog againn an ath sheachdain!

Leabhar-obrach cleachdaidh airson a luchdachadh a-nuas

Eisempleirean VLOOKUP a tha mothachail air cùis (faidhle .xlsx)