Oʻquv qoʻllanma Excel VLOOKUP dasturini katta-kichik harflarga sezgir qilishni tushuntiradi, matn katta-kichikligini ajratuvchi bir nechta boshqa formulalarni namoyish etadi va har bir funksiyaning kuchli va cheklovlarini koʻrsatadi.

Oʻylaymanki, har bir Excel foydalanuvchisi Excelda vertikal qidiruvni qaysi funktsiyani bajarishini biladi. To'g'ri, bu VLOOKUP. Biroq, juda kam odam Excelning VLOOKUP funksiyasi katta-kichik harflarni sezmasligini biladi, ya'ni u kichik va YUQOQ harflarni bir xil belgilar sifatida ko'radi.

VLOOKUP matn registrini ajrata olmasligini ko'rsatadigan tezkor misol. Aytaylik, agar sizda A2 katakda "hisob-kitob" va A4 katakchasida "hisob-kitob" mavjud bo'lsa. Quyidagi formula "hisob-kitob" ni ushlaydi, chunki u qidiruv massivida birinchi bo'lib keladi va B2 dan mos keladigan qiymatni qaytaradi.

=VLOOKUP("Bill", A2:B4, 2, FALSE)

Bundan keyin bu erda. maqolada, men sizga VLOOKUP katta-kichikligini sezgir qilish usulini ko'rsataman. Bundan tashqari, Excelda katta-kichik harflarni hisobga oladigan boshqa funksiyalarni ham ko‘rib chiqamiz.

Harf-katta sezgir VLOOKUP formulasi

Yuqorida aytib o‘tilganidek, odatiy VLOOKUP formulasi harf holatini tanimaydi. Biroq, quyida keltirilgan misolda ko'rsatilgandek Excel VLOOKUP-ni katta-kichik harflarga sezgir qilishning bir usuli bor.

Sizda A ustunida Element identifikatorlari bor va buyum narxi va sharhini olishni xohlaysiz. B va C ustunlaridan. Muammo shundaki, identifikatorlar kichik va katta harflarni o'z ichiga oladi. Masalan, A4 (001Tvci3u) va A5 (001Tvci3U) dagi qiymatlar faqat bir-biridan farq qiladi.oxirgi belgi mos ravishda "u" va "U".

"001Tvci3 U " ni qidirayotganda standart VLOOKUP formulasi "001Tvci3 u" bilan bog'langan $90 chiqadi. " chunki u qidirish massivida "001Tvci3 U " dan oldin keladi. Lekin bu siz istagan narsa emas, to'g'rimi?

=VLOOKUP(F2, A2:C7, 2, FALSE)

Excelda katta-kichik harflarni hisobga olgan holda qidirishni amalga oshirish uchun biz VLOOKUP, CHOOSE va EXACT-ni birlashtiramiz. funktsiyalari:

Ushbu umumiy formula barcha holatlarda mukammal ishlaydi. Siz hatto o'ngdan chapga ga qarashingiz mumkin, bu oddiy VLOOKUP formulasi buni qila olmaydi. Ushbu oddiy va oqlangan yechimni taklif qilgani uchun Pouriyaga rahmat!

Bizning holatlarimizda haqiqiy formulalar quyidagicha bo'ladi.

F3da narxni tortish uchun:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

Izohni olish uchun F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Eslatma. Excel 365 dan boshqa barcha Excel versiyalarida bu faqat massiv formulasi sifatida ishlaydi, shuning uchun uni to'g'ri bajarish uchun Ctrl + Shift + Enter tugmalarini bosishni unutmang. Excel 365 da dinamik massivlarni qo'llab-quvvatlash tufayli u oddiy formula sifatida ham ishlaydi.

Ushbu formula qanday ishlaydi:

Mazkur vazifani bajaradigan asosiy qism CHOOSE formulasi ichida joylashgan EXACT:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

Bu yerda, EXACT funksiyasi F2 qiymatini A2:A7 dagi har bir qiymat bilan solishtiradi va agar ular harflar bilan bir xil bo‘lsa, TRUE qiymatini qaytaradi,FALSE aks holda:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

CHOOSE ning indeks_num argumenti uchun {1,2} massiv doimiysidan foydalanamiz. Natijada, funktsiya yuqoridagi massivdagi mantiqiy qiymatlarni va C2:C7 dan qiymatlarni quyidagi kabi ikki o'lchovli massivga birlashtiradi:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP funksiyasi uni shu yerdan oladi. va 2 o‘lchovli massivning 1-ustunida (mantiqiy qiymatlar bilan ifodalangan) qidirish qiymatini (bu TRUE) qidiradi va 2-ustundan moslikni qaytaradi, bu biz qidirayotgan narx:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

Harf-harflarga sezgir XLOOKUP formulasi

Microsoft 365 abonentlari Excelda katta-kichik harflarni hisobga olgan holda qidirishni oddiyroq formula bilan ham amalga oshirishlari mumkin. Siz taxmin qilganingizdek, men VLOOKUPning yanada kuchli vorisi – XLOOKUP funksiyasi haqida gapiryapman.

XLOOKUP massivlarni qidirish va qaytarishda alohida ishlagani uchun bizga avvalgisidan ikki o‘lchovli massiv nayrangi kerak emas. misol. Shunchaki, qidiruv_massivi argumenti uchun EXACT-dan foydalaning:

Oxirgi argument ("topilmadi") ixtiyoriy. U faqat mos keladigan qiymat topilmasa, qanday qiymatni qaytarish kerakligini belgilaydi. Agar uni o'tkazib yuborsangiz, formula hech narsa topmasa, standart #N/A xatosi qaytariladi.

Namunaviy jadvalimiz uchun bu katta-kichik harflarga sezgir XLOOKUP formulalari.

F3-da narxni olish uchun:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

izoh F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

Ushbu formula qanday ishlaydi:

Avvalgi misoldagi kabi, EXACT qaytaradi TRUE va FALSE qiymatlari massivi, bu erda TRUE katta-kichik-katta mosliklarni ifodalaydi. XLOOKUP yuqoridagi massivdan TRUE qiymatini qidiradi va qaytish_massivi dan moslikni qaytaradi. E'tibor bering, agar qidirish ustunida ikki yoki undan ortiq aynan bir xil qiymatlar bo'lsa (jumladan, harf kattaligi), formula birinchi topilgan moslikni qaytaradi.

XLOOKUP cheklovi : faqat mavjud Excel 365 va Excel 2021 da.

SUMPRODUCT - mos keladigan raqamlarni qaytarish uchun katta-kichik harflarni hisobga olgan holda qidirish

Sarlavhadan tushunganingizdek, SUMPRODUCT Excelning yana bir funksiyasi bo'lib, katta-kichik harflarni hisobga olgan holda qidirishni amalga oshiradi. , lekin u faqat raqamli qiymatlarni qaytarishi mumkin. Agar bu sizning holatingiz bo'lmasa, barcha ma'lumotlar turlari uchun yechimni ta'minlovchi INDEX MATCH misoliga o'ting.

Sizga ma'lumki, Excelning SUMPRODUCT ko'rsatilgan massivlardagi komponentlarni ko'paytiradi va mahsulotlar yig'indisini qaytaradi. Biz katta-kichik registrni hisobga olgan holda qidirishni xohlayotganimiz sababli, birinchi massivni olish uchun EXACT funksiyasidan foydalanamiz:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

Afsuski, SUMPRODUCT funksiyasi matn qiymatlarini ko‘paytirib bo‘lmagani uchun matn mosligini qaytara olmaydi. Bunday holda siz #QIYMATga ega bo'lasiz! quyidagi skrinshotdagi F4 katakdagi kabi xato:

Ushbu formula qanday ishlaydi:

VLOOKUP misolidagi kabi, EXACT funksiya tekshiruvlariF2 dagi qiymat A2:A7 dagi barcha qiymatlarga nisbatan va katta-kichik harflar uchun moslik uchun TRUE qiymatini qaytaradi, aks holda FALSE:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

Ko'pgina formulalarda Excel TRUE qiymatini 1 va FALSE qiymatini 0 ga baholaydi. Shunday qilib, SUMPRODUCT ikkita massivning elementlarini bir xil pozitsiyalarda ko'paytirganda, barcha mos kelmaydiganlar (FALSE) nolga aylanadi:

SUMPRODUCT({0;0;0;54;0;0})

Natijada formula quyidagidan raqamni qaytaradi. A ustunidagi katta-kichik harf sezgirligiga mos keladigan B ustuni.

SUMPRODUCT cheklovi : faqat raqamli qiymatlarni qaytarishi mumkin.

INDEX MATCH - katta-kichik harf sezgir qidiruv barcha ma'lumotlar turlari

Nihoyat, biz Excelning barcha versiyalarida va barcha ma'lumotlar to'plamlarida ishlaydigan cheklovlarsiz katta-kichik harflarni hisobga olgan holda qidirish formulasini olishga yaqinmiz.

Ushbu misol faqat oxirgi bo'lgani uchun emas. Eng yaxshisi oxirgisi uchun saqlanadi, balki oldingi misollarda olgan bilimlaringiz katta-kichik harflarga sezgir MATCH INDEX formulasini yaxshiroq tushunishingizga yordam berishi mumkin.

INDEX va MATCH funksiyalarining kombinatsiyasi tez-tez ishlatiladi. Ex cel VLOOKUP-ga yanada moslashuvchan va ko'p qirrali alternativa sifatida. Quyidagi maqola yaxshi ish qiladi (umid qilamanki :) bu ikki funksiya qanday ishlashini tushuntiradi - VLOOKUP o'rniga INDEX MATCH dan foydalanish.

Bu erda men sizga asosiy fikrlarni eslatib o'taman:

• MATCH funksiyasi ko'rsatilgan qidirish massivida qidirish qiymatini qidiradi va uning nisbiy o'rnini qaytaradi.
• NisbiyQidiruv qiymatining oʻrni toʻgʻridan-toʻgʻri INDEX funksiyasining satr_num argumentiga oʻtadi va unga shu qatordan qiymat qaytarishni buyuradi.

Formula matn registrini tanib olishi uchun siz shunchaki boʻlishingiz kerak. klassik INDEX MATCH kombinatsiyasiga yana bitta funktsiyani qo'shish kerak. Shubhasiz, sizga yana EXACT funksiyasi kerak:

F3-dagi haqiqiy formula:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

F4-da biz buni ishlatamiz:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Iltimos, u faqat shunday ishlaydi massiv formulasi Excel 365 dan boshqa barcha versiyalarda, shuning uchun uni Ctrl + Shift + Enter tugmalarini birgalikda bosib kiritishni unutmang. Agar to'g'ri bajarilgan bo'lsa, formula quyidagi skrinshotda ko'rsatilgandek jingalak qavslar ichiga olinadi:

Ushbu formula qanday ishlaydi:

Avvalgi barcha misollardagi kabi, EXACT F2 qiymatiga toʻliq mos keladigan A2:A7 formatidagi har bir qiymat uchun TRUE qiymatini qaytaradi. MATCH ning qidiruv_qiymati uchun TRUE dan foydalanganimiz sababli, u aniq katta-kichik harflarga mos keladigan moslikning nisbiy pozitsiyasini qaytaradi, bu INDEX B2:B7 dan moslikni qaytarishi uchun aynan shu narsadir.

Kengaytirilgan katta-kichik harflarni hisobga olgan holda qidirish formulasi

Yuqorida aytib o'tilgan INDEX MATCH formulasi mukammal ko'rinadi, to'g'rimi? Lekin, aslida, unday emas. Buning sababini ko'rsataman.

Fayz qilaylik, qaytarish ustunidagi qidiruv qiymatiga mos keladigan katak bo'sh. Formula nimani qaytaradi? Hech narsa.Keling, u aslida nimani qaytarishini ko'rib chiqaylik:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Of, formula nolni qaytaradi! Ehtimol, faqat matn qiymatlari bilan ishlashda bu juda muhim emas. Biroq, agar sizning ishchi varaqingizda raqamlar mavjud bo'lsa va ularning ba'zilari haqiqiy nolga teng bo'lsa, bu muammo.

Haqiqatdan ham, avval muhokama qilingan boshqa barcha qidirish formulalari xuddi shunday harakat qiladi. Lekin endi siz benuqson formulani xohlaysiz, shunday emasmi?

Harf-harakatga sezgir INDEX MATCH formulasini mutlaqo mukammal qilish uchun uni IF funktsiyasiga o'rab, qaytariladigan katakchaning bo'shligini tekshiradi va hech narsa qaytarmaydi. bu holat:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

Yuqoridagi formulada:

• "C" - qaytarish ustuni.
• "1" - son. bu MATCH funksiyasi tomonidan qaytarilgan katakning nisbiy pozitsiyasini haqiqiy hujayra manziliga aylantiradi.

Masalan, MATCH funksiyamizdagi qidirish massivi bu A2:A7, ya'ni A2 katakning nisbiy joylashuvi "1" ni bildiradi, chunki bu massivdagi birinchi katakdir. Biroq, aslida, qidirish massivi 2-qatordan boshlanadi. Farqni qoplash uchun biz 1 qo'shamiz, shuning uchun INDIRECT funksiyasi o'ng katakdagi qiymatni qaytaradi.

Quyidagi skrinshotlar yaxshilangan katta-kichik harf sezgir INDEXni ko'rsatadi. MATCH formulasi amalda.

Agar qaytish katak bo'sh bo'lsa, formuladan hech narsa chiqmaydi (bo'sh qator):

Agar qaytish katakchasida nol bo'lsa , formula 0 ni qaytaradi:

Agar xohlasangizQaytish katakchasi bo'sh bo'lganda ba'zi xabarlarni ko'rsatish, IF ning oxirgi argumentidagi bo'sh satrni ("") bir nechta matn bilan almashtiring:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

Katta va katta hajmdagi VLOOKUPni oson yo'l bilan bajaring

Excel uchun Ultimate Suite foydalanuvchilari katta va murakkab jadvallarni oson va stresssiz qidirishni ta'minlaydigan maxsus vositaga ega. Eng yaxshisi shundaki, ikkita jadvalni birlashtirish opsiyasi katta-kichik harflarni hisobga oladi va quyidagi misolda uni amalda ko'rsatadi.

Siz Miqdorni tortmoqchisiz deylik. Qidiruv jadvalidan Asosiy jadvaliga noyob element identifikatorlari asosida o'ting:

Jadvallarni birlashtirishni ishga tushirish. sehrgarni oching va quyidagi amallarni bajaring:

1. Yangi ma'lumotlarni olish uchun asosiy jadvalni tanlang.
2. Yangi ma'lumotlarni qidiradigan qidirish jadvalini tanlang.
3. Bir yoki bir nechta asosiy ustunlarni tanlang (bizning holatlarimizda element identifikatori). Va Harf-harflar uchun moslik katagiga belgi qo'yganingizga ishonch hosil qiling.

Birozdan so'ng siz kerakli natijani olasiz :)

Matn registrini hisobga olgan holda Excelda shunday qidirish mumkin. O'qiganingiz uchun tashakkur va keyingi haftada blogimizda ko'rishamiz degan umiddaman!

Yuklab olish uchun mashq kitobi

Harf-harflarga sezgir VLOOKUP misollari (.xlsx fayli)