টিউটোরিয়ালটি ব্যাখ্যা করে কিভাবে Excel VLOOKUP কেস-সংবেদনশীল করা যায়, আরও কয়েকটি সূত্র দেখায় যা টেক্সট কেসকে আলাদা করে, এবং প্রতিটি ফাংশনের শক্তি এবং সীমাবদ্ধতা নির্দেশ করে।

আমার ধারণা প্রতিটি এক্সেল ব্যবহারকারী জানেন যে এক্সেলে উল্লম্ব লুকআপ কী ফাংশন করে। ঠিক আছে, এটা VLOOKUP. যাইহোক, খুব কম লোকই জানেন যে Excel এর VLOOKUP কেস-সংবেদনশীল, যার অর্থ এটি ছোট হাতের এবং বড় হাতের অক্ষরগুলিকে একই অক্ষর হিসাবে বিবেচনা করে৷

এখানে একটি দ্রুত উদাহরণ যা পাঠ্য ক্ষেত্রে পার্থক্য করতে VLOOKUP-এর অক্ষমতা প্রদর্শন করে৷ ধরুন A2 কক্ষে আপনার "বিল" এবং A4-এ "বিল" থাকলে। নীচের সূত্রটি "বিল" ধরবে কারণ এটি লুকআপ অ্যারেতে প্রথমে আসে এবং B2 থেকে একটি মিলে যাওয়া মান ফেরত দেয়।

=VLOOKUP("Bill", A2:B4, 2, FALSE)

4>

এতে আরও এগিয়ে যান। নিবন্ধ, আমি আপনাকে VLOOKUP কেস-সংবেদনশীল করার একটি উপায় দেখাব। আমরা আরও কয়েকটি ফাংশন এক্সপ্লোর করব যা এক্সেলের ক্ষেত্রে একটি কেস-সংবেদনশীল ম্যাচ করতে পারে৷

কেস-সংবেদনশীল VLOOKUP সূত্র

উপরে উল্লিখিত হিসাবে, একটি সাধারণ VLOOKUP সূত্র চিঠির কেস চিনতে পারে না। যাইহোক, Excel VLOOKUP কে কেস-সংবেদনশীল করার একটি উপায় আছে, যেমনটি নীচের উদাহরণে দেখানো হয়েছে।

ধরুন আপনার কলাম A-তে আইটেম আইডি আছে এবং আইটেমের দাম এবং মন্তব্য টানতে চান কলাম B এবং C থেকে। সমস্যা হল আইডিতে ছোট হাতের এবং বড় হাতের অক্ষর উভয়ই অন্তর্ভুক্ত। উদাহরণস্বরূপ, A4 (001Tvci3u) এবং A5 (001Tvci3U) এর মানগুলি শুধুমাত্র এর মধ্যে পৃথকশেষ অক্ষর, যথাক্রমে "u" এবং "U",।

"001Tvci3 U " খোঁজার সময়, একটি আদর্শ VLOOKUP সূত্র $90 আউটপুট দেয় যা "001Tvci3 u এর সাথে যুক্ত। " কারণ এটি লুকআপ অ্যারেতে "001Tvci3 U " এর আগে আসে। কিন্তু আপনি যা চান তা নয়, তাই না?

=VLOOKUP(F2, A2:C7, 2, FALSE)

এক্সেল-এ একটি কেস-সংবেদনশীল লুকআপ করতে, আমরা VLOOKUP, চয়ন এবং সঠিক একত্রিত করি ফাংশন:

এই জেনেরিক সূত্রটি সব পরিস্থিতিতে পুরোপুরি কাজ করে। এমনকি আপনি ডান থেকে বামে দেখতে পারেন, এমন কিছু যা একটি নিয়মিত VLOOKUP সূত্র করতে অক্ষম। এই সহজ এবং মার্জিত সমাধানটি সাজেস্ট করার জন্য পৌরিয়াকে ধন্যবাদ!

আমাদের ক্ষেত্রে, আসল সূত্রগুলি নিম্নরূপ।

মূল্য F3 এ টেনে আনতে:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

মন্তব্য আনতে F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

নোট। এক্সেল 365 ব্যতীত অন্য সমস্ত এক্সেল সংস্করণে, এটি শুধুমাত্র একটি অ্যারে সূত্র হিসাবে কাজ করে, তাই এটি সঠিকভাবে সম্পূর্ণ করতে Ctrl + Shift + Enter চাপতে ভুলবেন না। এক্সেল 365-এ, গতিশীল অ্যারেগুলির সমর্থনের কারণে, এটি একটি নিয়মিত সূত্র হিসাবেও কাজ করে।

এই সূত্রটি কীভাবে কাজ করে:

প্রধান অংশটি যা কৌশলটি করে তা হল নেস্টেড EXACT সহ সূত্রটি চয়ন করুন:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

এখানে, EXACT ফাংশন A2:A7-এর প্রতিটি মানের সাথে F2-এর মান তুলনা করে এবং লেটার কেস সহ হুবহু একই হলে TRUE প্রদান করে,অন্যথায় FALSE:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

CHOOSE এর index_num আর্গুমেন্টের জন্য, আমরা অ্যারে ধ্রুবক {1,2} ব্যবহার করি। ফলস্বরূপ, ফাংশনটি উপরের অ্যারে থেকে লজিক্যাল মান এবং C2:C7 এর মানগুলিকে একটি দ্বি-মাত্রিক অ্যারেতে একত্রিত করে এভাবে:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP ফাংশন সেখান থেকে এটি নেয় এবং 2-মাত্রিক অ্যারের (যৌক্তিক মান দ্বারা উপস্থাপিত) 1ম কলামে লুকআপ মান (যা সত্য) অনুসন্ধান করে এবং 2য় কলাম থেকে একটি মিল দেখায়, যা আমরা যে দামটি খুঁজছি:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

কেস-সংবেদনশীল XLOOKUP সূত্র

Microsoft 365 গ্রাহকরা এমনকি একটি সহজ সূত্র সহ Excel-এ একটি কেস-সংবেদনশীল লুকআপ করতে পারেন। আপনি যেমন অনুমান করতে পারেন, আমি VLOOKUP-এর আরও শক্তিশালী উত্তরসূরির কথা বলছি - XLOOKUP ফাংশন৷

যেহেতু XLOOKUP আলাদাভাবে লুকআপ এবং রিটার্ন অ্যারেগুলি পরিচালনা করে, আমাদের আগের থেকে দ্বি-মাত্রিক অ্যারে কৌশলের প্রয়োজন নেই৷ উদাহরণ সহজভাবে, lookup_array আর্গুমেন্টের জন্য EXACT ব্যবহার করুন:

শেষ আর্গুমেন্ট ("নট ফাউন্ড") ঐচ্ছিক। কোন মিল পাওয়া না গেলে কোন মানটি ফেরত দিতে হবে তা নির্ধারণ করে। যদি আপনি এটি বাদ দেন, তাহলে সূত্রটি কিছু না পেলে একটি মানক #N/A ত্রুটি ফেরত দেওয়া হবে৷

আমাদের নমুনা টেবিলের জন্য, এইগুলি ব্যবহার করার জন্য কেস-সংবেদনশীল XLOOKUP সূত্র৷

F3 এ মূল্য পেতে:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

এক্সট্রাক্ট করতেমন্তব্য F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

এই সূত্রটি কীভাবে কাজ করে:

আগের উদাহরণের মতো, EXACT রিটার্ন TRUE এবং FALSE মানগুলির একটি অ্যারে, যেখানে TRUE কেস-সংবেদনশীল মিলগুলিকে উপস্থাপন করে। XLOOKUP TRUE মানের জন্য উপরের অ্যারে অনুসন্ধান করে এবং return_array থেকে একটি মিল প্রদান করে। অনুগ্রহ করে মনে রাখবেন, যদি লুকআপ কলামে (লেটার কেস সহ) দুই বা তার বেশি ঠিক একই মান থাকে তবে সূত্রটি প্রথম পাওয়া মিলটি ফিরিয়ে দেবে।

XLOOKUP সীমাবদ্ধতা : শুধুমাত্র উপলব্ধ Excel 365 এবং Excel 2021-এ।

SUMPRODUCT - ম্যাচিং নম্বর ফেরাতে কেস-সংবেদনশীল লুকআপ

যেমন আপনি শিরোনাম থেকে বুঝতে পেরেছেন, SUMPRODUCT হল আরেকটি এক্সেল ফাংশন যা কেস-সংবেদনশীল লুকআপ করতে পারে , কিন্তু এটি শুধুমাত্র সাংখ্যিক মান ফেরত দিতে পারে। যদি এটি আপনার ক্ষেত্রে না হয়, তাহলে INDEX MATCH উদাহরণে যান যা সমস্ত ডেটা প্রকারের জন্য একটি সমাধান প্রদান করে৷

আপনি সম্ভবত জানেন যে, Excel এর SUMPRODUCT নির্দিষ্ট অ্যারেতে উপাদানগুলিকে গুণ করে এবং পণ্যগুলির যোগফল প্রদান করে৷ যেহেতু আমরা একটি কেস সংবেদনশীল লুকআপ চাই, তাই আমরা প্রথম অ্যারে পেতে EXACT ফাংশন ব্যবহার করি:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

দুঃখের বিষয়, SUMPRODUCT ফাংশন পাঠ্যের মানগুলিকে গুণিত করা যায় না বলে টেক্সট ম্যাচ ফেরত দিতে পারে না। এই ক্ষেত্রে, আপনি একটি #VALUE পাবেন! নীচের স্ক্রিনশটে সেল F4 এর মতো ত্রুটি:

এই সূত্রটি কীভাবে কাজ করে:

VLOOKUP উদাহরণের মতো, সঠিক ফাংশন চেকA2:A7-এর সমস্ত মানের বিপরীতে F2-এর মান এবং কেস-সংবেদনশীল মিলগুলির জন্য সত্য প্রদান করে, অন্যথায় FALSE:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

অধিকাংশ সূত্রে, এক্সেল সত্যকে 1 থেকে এবং 0 থেকে মিথ্যাকে মূল্যায়ন করে তাই, যখন SUMPRODUCT একই অবস্থানে দুটি অ্যারের উপাদানগুলিকে গুণ করে, তখন সমস্ত অ-মিল (FALSE) শূন্য হয়ে যায়:

SUMPRODUCT({0;0;0;54;0;0})

ফলাফল হিসাবে, সূত্রটি থেকে একটি সংখ্যা প্রদান করে কলাম B যা কলাম A-তে সঠিক কেস-সংবেদনশীল মিলের সাথে মিলে যায়।

SUMPRODUCT সীমাবদ্ধতা : শুধুমাত্র সাংখ্যিক মান ফেরত দিতে পারে।

INDEX MATCH - এর জন্য কেস-সংবেদনশীল লুকআপ সমস্ত ডেটা প্রকার

অবশেষে, আমরা একটি সীমাবদ্ধতা-মুক্ত কেস-সংবেদনশীল লুকআপ ফর্মুলা পাওয়ার কাছাকাছি যা সমস্ত এক্সেল সংস্করণে এবং সমস্ত ডেটা সেটে কাজ করে৷

এই উদাহরণটি শেষ পর্যন্ত আসে না শুধুমাত্র কারণ সর্বোত্তমটি শেষের জন্য সংরক্ষণ করা হয়, কিন্তু এছাড়াও কারণ পূর্ববর্তী উদাহরণগুলিতে আপনি যে জ্ঞান অর্জন করেছেন তা আপনাকে কেস-সংবেদনশীল ম্যাচ সূচক সূত্রটি আরও ভালভাবে বুঝতে সাহায্য করতে পারে৷

INDEX এবং MATCH ফাংশনগুলির সমন্বয় প্রায়শই ব্যবহৃত হয় প্রাক্তন মধ্যে cel VLOOKUP-এর আরও নমনীয় এবং বহুমুখী বিকল্প হিসাবে। নিম্নলিখিত নিবন্ধটি একটি ভাল কাজ করেছে (আশা করি :) ব্যাখ্যা করে কিভাবে এই দুটি ফাংশন একসাথে কাজ করে - VLOOKUP এর পরিবর্তে INDEX MATCH ব্যবহার করা।

এখানে, আমি আপনাকে শুধু মূল পয়েন্টগুলি মনে করিয়ে দেব:

• MATCH ফাংশন নির্দিষ্ট লুকআপ অ্যারেতে লুকআপ মান অনুসন্ধান করে এবং এর আপেক্ষিক অবস্থান প্রদান করে।
• আপেক্ষিকলুকআপ মানের অবস্থান সরাসরি INDEX ফাংশনের row_num আর্গুমেন্টে যায় যা এটিকে সেই সারি থেকে একটি মান ফেরত দেওয়ার নির্দেশ দেয়।

টেক্সট কেস চিনতে সূত্রের জন্য, আপনি শুধু ক্লাসিক INDEX ম্যাচ সংমিশ্রণে আরও একটি ফাংশন যোগ করতে হবে। স্পষ্টতই, আপনার আবার সঠিক ফাংশন প্রয়োজন:

F3 তে আসল সূত্র হল:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

F4 এ, আমরা এটি ব্যবহার করছি:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

দয়া করে মনে রাখবেন এটি শুধুমাত্র এই হিসাবে কাজ করে এক্সেল 365 ব্যতীত অন্য সকল সংস্করণে একটি অ্যারে সূত্র, তাই Ctrl + Shift + Enter কী একসাথে টিপে এটি প্রবেশ করতে ভুলবেন না। সঠিকভাবে করা হলে, সূত্রটি নীচের স্ক্রিনশটে দেখানো মত কোঁকড়া বন্ধনীতে আবদ্ধ হবে:

এই সূত্রটি কীভাবে কাজ করে:

পূর্ববর্তী সমস্ত উদাহরণের মত, EXACT A2:A7-এর প্রতিটি মানের জন্য TRUE প্রদান করে যা F2-এর মানের সাথে হুবহু মেলে। যেহেতু আমরা ম্যাচের lookup_value এর জন্য TRUE ব্যবহার করি, তাই এটি সঠিক কেস-সংবেদনশীল মিলের একটি আপেক্ষিক অবস্থান প্রদান করে, যা B2:B7 থেকে একটি ম্যাচ ফেরত দিতে INDEX-এর প্রয়োজন হয়।

উন্নত কেস-সংবেদনশীল লুকআপ ফর্মুলা

উপরে উল্লিখিত INDEX ম্যাচ সূত্রটি নিখুঁত দেখাচ্ছে, তাই না? কিন্তু বাস্তবে তা নয়। কেন আমি আপনাকে দেখাই।

ধরুন, লুকআপ মানের সাথে সম্পর্কিত রিটার্ন কলামের একটি ঘর ফাঁকা। সূত্র কি ফিরে আসবে? কিছুই না।এবং এখন, দেখা যাক এটি আসলে কী রিটার্ন করে:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

ওহো, সূত্রটি শূন্য দেয়! হতে পারে, শুধুমাত্র পাঠ্য মান নিয়ে কাজ করার সময় এটি সত্যিই গুরুত্বপূর্ণ নয়। যাইহোক, যদি আপনার ওয়ার্কশীটে সংখ্যা থাকে এবং সেগুলির মধ্যে কিছু প্রকৃত শূন্য হয়, তাহলে এটি একটি সমস্যা৷

সত্যি, পূর্বে আলোচনা করা অন্য সব লুকআপ সূত্র একইভাবে আচরণ করে৷ কিন্তু এখন আপনি একটি অনবদ্য সূত্র চান, তাই না?

কেস-সংবেদনশীল INDEX ম্যাচ ফর্মুলাটিকে একেবারে নিখুঁত করতে, আপনি এটিকে IF ফাংশনে মুড়ে দেন যা একটি রিটার্ন সেল ফাঁকা আছে কিনা তা পরীক্ষা করে এবং এতে কিছুই ফেরত দেয় না এই ক্ষেত্রে:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

উপরের সূত্রে:

• "C" হল রিটার্ন কলাম।
• "1" হল সংখ্যা যা MATCH ফাংশন দ্বারা প্রত্যাবর্তিত সেলের একটি আপেক্ষিক অবস্থান কে একটি বাস্তব সেল ঠিকানা তে পরিণত করে।

উদাহরণস্বরূপ, আমাদের MATCH ফাংশনে লুকআপ অ্যারে হল A2:A7, মানে সেল A2 এর আপেক্ষিক অবস্থান হল "1", কারণ এটি অ্যারের প্রথম ঘর। কিন্তু বাস্তবে, লুকআপ অ্যারেটি 2 সারিতে শুরু হয়। পার্থক্যটি পূরণ করতে, আমরা 1 যোগ করি, তাই INDIRECT ফাংশন ডান ঘর থেকে একটি মান ফিরিয়ে দেবে।

নীচের স্ক্রিনশটগুলি উন্নত কেস-সংবেদনশীল INDEX প্রদর্শন করে MATCH সূত্র কর্মে।

যদি রিটার্ন সেল খালি থাকে, সূত্রটি কিছুই আউটপুট করে না (একটি খালি স্ট্রিং):

যদি রিটার্ন সেলটিতে একটি শূন্য থাকে , সূত্রটি 0 প্রদান করে:

যদি আপনি চানরিটার্ন সেল ফাঁকা থাকলে কিছু বার্তা প্রদর্শন করুন, IF এর শেষ আর্গুমেন্টে একটি খালি স্ট্রিং ("") প্রতিস্থাপন করুন কিছু পাঠ্য সহ:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

কেস-সংবেদনশীল VLOOKUP একটি সহজ উপায় করুন

আমাদের এক্সেলের জন্য আলটিমেট স্যুট ব্যবহারকারীদের কাছে একটি বিশেষ টুল রয়েছে যা বড় এবং জটিল টেবিলে দেখা সহজ এবং চাপমুক্ত করে। সর্বোত্তম জিনিস হল যে মার্জ টু টেবিলের একটি কেস-সংবেদনশীল বিকল্প রয়েছে এবং নীচের উদাহরণটি এটিকে কার্যকরভাবে দেখায়।

ধরুন আপনি Qty টানতে চান। অনন্য আইটেম আইডির উপর ভিত্তি করে লুকআপ টেবিল থেকে প্রধান টেবিলে যান:

আপনি যা করেন তা হল মার্জ টেবিল চালানো উইজার্ড করুন এবং এই পদক্ষেপগুলি সম্পাদন করুন:

1. নতুন ডেটা টেনে নেওয়ার জন্য প্রধান টেবিলটি নির্বাচন করুন৷
2. নতুন ডেটা কোথায় দেখতে হবে তা সন্ধানের টেবিলটি নির্বাচন করুন৷
3. এক বা একাধিক কী কলাম চয়ন করুন (আমাদের ক্ষেত্রে আইটেম আইডি)। এবং কেস-সংবেদনশীল ম্যাচিং বক্সটি চেক করতে ভুলবেন না৷

এক মুহূর্ত পরে, আপনি পছন্দসই ফলাফল পাবেন :)

এভাবে টেক্সট কেস বিবেচনা করে এক্সেলে কীভাবে সন্ধান করবেন। পড়ার জন্য আমি আপনাকে ধন্যবাদ জানাই এবং আশা করছি আগামী সপ্তাহে আমাদের ব্লগে আপনাকে দেখতে পাব!

ডাউনলোডের জন্য অনুশীলন ওয়ার্কবুক

কেস-সংবেদনশীল VLOOKUP উদাহরণ (.xlsx ফাইল)