টিউটোৰিয়েলত Excel VLOOKUP কেনেকৈ কেছ-চেন্সিটিভ কৰিব লাগে সেই বিষয়ে ব্যাখ্যা কৰা হৈছে, টেক্সট কেছক পৃথক কৰা আন কেইটামান সূত্ৰ প্ৰদৰ্শন কৰা হৈছে, আৰু প্ৰতিটো ফাংচনৰ শক্তি আৰু সীমাবদ্ধতাসমূহ আঙুলিয়াই দিয়া হৈছে।

মই অনুমান কৰিছোঁ যে প্ৰতিটো এক্সেল ব্যৱহাৰকাৰীয়ে জানে যে এক্সেলত কি ফাংচনে উলম্ব লুকআপ কৰে। ঠিকেই, ই VLOOKUP। কিন্তু, অতি কম সংখ্যক লোকে জানে যে Excel ৰ VLOOKUP ডাঙৰ-বৰ-অসংবেদনশীল, অৰ্থাৎ ই সৰু আৰু UPPERCASE আখৰক একে আখৰ হিচাপে গণ্য কৰে।

ইয়াত এটা ক্ষন্তেকীয়া উদাহৰণ দিয়া হৈছে যিয়ে VLOOKUP ৰ লিখনী কেছ পৃথক কৰিব নোৱাৰাটো প্ৰদৰ্শন কৰে। ধৰি লওক যদি আপোনাৰ A2 কোষত "বিল" আৰু A4 ত "বিল" আছে। তলৰ সূত্ৰই "বিল" ধৰিব কাৰণ ই লুকআপ এৰেত প্ৰথমে আহে আৰু B2 ৰ পৰা এটা মিল থকা মান ঘূৰাই দিয়ে।

=VLOOKUP("Bill", A2:B4, 2, FALSE)

ইয়াত আৰু আগবাঢ়ক লেখাটোত, মই আপোনালোকক VLOOKUP কেছ-চেন্সিটিভ কৰাৰ এটা উপায় দেখুৱাম। আমি এক্সেলত কেছ-চেন্সিটিভ মেচ কৰিব পৰা আন কেইটামান ফাংচনও অন্বেষণ কৰিম।

কেছ-চেন্সিটিভ VLOOKUP সূত্ৰ

ওপৰত উল্লেখ কৰা অনুসৰি এটা সাধাৰণ VLOOKUP সূত্ৰ চিঠিৰ গোচৰটো চিনি নাপায়। কিন্তু, তলৰ উদাহৰণত দেখুওৱাৰ দৰে Excel VLOOKUP কেছ-চেন্সিটিভ কৰাৰ এটা উপায় আছে।

ধৰি লওক আপোনাৰ A স্তম্ভত আইটেম আইডি আছে আৰু বস্তুটোৰ মূল্য আৰু মন্তব্য টানিব বিচাৰে সমস্যাটো হ'ল যে ID সমূহে সৰু আৰু ডাঙৰ আখৰ দুয়োটা অন্তৰ্ভুক্ত কৰে। উদাহৰণস্বৰূপে, A4 (001Tvci3u) আৰু A5 (001Tvci3U) ৰ মানসমূহ কেৱল 1000 ত পাৰ্থক্য আছেশেষৰ আখৰ, "u" আৰু "U", যথাক্ৰমে।

"001Tvci3 U " চালে, এটা প্ৰামাণিক VLOOKUP সূত্ৰই $90 আউটপুট কৰে যি "001Tvci3 u ৰ সৈতে জড়িত " কাৰণ ই লুকআপ এৰেত "001Tvci3 U " ৰ আগত আহে। কিন্তু এইটো আপুনি বিচৰা ধৰণৰ নহয়, নহয়নে?

১৯৮৫

এক্সেলত এটা কেছ-চেন্সিটিভ লুকআপ কৰিবলৈ আমি VLOOKUP, CHOOSE আৰু EXACT একত্ৰিত কৰোঁ ফাংচনসমূহ:

এই জেনেৰিক সূত্ৰটোৱে সকলো পৰিস্থিতিত নিখুঁতভাৱে কাম কৰে। আপুনি আনকি সোঁফালৰ পৰা বাওঁফাললৈ চাব পাৰে , যিটো এটা নিয়মীয়া VLOOKUP সূত্ৰই কৰিব নোৱাৰে। এই সহজ আৰু মাৰ্জিত সমাধানৰ পৰামৰ্শ দিয়াৰ বাবে পৌৰিয়াক কুডোছ!

আমাৰ ক্ষেত্ৰত, প্ৰকৃত সূত্ৰসমূহ তলত দিয়া ধৰণে যায়।

F3 ত মূল্য টানিবলৈ:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), B2:B7), 2, FALSE)

মন্তব্যটো আনিবলৈ F4:

=VLOOKUP(TRUE, CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7), 2, FALSE)

টোকা। Excel 365 ৰ বাহিৰে আন সকলো Excel সংস্কৰণত, ই কেৱল এটা এৰে সূত্ৰ হিচাপে কাম কৰে, গতিকে ইয়াক সঠিকভাৱে সম্পূৰ্ণ কৰিবলৈ Ctrl + Shift + Enter টিপিবলৈ মনত ৰাখিব। Excel 365 ত, ডাইনামিক এৰেৰ বাবে সমৰ্থনৰ বাবে, ই এটা নিয়মীয়া সূত্ৰ হিচাপেও কাম কৰে।

এই সূত্ৰটোৱে কেনেকৈ কাম কৰে:

ট্ৰিকটো কৰা মূল অংশটো হ'ল নেষ্টেড EXACT ৰ সৈতে CHOOSE সূত্ৰটো:

CHOOSE({1,2}, EXACT(F2, A2:A7), C2:C7)

ইয়াত, EXACT ফাংচনে F2 ৰ মানক A2:A7 ৰ প্ৰতিটো মানৰ বিপৰীতে তুলনা কৰে আৰু TRUE ঘূৰাই দিয়ে যদি সিহঁত আখৰৰ আখৰ অন্তৰ্ভুক্ত কৰি হুবহু একে হয়,অন্যথা FALSE:

{FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}

CHOOSE ৰ index_num যুক্তিৰ বাবে, আমি এৰে ধ্ৰুৱক {1,2} ব্যৱহাৰ কৰো। ফলস্বৰূপে, ফাংচনে ওপৰৰ এৰেৰ পৰা লজিকেল মানসমূহ আৰু C2:C7 ৰ পৰা মানসমূহক এনেদৰে এটা দ্বিমাত্ৰিক এৰেলৈ একত্ৰিত কৰে:

{FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}

VLOOKUP ফাংচনে ইয়াক তাৰ পৰা লয় আৰু ২-মাত্ৰিক এৰেৰ ১ম স্তম্ভত (লজিকেল মানসমূহে প্ৰতিনিধিত্ব কৰা) লুকআপ মান (যিটো TRUE) সন্ধান কৰে আৰু ২য় স্তম্ভৰ পৰা এটা মিল ঘূৰাই দিয়ে, যিটো আমি বিচৰা মূল্য:

VLOOKUP(TRUE, {FALSE,155;FALSE,186;FALSE,90;TRUE,54;FALSE,159;FALSE,28}, 2, 0)

আখৰ-সংবেদনশীল XLOOKUP সূত্ৰ

মাইক্ৰ'ছফ্ট 365 গ্ৰাহকে এক্সেলত আৰু এটা সহজ সূত্ৰৰ সৈতে এটা কেছ-চেন্সিটিভ লুকআপ কৰিব পাৰে। আপুনি অনুমান কৰিব পাৰে যে মই VLOOKUP ৰ এটা অধিক শক্তিশালী উত্তৰাধিকাৰীৰ কথা কৈছো - XLOOKUP ফাংচন।

যিহেতু XLOOKUP এ লুকআপ আৰু ৰিটাৰ্ণ এৰে পৃথকে পৃথকে কাম কৰে, আমাক পূৰ্বৰ পৰা দ্বিমাত্ৰিক এৰে ট্ৰিকৰ প্ৰয়োজন নাই উদাহৰণ. সৰলভাৱে, lookup_array যুক্তিৰ বাবে EXACT ব্যৱহাৰ কৰক:

শেষ যুক্তি ("পোৱা হোৱা নাই") বৈকল্পিক। ই কেৱল সংজ্ঞায়িত কৰে যে যদি কোনো মিল পোৱা নাযায় তেন্তে কি মান ঘূৰাই দিব লাগে। যদি আপুনি ইয়াক বাদ দিয়ে, তেন্তে এটা প্ৰামাণিক #N/A ভুল ঘূৰাই দিয়া হ'ব যদিহে সূত্ৰই একো নাপায়।

আমাৰ নমুনা টেবুলৰ বাবে, এইবোৰ ব্যৱহাৰ কৰিবলৈ ডাঙৰ-বৰ-সংবেদনশীল XLOOKUP সূত্ৰ।

F3 ত মূল্য পাবলৈ:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), B2:B7, "Not found")

উলিয়াবলৈ...comment F4:

=XLOOKUP(TRUE, EXACT(F2, A2:A7), C2:C7, "Not found")

এই সূত্ৰটোৱে কেনেকৈ কাম কৰে:

পূৰ্বৰ উদাহৰণৰ দৰে, EXACT এ ঘূৰাই দিয়ে TRUE আৰু FALSE মানসমূহৰ এটা এৰে, য'ত TRUE এ ডাঙৰ-বৰ-সংবেদনশীল মিলসমূহক প্ৰতিনিধিত্ব কৰে। XLOOKUP এ ওপৰৰ এৰেত TRUE মানৰ বাবে সন্ধান কৰে আৰু return_array ৰ পৰা এটা মিল ঘূৰাই দিয়ে। অনুগ্ৰহ কৰি মন কৰক, যদি লুকআপ স্তম্ভত দুটা বা তাতকৈ অধিক হুবহু একে মান আছে (আখৰৰ ক্ষেত্ৰ অন্তৰ্ভুক্ত কৰি), সূত্ৰই প্ৰথম পোৱা মিল ঘূৰাই দিব।

XLOOKUP সীমাবদ্ধতা : কেৱল উপলব্ধ Excel 365 আৰু Excel 2021 ত।

SUMPRODUCT - মিল থকা সংখ্যা ঘূৰাই দিবলৈ ডাঙৰ-বৰ-সংবেদনশীল লুকআপ

আপুনি শিৰোনামৰ পৰা বুজি পোৱাৰ দৰে, SUMPRODUCT হৈছে আন এটা Excel ফাংচন যিয়ে এটা ডাঙৰ-বৰ-সংবেদনশীল লুকআপ কৰিব পাৰে , কিন্তু ই কেৱল সংখ্যাগত মান ঘূৰাই দিব পাৰে। যদি এইটো আপোনাৰ নহয়, তেন্তে INDEX MATCH উদাহৰণলৈ যাওক যি সকলো তথ্য ধৰণৰ বাবে এটা সমাধান প্ৰদান কৰে।

আপুনি হয়তো জানে যে, Excel ৰ SUMPRODUCT এ ধাৰ্য্য কৰা এৰেসমূহত উপাদানসমূহক বহুগুণ কৰে আৰু উৎপাদনসমূহৰ যোগফল ঘূৰাই দিয়ে। যিহেতু আমি এটা কেছ চেন্সিটিভ লুকআপ বিচাৰো, আমি প্ৰথম এৰে পাবলৈ EXACT ফাংচন ব্যৱহাৰ কৰো:

=SUMPRODUCT((EXACT(A2:A7,F2) * (B2:B7)))

দুখৰ বিষয় যে, SUMPRODUCT ফাংচনে টেক্সট মেচ ঘূৰাই দিব নোৱাৰে কাৰণ টেক্সট মানসমূহ গুণ কৰিব নোৱাৰি। এনে ক্ষেত্ৰত আপুনি #VALUE পাব! তলৰ স্ক্ৰীণশ্বটত F4 কোষৰ দৰে ভুল:

এই সূত্ৰই কেনেকৈ কাম কৰে:

VLOOKUP উদাহৰণৰ দৰে, EXACT ফাংচন পৰীক্ষা কৰেF2 ত থকা মানটো A2:A7 ৰ সকলো মানৰ বিপৰীতে আৰু ডাঙৰ-বৰ-সংবেদনশীল মিলৰ বাবে TRUE ঘূৰাই দিয়ে, অন্যথা FALSE:

SUMPRODUCT(({FALSE;FALSE;FALSE;TRUE;FALSE;FALSE}*{155;186;90;54;159;28}))

বেছিভাগ সূত্ৰত, Excel এ TRUE ক 1 লৈ আৰু FALSE 0 লৈ মূল্যায়ন কৰে গতিকে, যেতিয়া SUMPRODUCT এ একে অৱস্থানত দুটা এৰেৰ উপাদানসমূহক গুণ কৰে, সকলো অমিল (FALSE) শূন্য হৈ পৰে:

SUMPRODUCT({0;0;0;54;0;0})

ফলত, সূত্ৰই ৰ পৰা এটা সংখ্যা ঘূৰাই দিয়ে স্তম্ভ B যি স্তম্ভ A ত সঠিক আখৰ-সংবেদনশীল মিলৰ সৈতে মিল খায়।

SUMPRODUCT সীমাবদ্ধতা : কেৱল সংখ্যাগত মান ঘূৰাই দিব পাৰে।

INDEX MATCH - case-sensitive lookup for সকলো ডাটা প্ৰকাৰ

শেষত, আমি এটা সীমাবদ্ধতা-মুক্ত আখৰ-সংবেদনশীল লুকআপ সূত্ৰ পোৱাৰ ওচৰ চাপিছো যিয়ে সকলো এক্সেল সংস্কৰণত আৰু সকলো ডাটা ছেটত কাম কৰে।

এই উদাহৰণটো কেৱল কাৰণেই নহয় সৰ্বোত্তমটো শেষৰ বাবে সংৰক্ষণ কৰা হয়, কিন্তু কাৰণ আপুনি পূৰ্বৰ উদাহৰণসমূহত লাভ কৰা জ্ঞানে আপোনাক ডাঙৰ-বৰ-সংবেদনশীল MATCH INDEX সূত্ৰ ভালদৰে বুজিবলৈ সহায় কৰিব পাৰে।

INDEX আৰু MATCH ফাংচনসমূহৰ সংমিশ্ৰণ প্ৰায়ে ব্যৱহাৰ কৰা হয় in Ex cel VLOOKUP ৰ এটা অধিক নমনীয় আৰু বহুমুখী বিকল্প হিচাপে। তলৰ প্ৰবন্ধটোৱে এই দুটা ফাংচনে কেনেকৈ একেলগে কাম কৰে সেই বিষয়ে বুজাই ভাল কাম কৰিছে (আশাকৰোঁ :) - VLOOKUP ৰ পৰিৱৰ্তে INDEX MATCH ব্যৱহাৰ কৰা।

ইয়াত, মই আপোনাক মূল কথাবোৰ সোঁৱৰাই দিম:

• MATCH ফাংচনে ধাৰ্য্য কৰা লুকআপ এৰেত লুকআপ মান সন্ধান কৰে আৰু ইয়াৰ আপেক্ষিক অৱস্থান ঘূৰাই দিয়ে।
• আপেক্ষিকলুকআপ মানৰ অৱস্থান পোনপটীয়াকৈ INDEX ফাংচনৰ row_num যুক্তিলৈ যায় আৰু ইয়াক সেই শাৰীৰ পৰা এটা মান ঘূৰাই দিবলৈ নিৰ্দেশ দিয়ে।

সূত্ৰটোৱে লিখনী কেছ চিনাক্ত কৰিবলে, আপুনি মাত্ৰ ক্লাছিক INDEX MATCH সংমিশ্ৰণত আৰু এটা ফাংচন যোগ কৰিব লাগিব। স্পষ্টভাৱে, আপুনি আকৌ EXACT ফাংচনৰ প্ৰয়োজন:

F3 ত প্ৰকৃত সূত্ৰটো হ'ল:

=INDEX(B2:B7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

F4 ত আমি এইটো ব্যৱহাৰ কৰিছো:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

অনুগ্ৰহ কৰি মনত ৰাখিব যে ই কেৱল হিচাপে কাম কৰে Excel 365 ৰ বাহিৰে অন্য সকলো সংস্কৰণতে এটা এৰে সূত্ৰ, গতিকে ইয়াক Ctrl + Shift + Enter কি'সমূহ একেলগে টিপি সুনিশ্চিত কৰক। যদি সঠিকভাৱে কৰা হয়, তেন্তে সূত্ৰটো তলৰ স্ক্ৰীণশ্বটত দেখুওৱাৰ দৰে কোঁচা ব্ৰেচত আবদ্ধ হৈ পৰিব:

এই সূত্ৰটোৱে কেনেকৈ কাম কৰে:

পূৰ্বৰ সকলো উদাহৰণৰ দৰে, EXACT এ A2:A7 ৰ প্ৰতিটো মানৰ বাবে TRUE ঘূৰাই দিয়ে যি F2 ৰ মানৰ সৈতে হুবহু মিলে। যিহেতু আমি MATCH ৰ lookup_value ৰ বাবে TRUE ব্যৱহাৰ কৰো, ই সঠিক আখৰ-সংবেদনশীল মিলৰ এটা আপেক্ষিক অৱস্থান ঘূৰাই দিয়ে, যিটো INDEX য়ে B2:B7.

ৰ পৰা এটা মিল ঘূৰাই দিবলৈ প্ৰয়োজনীয় উন্নত আখৰ-সংবেদনশীল লুকআপ সূত্ৰ

ওপৰত উল্লেখ কৰা INDEX MATCH সূত্ৰটো নিখুঁত দেখা যায়, নহয়নে? কিন্তু আচলতে নহয়। মই আপোনাক কিয় দেখুৱাওঁ।

ধৰি লওক লুকআপ মানৰ সৈতে সংগতি ৰাখি ৰিটাৰ্ণ কলামৰ এটা কোষ খালী। সূত্ৰটোৱে কি ঘূৰাই দিব? একো নাই.আৰু এতিয়া, চাওঁ আহক ই প্ৰকৃততে কি ঘূৰাই দিয়ে:

=INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0))

উফ, সূত্ৰটোৱে শূন্য ঘূৰাই দিয়ে! হয়তো, কেৱল লিখনী মূল্যৰ সৈতে মোকাবিলা কৰাৰ সময়ত ই আচলতে গুৰুত্বপূৰ্ণ নহয়। কিন্তু, যদি আপোনাৰ কাৰ্য্যপত্ৰিকাত সংখ্যা থাকে আৰু ইয়াৰে কিছুমান বাস্তৱ শূন্য হয়, এইটো এটা সমস্যা।

সত্যত, আগতে আলোচনা কৰা আন সকলো লুকআপ সূত্ৰই একে ধৰণে আচৰণ কৰে। কিন্তু এতিয়া আপুনি এটা দোষহীন সূত্ৰ বিচাৰে, নহয়নে?

আখৰৰ সংবেদনশীল INDEX MATCH সূত্ৰটোক একেবাৰে নিখুঁত কৰিবলৈ, আপুনি ইয়াক IF ফাংচনত ৰেপ কৰে যিয়ে এটা ৰিটাৰ্ণ চেল খালী নেকি আৰু একো ঘূৰাই নিদিয়ে নেকি পৰীক্ষা কৰে এই ক্ষেত্ৰত:

=IF(INDIRECT("C"&(1+MATCH(TRUE,EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "")

ওপৰৰ সূত্ৰত:

• "C" হৈছে উভতি অহা স্তম্ভ।
• "1" হৈছে সংখ্যা যিয়ে MATCH ফাংচনে ঘূৰাই দিয়া কোষৰ এটা আপেক্ষিক অৱস্থান ক এটা বাস্তৱ কোষ ঠিকনা লৈ ৰূপান্তৰিত কৰে।

উদাহৰণস্বৰূপে, আমাৰ MATCH ফাংচনত থকা লুকআপ এৰে হৈছে A2:A7, অৰ্থাৎ A2 কোষৰ আপেক্ষিক অৱস্থান "1", কাৰণ এইটো এৰেৰ প্ৰথম কোষ। কিন্তু বাস্তৱত, লুকআপ এৰে শাৰী ২ ৰ পৰা আৰম্ভ হয়। পাৰ্থক্যটো ক্ষতিপূৰণ কৰিবলৈ আমি ১ যোগ কৰো, গতিকে INDIRECT ফাংচনে সোঁফালৰ কোষৰ পৰা এটা মান ঘূৰাই দিব।

তলৰ স্ক্ৰীণশ্বটসমূহে উন্নত আখৰৰ সংবেদনশীল INDEX প্ৰদৰ্শন কৰে সূত্ৰটো কাৰ্য্যত MATCH কৰক।

যদি ৰিটাৰ্ণ চেল খালী থাকে, সূত্ৰই একো আউটপুট নকৰে (এটা খালী ষ্ট্ৰিং):

যদি ৰিটাৰ্ণ চেলত এটা শূন্য থাকে , সূত্ৰটোৱে 0 ঘূৰাই দিয়ে:

যদি আপুনি পছন্দ কৰেকিছুমান বাৰ্তা প্ৰদৰ্শন কৰক যেতিয়া এটা উভতি অহা ঘৰ খালী হয়, IF ৰ শেষ যুক্তিত এটা খালী স্ট্ৰিং ("") কিছুমান লিখনীৰ সৈতে সলনি কৰক:

=IF(INDIRECT("C"&(1+MATCH(TRUE, EXACT(A2:A7, F2), 0)))"", INDEX(C2:C7, MATCH(TRUE, EXACT(A2:A7, F2), 0)), "There is nothing to return, sorry.")

কেছ-চেন্সিটিভ VLOOKUP সহজ উপায়েৰে কৰক

আমাৰ এক্সেলৰ বাবে আলটিমেট ছুইটৰ ব্যৱহাৰকাৰীসকলৰ এটা বিশেষ সঁজুলি আছে যিয়ে ডাঙৰ আৰু জটিল টেবুলসমূহত ওপৰলৈ চোৱাটো সহজ আৰু মানসিক চাপমুক্ত কৰে। আটাইতকৈ ভাল কথাটো হ'ল যে দুটা টেবুল একত্ৰিত কৰক এটা ডাঙৰ-বৰ-সংবেদনশীল বিকল্প আছে, আৰু তলৰ উদাহৰণে ইয়াক কাৰ্য্যত দেখুৱাইছে।

ধৰি লওক আপুনি Qty টানিব বিচাৰে। Lookup টেবুলৰ পৰা Main টেবুললৈ একক বস্তু ID সমূহৰ ওপৰত ভিত্তি কৰি:

আপুনি যি কৰে সেয়া হ'ল মাৰ্জ টেবুলসমূহ চলোৱা উইজাৰ্ড আৰু এই পদক্ষেপসমূহ সম্পাদন কৰক:

1. নতুন তথ্য টানিব পৰা মূল টেবুল নিৰ্ব্বাচন কৰক।
2. নতুন তথ্য বিচাৰিবলৈ লুকআপ টেবুল নিৰ্ব্বাচন কৰক।
3. এটা বা অধিক মূল স্তম্ভ বাছক (আমাৰ ক্ষেত্ৰত বস্তু ID)। আৰু আখৰৰ সংবেদনশীল মিলন বাকচটো নিশ্চিতভাৱে পৰীক্ষা কৰক।

এটা মুহূৰ্তৰ পিছত, আপুনি পছন্দৰ ফলাফল পাব :)

টেক্সট কেছটোৰ প্ৰতি লক্ষ্য ৰাখি এক্সেলত লুকআপ কৰিবলৈ তেনেকৈয়ে। মই আপোনাক পঢ়াৰ বাবে ধন্যবাদ জনাইছো আৰু অহা সপ্তাহত আমাৰ ব্লগত আপোনাক লগ পাম বুলি আশা কৰিছো!

ডাউনলোডৰ বাবে অনুশীলন কাৰ্য্যপুস্তিকা

আখৰৰ সংবেদনশীল VLOOKUP উদাহৰণ (.xlsx ফাইল)