Das Tutorial erklärt, wie man in Excel VLOOKUP unter Berücksichtigung der Groß- und Kleinschreibung einrichtet, demonstriert einige andere Formeln, die zwischen Groß- und Kleinschreibung unterscheiden, und zeigt die Stärken und Grenzen der einzelnen Funktionen auf.

Ich denke, jeder Excel-Benutzer weiß, welche Funktion eine vertikale Suche in Excel durchführt. Richtig, es ist VLOOKUP. Die wenigsten wissen jedoch, dass VLOOKUP in Excel die Groß- und Kleinschreibung nicht berücksichtigt, d. h. Klein- und Großbuchstaben werden als gleichwertig behandelt.

Hier ein kurzes Beispiel, das die Unfähigkeit von VLOOKUP, zwischen Groß- und Kleinschreibung zu unterscheiden, verdeutlicht. Angenommen, Sie haben "bill" in Zelle A2 und "Bill" in A4. Die folgende Formel fängt "bill" ab, weil es im Lookup-Array an erster Stelle steht, und gibt einen passenden Wert aus B2 zurück.

=VLOOKUP("Rechnung", A2:B4, 2, FALSE)

Im weiteren Verlauf dieses Artikels zeige ich Ihnen, wie Sie die Groß- und Kleinschreibung bei VLOOKUP berücksichtigen können, und wir werden auch einige andere Funktionen untersuchen, mit denen in Excel die Groß- und Kleinschreibung beachtet werden kann.

Groß- und Kleinschreibung beachtende VLOOKUP-Formel

Wie bereits erwähnt, erkennt eine gewöhnliche VLOOKUP-Formel die Groß- und Kleinschreibung nicht. Es gibt jedoch eine Möglichkeit, Excel VLOOKUP von der Groß- und Kleinschreibung abhängig zu machen, wie im folgenden Beispiel gezeigt wird.

Angenommen, Sie haben Artikel-IDs Das Problem besteht darin, dass die IDs sowohl Klein- als auch Großbuchstaben enthalten. Die Werte in A4 (001Tvci3u) und A5 (001Tvci3U) unterscheiden sich zum Beispiel nur durch das letzte Zeichen, "u" bzw. "U".

Bei der Suche nach "001Tvci3 U Eine Standard-VLOOKUP-Formel gibt $90 aus, die mit "001Tvci3" verknüpft sind. u ", weil es vor "001Tvci3" steht U "Das ist aber nicht das, was Sie wollen, oder?

=VLOOKUP(F2, A2:C7, 2, FALSE)

Um in Excel eine Suche unter Berücksichtigung der Groß- und Kleinschreibung durchzuführen, kombinieren wir die Funktionen VLOOKUP, CHOOSE und EXACT:

Diese allgemeine Formel funktioniert in allen Situationen. Sie können sogar nachschlagen von rechts nach links Das ist etwas, was eine normale VLOOKUP-Formel nicht leisten kann. Hut ab vor Pouriya, der diese einfache und elegante Lösung vorgeschlagen hat!

In unserem Fall lauten die echten Formeln wie folgt.

Um den Preis in F3 zu ziehen:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

Zum Abrufen des Kommentars F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

Hinweis: In allen Excel-Versionen außer Excel 365 funktioniert dies nur als Array-Formel, daher müssen Sie Strg + Umschalt + Eingabe drücken, um die Formel korrekt auszufüllen. In Excel 365 funktioniert sie dank der Unterstützung für dynamische Arrays auch als normale Formel.

Wie diese Formel funktioniert:

Das Kernstück ist die CHOOSE-Formel mit verschachteltem EXACT, die die Aufgabe erfüllt:

WÄHLEN({1,2}, EXAKT(F2, A2:A7), C2:C7)

Hier vergleicht die Funktion EXACT den Wert in F2 mit jedem Wert in A2:A7 und gibt TRUE zurück, wenn sie einschließlich der Groß- und Kleinschreibung genau gleich sind, andernfalls FALSE:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

Für die index_num Argument von CHOOSE verwenden wir die Array-Konstante {1,2}. Als Ergebnis kombiniert die Funktion die logischen Werte aus dem obigen Array und die Werte aus C2:C7 zu einem zweidimensionalen Array wie folgt:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

Die Funktion VLOOKUP übernimmt diese Aufgabe und sucht in der ersten Spalte des zweidimensionalen Arrays (dargestellt durch die logischen Werte) nach dem Nachschlagewert (der TRUE ist) und gibt eine Übereinstimmung in der zweiten Spalte zurück, die den gesuchten Preis darstellt:

VLOOKUP(WAHR, {FALSCH,155;FALSCH,186;FALSCH,90;WAHR,54;FALSCH,159;FALSCH,28}, 2, 0)

Groß- und Kleinschreibung beachtende XLOOKUP-Formel

Microsoft 365-Abonnenten können in Excel mit einer noch einfacheren Formel eine Groß-/Kleinschreibung beachtende Suche durchführen. Wie Sie sich denken können, spreche ich von einem leistungsfähigeren Nachfolger von VLOOKUP - der XLOOKUP-Funktion.

Da XLOOKUP auf Lookup- und Return-Arrays getrennt arbeitet, brauchen wir den zweidimensionalen Array-Trick aus dem vorherigen Beispiel nicht. Verwenden Sie einfach EXACT für die lookup_array Argument:

Das letzte Argument ("Nicht gefunden") ist optional. Es legt lediglich fest, welcher Wert zurückgegeben werden soll, wenn keine Übereinstimmung gefunden wird. Wenn Sie es weglassen, wird ein Standardfehler #N/A zurückgegeben, falls die Formel nichts findet.

Für unsere Beispieltabelle sind dies die XLOOKUP-Formeln, die Groß- und Kleinschreibung berücksichtigen.

Um den Preis in F3 zu erhalten:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Nicht gefunden")

Zum Extrahieren des Kommentars F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Nicht gefunden")

Wie diese Formel funktioniert:

Wie im vorigen Beispiel gibt EXACT ein Array mit TRUE- und FALSE-Werten zurück, wobei TRUE die Groß- und Kleinschreibung beachtet. XLOOKUP durchsucht das obige Array nach dem TRUE-Wert und gibt eine Übereinstimmung aus der return_array Bitte beachten Sie, dass die Formel die erste gefundene Übereinstimmung zurückgibt, wenn es zwei oder mehr exakt gleiche Werte in der Suchspalte gibt (einschließlich Groß- und Kleinschreibung).

XLOOKUP-Beschränkung : nur in Excel 365 und Excel 2021 verfügbar.

SUMPRODUCT - Groß- und Kleinschreibung beachten, um übereinstimmende Zahlen zurückzugeben

Wie Sie aus der Überschrift ersehen können, ist SUMPRODUCT eine weitere Excel-Funktion, die eine Groß-/Kleinschreibung berücksichtigen kann, aber sie kann auch Folgendes zurückgeben numerische Werte Wenn dies nicht der Fall ist, springen Sie zum Beispiel INDEX MATCH, das eine Lösung für alle Datentypen bietet.

Wie Sie wahrscheinlich wissen, multipliziert Excel's SUMPRODUCT die Komponenten in den angegebenen Feldern und gibt die Summe der Produkte zurück. Da wir die Groß- und Kleinschreibung beachten wollen, verwenden wir die EXACT-Funktion, um das erste Feld zu erhalten:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

Leider kann die Funktion SUMPRODUCT keine Textübereinstimmungen zurückgeben, da Textwerte nicht multipliziert werden können. In diesem Fall erhalten Sie eine #VALUE!-Fehlermeldung wie in Zelle F4 in der folgenden Abbildung:

Wie diese Formel funktioniert:

Wie im VLOOKUP-Beispiel prüft die Funktion EXACT den Wert in F2 mit allen Werten in A2:A7 und gibt TRUE zurück, wenn die Groß-/Kleinschreibung beachtet wird, ansonsten FALSE:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

In den meisten Formeln wertet Excel TRUE als 1 und FALSE als 0. Wenn also SUMPRODUCT die Elemente der beiden Arrays an denselben Positionen multipliziert, werden alle Nichtübereinstimmungen (FALSE) zu Nullen:

SUMPRODUCT({0;0;0;54;0;0})

Als Ergebnis gibt die Formel eine Zahl aus Spalte B zurück, die der exakten Groß-/Kleinschreibungstreffer in Spalte A entspricht.

SUMPRODUCT-Beschränkung : kann nur numerische Werte zurückgeben.

INDEX MATCH - Groß- und Kleinschreibung beachtende Suche für alle Datentypen

Endlich sind wir kurz davor, eine einschränkungsfreie Formel für die Groß- und Kleinschreibung zu entwickeln, die in allen Excel-Versionen und für alle Datensätze funktioniert.

Dieses Beispiel kommt nicht nur zum Schluss, weil das Beste für den Schluss aufgespart wird, sondern auch, weil das Wissen, das Sie in den vorangegangenen Beispielen gewonnen haben, Ihnen helfen kann, die MATCH INDEX-Formel, die Groß- und Kleinschreibung berücksichtigt, besser zu verstehen.

Die Kombination der Funktionen INDEX und MATCH wird in Excel häufig als flexiblere und vielseitigere Alternative zu VLOOKUP verwendet. Der folgende Artikel erklärt (hoffentlich :) gut, wie diese beiden Funktionen zusammen funktionieren - Verwendung von INDEX MATCH anstelle von VLOOKUP.

Ich möchte Ihnen hier nur die wichtigsten Punkte in Erinnerung rufen:

• Die Funktion MATCH sucht nach dem Nachschlagewert im angegebenen Nachschlagearray und gibt dessen relative Position zurück.
• Die relative Position des Nachschlagewertes geht direkt in die zeilen_nummer Argument der INDEX-Funktion, das sie anweist, einen Wert aus dieser Zeile zurückzugeben.

Damit die Formel die Groß- und Kleinschreibung erkennt, müssen Sie der klassischen INDEX MATCH-Kombination nur eine weitere Funktion hinzufügen: die EXACT-Funktion:

Die eigentliche Formel in F3 lautet:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

In F4 verwenden wir diese:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Bitte denken Sie daran, dass die Formel nur als Array-Formel in allen Versionen außer Excel 365 funktioniert, also stellen Sie sicher, dass Sie sie durch gleichzeitiges Drücken der Tasten Strg + Umschalt + Enter eingeben. Wenn Sie es richtig machen, wird die Formel in geschweifte Klammern eingeschlossen, wie im Screenshot unten gezeigt:

Wie diese Formel funktioniert:

Wie in allen vorherigen Beispielen gibt EXACT TRUE für jeden Wert in A2:A7 zurück, der genau mit dem Wert in F2 übereinstimmt. Da wir TRUE für die lookup_value von MATCH eine relative Position der exakten Übereinstimmung unter Berücksichtigung der Groß- und Kleinschreibung zurück, was genau das ist, was INDEX benötigt, um eine Übereinstimmung von B2:B7 zurückzugeben.

Erweiterte Formel für die Suche nach Groß- und Kleinschreibung

Die oben erwähnte INDEX MATCH-Formel sieht perfekt aus, oder? Aber in Wirklichkeit ist sie es nicht. Ich zeige Ihnen, warum.

Angenommen, eine Zelle in der Rückgabespalte, die dem Suchwert entspricht, ist leer. Was soll die Formel zurückgeben? Nichts. Und nun wollen wir sehen, was sie tatsächlich zurückgibt:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

Hoppla, die Formel gibt eine Null zurück! Wenn es sich nur um Textwerte handelt, ist das vielleicht nicht so wichtig, aber wenn Ihr Arbeitsblatt Zahlen enthält und einige davon echte Nullen sind, ist das ein Problem.

In Wahrheit verhalten sich alle anderen zuvor besprochenen Nachschlageformeln genauso. Aber jetzt wollen Sie doch eine tadellose Formel, oder?

Um die Formel INDEX MATCH, die Groß- und Kleinschreibung berücksichtigt, absolut perfekt zu machen, verpacken Sie sie in die Funktion IF, die prüft, ob eine Rückgabezelle leer ist und in diesem Fall nichts zurückgibt:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

In der obigen Formel:

• "C" ist die Rückgabespalte.
• "1" ist die Zahl, die aus einem relative Position der von der MATCH-Funktion zurückgegebenen Zelle in eine echte Zelladresse .

Das Lookup-Array in unserer MATCH-Funktion lautet beispielsweise A2:A7, was bedeutet, dass die relative Position der Zelle A2 "1" ist, da dies die erste Zelle im Array ist. In Wirklichkeit beginnt das Lookup-Array jedoch in Zeile 2. Um den Unterschied auszugleichen, fügen wir 1 hinzu, damit die INDIRECT-Funktion einen Wert aus der rechten Zelle zurückgibt.

Die folgenden Screenshots zeigen die verbesserte INDEX MATCH-Formel, die Groß- und Kleinschreibung berücksichtigt.

Wenn die Rückgabezelle leer ist, gibt die Formel nichts aus (eine leere Zeichenfolge):

Wenn die Rückgabezelle eine Null enthält, gibt die Formel 0 zurück:

Wenn Sie lieber eine Meldung anzeigen möchten, wenn eine Rückgabezelle leer ist, ersetzen Sie eine leere Zeichenfolge ("") im letzten Argument von IF durch einen Text:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "Es gibt nichts zurückzugeben, tut mir leid.")

VLOOKUP unter Berücksichtigung der Groß-/Kleinschreibung auf einfache Weise durchführen

Den Nutzern unserer Ultimate Suite für Excel steht ein spezielles Tool zur Verfügung, mit dem das Nachschlagen in großen und komplexen Tabellen einfacher und stressfreier wird. Das Beste daran ist, dass "Merge Two Tables" über eine Option zur Unterscheidung von Groß- und Kleinschreibung verfügt, wie das folgende Beispiel zeigt.

Angenommen, Sie möchten Qty. aus dem Nachschlagen Tabelle zum Hauptseite Tabelle auf der Grundlage eindeutiger Artikel-IDs:

Führen Sie dazu den Assistenten zum Zusammenführen von Tabellen aus und führen Sie die folgenden Schritte durch:

1. Wählen Sie die Haupttabelle, in die neue Daten gezogen werden sollen.
2. Wählen Sie die Nachschlagetabelle aus, in der die neuen Daten gesucht werden sollen.
3. Wählen Sie eine oder mehrere Schlüsselspalten aus (in unserem Fall die Artikel-ID) und überprüfen Sie unbedingt das Feld Abgleich unter Berücksichtigung der Groß-/Kleinschreibung Box.

Einen Moment später werden Sie das gewünschte Ergebnis erhalten :)

So funktioniert das Nachschlagen in Excel unter Berücksichtigung der Groß- und Kleinschreibung. Ich danke Ihnen für die Lektüre und hoffe, Sie nächste Woche in unserem Blog begrüßen zu dürfen!

Übungsheft zum Herunterladen

Beispiele für VLOOKUPs unter Berücksichtigung der Groß-/Kleinschreibung (.xlsx-Datei)